[Mac/GN] Set up the component build.

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
 import("//build/config/sanitizers/sanitizers.gni")
@@ skipping 213 matching lines @@
       "//third_party/widevine/cdm:widevinecdmadapter",
     ]
 
     if (is_multi_dll_chrome) {
       defines += [ "CHROME_MULTIPLE_DLL" ]
       data_deps += [ ":chrome_child" ]
     }
   }
 }  # !is_android && !is_mac
 
-if (is_mac) {
-  if (is_component_build) {
-    # On Mac component builds, this target is the bundle, and the main dll is
-    # just another shared library. This speeds up incremental builds by
-    # not requiring re-doing the bundle every time main_dll changes.
-    # See https://codereview.chromium.org/11420019
-
-    # TODO(GYP) chrome_dll for Mac component build.
-    assert(false)
-  } else {
-    # On Mac non-component builds, this is a no-op forwarding target.
-    group("chrome_dll") {
-      public_deps = [
-        ":chrome_framework",
-      ]
-    }
-  }
-}
-
 if (is_win) {
   # This target is a forwarding target to compile the necessary DLLs used
   # by Chrome.
   group("chrome_dll") {
     # TODO(GYP) support incremental_chrome_dll on Windows for faster links in
     # developer component builds. When that's supported, this target will need
     # to become more complicated.
     data_deps = [
       ":main_dll",
     ]
@@ skipping 132 matching lines @@
         deps += [ "//pdf" ]
       }
     }
   }
 } else if (is_mac) {
   chrome_helper_name = chrome_product_full_name + " Helper"
   chrome_framework_name = chrome_product_full_name + " Framework"
 
   group("chrome") {
     deps = [
-      ":chrome_initial",
-    ]
-  }
-
-  group("chrome_initial") {
-    deps = [
       ":chrome_app",
     ]
   }
 
   tweak_info_plist("chrome_app_plist") {
     info_plist = "app/app-Info.plist"
     args = [
       "--breakpad=0",
 
       #"--keystone=???",  # TODO(rsesek): Keystone.
@@ skipping 143 matching lines @@
 
     sources = [
       "app/chrome_exe_main_mac.c",
     ]
 
     defines = [ "HELPER_EXECUTABLE" ]
 
     deps = [
       "//chrome/common:version_header",
     ]
+
+    ldflags = [
+      # The helper is in Chromium.app/Contents/Versions/X/Chromium Helper.app/Conents/MacOS/
+      # so set rpath up to the base.
+      "-rpath",
+      "@loader_path/../../../../../../..",
+    ]
   }
 
   bundle_data("chrome_framework_locales") {
     sources = []
     public_deps = [
       ":repack_locales_pack",
     ]
 
     foreach(locale, locales_as_mac_outputs) {
       sources += [ "$root_gen_dir/repack/locales/$locale.pak" ]
@@ skipping 74 matching lines @@
 
       #"--breakpad_uploads=???",  # TODO(rsesek): Breakpad uploads.
 
       "--keystone=0",
       "--scm=1",
       "--branding",
       chrome_product_short_name,
     ]
   }
 
-  mac_framework_bundle("chrome_framework") {
-    output_name = chrome_framework_name
-
-    configs += [ "//build/config/compiler:wexit_time_destructors" ]
+  # On Mac, speed up the component build by not re-bundling the framework
+  # every time it changes. Instead, place all the sources and their deps in
+  # a library that the bundled framework links (and re-exports). That way
+  # only the library needs to be re-linked when it changes.
+  if (is_component_build) {
+    _dll_target_type = "shared_library"
+  } else {
+    _dll_target_type = "source_set"
+  }
+  target(_dll_target_type, "chrome_dll") {
+    visibility = [
+      ":chrome_framework",
+      ":chrome_framework_shared_library",
+    ]
 
     sources = [
       "app/chrome_command_ids.h",
       "app/chrome_crash_reporter_client.cc",
       "app/chrome_crash_reporter_client.h",
       "app/chrome_crash_reporter_client_mac.mm",
       "app/chrome_dll_resource.h",
       "app/chrome_main.cc",
       "app/chrome_main_delegate.cc",
       "app/chrome_main_delegate.h",
       "app/chrome_main_mac.h",
       "app/chrome_main_mac.mm",
     ]
 
-    info_plist_target = ":chrome_framework_plist"
-    extra_substitutions = [
-      "CHROMIUM_BUNDLE_ID=$chrome_mac_bundle_id",
-      "CHROMIUM_SHORT_NAME=$chrome_product_short_name",
-    ]
-
     deps = [
       ":browser_dependencies",
       ":child_dependencies",
-      ":chrome_framework_helpers",
-      ":chrome_framework_locales",
-      ":chrome_framework_resources",
-      "//build/config/sanitizers:deps",
-      "//chrome/app/nibs:chrome_xibs",
       "//chrome/common:features",
       "//components/crash/content/app",
       "//components/policy",
       "//content/public/app:both",
       "//third_party/cld_2",
     ]
 
+    if (is_component_build) {
+      libs = [ "Carbon.framework" ]
+    }
+
     ldflags = [
       "-Wl,-order_file",
       "-Wl," + rebase_path("app/framework.order", root_build_dir),
-      "-install_name",
-      "@executable_path/../Versions/$chrome_version_full/$chrome_framework_name.framework/$chrome_framework_name",
-      "-compatibility_version",
-      chrome_dylib_version,
-      "-current_version",
-      chrome_dylib_version,
+      "-ObjC",
     ]
 
     if (enable_plugins && enable_pdf) {
       deps += [ "//pdf" ]
     }
 
     if (enable_package_mash_services) {
       deps += [ "//chrome/app/mash" ]
     }
   }
+
+  mac_framework_bundle("chrome_framework") {
+    output_name = chrome_framework_name
+
+    configs += [ "//build/config/compiler:wexit_time_destructors" ]
+
+    info_plist_target = ":chrome_framework_plist"
+    extra_substitutions = [
+      "CHROMIUM_BUNDLE_ID=$chrome_mac_bundle_id",
+      "CHROMIUM_SHORT_NAME=$chrome_product_short_name",
+    ]
+
+    public_deps = [
+      ":chrome_dll",
+    ]
+
+    deps = [
+      ":chrome_framework_helpers",
+      ":chrome_framework_locales",
+      ":chrome_framework_resources",
+      "//build/config/sanitizers:deps",
+      "//chrome/app/nibs:chrome_xibs",
+    ]
+
+    ldflags = [
+      "-Wl,-install_name,@executable_path/../Versions/$chrome_version_full/$chrome_framework_name.framework/$chrome_framework_name",
+      "-compatibility_version",
+      chrome_dylib_version,
+      "-current_version",
+      chrome_dylib_version,
+    ]
+
+    if (is_component_build) {
+      ldflags += [
+        "-rpath",
+        "@loader_path/../../../../..",
+        "-Wl,-reexport_library,libchrome_dll.dylib",
+      ]
+    }
+  }
 }
 
 # GYP version: chromium_browser_dependencies variable in chrome.gyp
 group("browser_dependencies") {
   public_deps = [
     "//chrome/browser",
     "//chrome/common",
     "//sync",
   ]
   if (enable_plugins) {
@@ skipping 632 matching lines @@
       "//chrome/app/theme/$branding_path_component/product_logo_48.png",
       "//chrome/tools/build/linux/chrome-wrapper",
       "//third_party/xdg-utils/scripts/xdg-mime",
       "//third_party/xdg-utils/scripts/xdg-settings",
     ]
     outputs = [
       "$root_out_dir/{{source_file_part}}",
     ]
   }
 }