Added brotli enc/ and tools/ directories.

third_party/brotli/brotli.gni

Index: third_party/brotli/brotli.gni
diff --git a/third_party/brotli/brotli.gni b/third_party/brotli/brotli.gni
new file mode 100644
index 0000000000000000000000000000000000000000..f4ed9d26b30c6963cb8f4b8ce863011ef4bf87b4
--- /dev/null
+++ b/third_party/brotli/brotli.gni
@@ -0,0 +1,35 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/compiled_action.gni")
+
+# Compresses a file with brotli.
+#
+# Variables
+#   input_file: Path to input file.
+#   output_file: Path to output file.
+#
+template("compress_file_brotli") {
+  compiled_action(target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "testonly",
+                           ])
+    tool = "//third_party/brotli:bro"
+    inputs = [
+      invoker.input_file,
+    ]
+    outputs = [
+      invoker.output_file,
+    ]
+    args = [
+      "--force",
+      "--input",
+      rebase_path(invoker.input_file, root_build_dir),
+      "--output",
+      rebase_path(invoker.output_file, root_build_dir),
+    ]
+  }
+}