simd/jiss2red.asm - Issue 1953443002: Update to libjpeg_turbo 1.4.90

Side by Side Diff: simd/jiss2red.asm

Issue 1953443002: Update to libjpeg_turbo 1.4.90 (Closed) Base URL: https://chromium.googlesource.com/chromium/deps/libjpeg_turbo.git@master

Patch Set: Created 4 years, 7 months ago

Use n/p to move between diff chunks; N/P to move between comments. Draft comments are only viewable by you.

Jump to:

View unified diff | Download patch

OLD	NEW
	(Empty)
1 ;

2 ; jiss2red.asm - reduced-size IDCT (SSE2)

3 ;

4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB

5 ;

6 ; Based on

7 ; x86 SIMD extension for IJG JPEG library

8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.

9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc

10 ;

11 ; This file should be assembled with NASM (Netwide Assembler),

12 ; can not be assembled with Microsoft's MASM or any compatible

13 ; assembler (including Borland's Turbo Assembler).

14 ; NASM is available from http://nasm.sourceforge.net/ or

15 ; http://sourceforge.net/project/showfiles.php?group_id=6208

16 ;

17 ; This file contains inverse-DCT routines that produce reduced-size

18 ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block.

19 ; The following code is based directly on the IJG's original jidctred.c;

20 ; see the jidctred.c for more details.

21 ;

22 ; [TAB8]

23

24 %include "jsimdext.inc"

25 %include "jdct.inc"

26

27 ; --------------------------------------------------------------------------

28

29 %define CONST_BITS 13

30 %define PASS1_BITS 2

31

32 %define DESCALE_P1_4 (CONST_BITS-PASS1_BITS+1)

33 %define DESCALE_P2_4 (CONST_BITS+PASS1_BITS+3+1)

34 %define DESCALE_P1_2 (CONST_BITS-PASS1_BITS+2)

35 %define DESCALE_P2_2 (CONST_BITS+PASS1_BITS+3+2)

36

37 %if CONST_BITS == 13

38 F_0_211 equ 1730 ; FIX(0.211164243)

39 F_0_509 equ 4176 ; FIX(0.509795579)

40 F_0_601 equ 4926 ; FIX(0.601344887)

41 F_0_720 equ 5906 ; FIX(0.720959822)

42 F_0_765 equ 6270 ; FIX(0.765366865)

43 F_0_850 equ 6967 ; FIX(0.850430095)

44 F_0_899 equ 7373 ; FIX(0.899976223)

45 F_1_061 equ 8697 ; FIX(1.061594337)

46 F_1_272 equ 10426 ; FIX(1.272758580)

47 F_1_451 equ 11893 ; FIX(1.451774981)

48 F_1_847 equ 15137 ; FIX(1.847759065)

49 F_2_172 equ 17799 ; FIX(2.172734803)

50 F_2_562 equ 20995 ; FIX(2.562915447)

51 F_3_624 equ 29692 ; FIX(3.624509785)

52 %else

53 ; NASM cannot do compile-time arithmetic on floating-point constants.

54 %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n))

55 F_0_211 equ DESCALE( 226735879,30-CONST_BITS) ; FIX(0.211164243)

56 F_0_509 equ DESCALE( 547388834,30-CONST_BITS) ; FIX(0.509795579)

57 F_0_601 equ DESCALE( 645689155,30-CONST_BITS) ; FIX(0.601344887)

58 F_0_720 equ DESCALE( 774124714,30-CONST_BITS) ; FIX(0.720959822)

59 F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865)

60 F_0_850 equ DESCALE( 913142361,30-CONST_BITS) ; FIX(0.850430095)

61 F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223)

62 F_1_061 equ DESCALE(1139878239,30-CONST_BITS) ; FIX(1.061594337)

63 F_1_272 equ DESCALE(1366614119,30-CONST_BITS) ; FIX(1.272758580)

64 F_1_451 equ DESCALE(1558831516,30-CONST_BITS) ; FIX(1.451774981)

65 F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065)

66 F_2_172 equ DESCALE(2332956230,30-CONST_BITS) ; FIX(2.172734803)

67 F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447)

68 F_3_624 equ DESCALE(3891787747,30-CONST_BITS) ; FIX(3.624509785)

69 %endif

70

71 ; --------------------------------------------------------------------------

72 SECTION SEG_CONST

73

74 alignz 16

75 global EXTN(jconst_idct_red_sse2) PRIVATE

76

77 EXTN(jconst_idct_red_sse2):

78

79 PW_F184_MF076 times 4 dw F_1_847,-F_0_765

80 PW_F256_F089 times 4 dw F_2_562, F_0_899

81 PW_F106_MF217 times 4 dw F_1_061,-F_2_172

82 PW_MF060_MF050 times 4 dw -F_0_601,-F_0_509

83 PW_F145_MF021 times 4 dw F_1_451,-F_0_211

84 PW_F362_MF127 times 4 dw F_3_624,-F_1_272

85 PW_F085_MF072 times 4 dw F_0_850,-F_0_720

86 PD_DESCALE_P1_4 times 4 dd 1 << (DESCALE_P1_4-1)

87 PD_DESCALE_P2_4 times 4 dd 1 << (DESCALE_P2_4-1)

88 PD_DESCALE_P1_2 times 4 dd 1 << (DESCALE_P1_2-1)

89 PD_DESCALE_P2_2 times 4 dd 1 << (DESCALE_P2_2-1)

90 PB_CENTERJSAMP times 16 db CENTERJSAMPLE

91

92 alignz 16

93

94 ; --------------------------------------------------------------------------

95 SECTION SEG_TEXT

96 BITS 32

97 ;

98 ; Perform dequantization and inverse DCT on one block of coefficients,

99 ; producing a reduced-size 4x4 output block.

100 ;

101 ; GLOBAL(void)

102 ; jsimd_idct_4x4_sse2 (void * dct_table, JCOEFPTR coef_block,

103 ; JSAMPARRAY output_buf, JDIMENSION output_col)

104 ;

105

106 %define dct_table(b) (b)+8 ; void * dct_table

107 %define coef_block(b) (b)+12 ; JCOEFPTR coef_block

108 %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf

109 %define output_col(b) (b)+20 ; JDIMENSION output_col

110

111 %define original_ebp ebp+0

112 %define wk(i) ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]

113 %define WK_NUM 2

114

115 align 16

116 global EXTN(jsimd_idct_4x4_sse2) PRIVATE

117

118 EXTN(jsimd_idct_4x4_sse2):

119 push ebp

120 mov eax,esp ; eax = original ebp

121 sub esp, byte 4

122 and esp, byte (-SIZEOF_XMMWORD) ; align to 128 bits

123 mov [esp],eax

124 mov ebp,esp ; ebp = aligned ebp

125 lea esp, [wk(0)]

126 pushpic ebx

127 ; push ecx ; unused

128 ; push edx ; need not be preserved

129 push esi

130 push edi

131

132 get_GOT ebx ; get GOT address

133

134 ; ---- Pass 1: process columns from input.

135

136 ; mov eax, [original_ebp]

137 mov edx, POINTER [dct_table(eax)] ; quantptr

138 mov esi, JCOEFPTR [coef_block(eax)] ; inptr

139

140 %ifndef NO_ZERO_COLUMN_TEST_4X4_SSE2

141 mov eax, DWORD [DWBLOCK(1,0,esi,SIZEOF_JCOEF)]

142 or eax, DWORD [DWBLOCK(2,0,esi,SIZEOF_JCOEF)]

143 jnz short .columnDCT

144

145 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]

146 movdqa xmm1, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]

147 por xmm0, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]

148 por xmm1, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]

149 por xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]

150 por xmm1, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]

151 por xmm0,xmm1

152 packsswb xmm0,xmm0

153 packsswb xmm0,xmm0

154 movd eax,xmm0

155 test eax,eax

156 jnz short .columnDCT

157

158 ; -- AC terms all zero

159

160 movdqa xmm0, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]

161 pmullw xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

162

163 psllw xmm0,PASS1_BITS

164

165 movdqa xmm3,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07)

166 punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03)

167 punpckhwd xmm3,xmm3 ; xmm3=(04 04 05 05 06 06 07 07)

168

169 pshufd xmm1,xmm0,0x50 ; xmm1=[col0 col1]=(00 00 00 00 01 01 01 01)

170 pshufd xmm0,xmm0,0xFA ; xmm0=[col2 col3]=(02 02 02 02 03 03 03 03)

171 pshufd xmm6,xmm3,0x50 ; xmm6=[col4 col5]=(04 04 04 04 05 05 05 05)

172 pshufd xmm3,xmm3,0xFA ; xmm3=[col6 col7]=(06 06 06 06 07 07 07 07)

173

174 jmp near .column_end

175 alignx 16,7

176 %endif

177 .columnDCT:

178

179 ; -- Odd part

180

181 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]

182 movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]

183 pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

184 pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

185 movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]

186 movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]

187 pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

188 pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

189

190 movdqa xmm4,xmm0

191 movdqa xmm5,xmm0

192 punpcklwd xmm4,xmm1

193 punpckhwd xmm5,xmm1

194 movdqa xmm0,xmm4

195 movdqa xmm1,xmm5

196 pmaddwd xmm4,[GOTOFF(ebx,PW_F256_F089)] ; xmm4=(tmp2L)

197 pmaddwd xmm5,[GOTOFF(ebx,PW_F256_F089)] ; xmm5=(tmp2H)

198 pmaddwd xmm0,[GOTOFF(ebx,PW_F106_MF217)] ; xmm0=(tmp0L)

199 pmaddwd xmm1,[GOTOFF(ebx,PW_F106_MF217)] ; xmm1=(tmp0H)

200

201 movdqa xmm6,xmm2

202 movdqa xmm7,xmm2

203 punpcklwd xmm6,xmm3

204 punpckhwd xmm7,xmm3

205 movdqa xmm2,xmm6

206 movdqa xmm3,xmm7

207 pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2L)

208 pmaddwd xmm7,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm7=(tmp2H)

209 pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0L)

210 pmaddwd xmm3,[GOTOFF(ebx,PW_F145_MF021)] ; xmm3=(tmp0H)

211

212 paddd xmm6,xmm4 ; xmm6=tmp2L

213 paddd xmm7,xmm5 ; xmm7=tmp2H

214 paddd xmm2,xmm0 ; xmm2=tmp0L

215 paddd xmm3,xmm1 ; xmm3=tmp0H

216

217 movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp0L

218 movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=tmp0H

219

220 ; -- Even part

221

222 movdqa xmm4, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]

223 movdqa xmm5, XMMWORD [XMMBLOCK(2,0,esi,SIZEOF_JCOEF)]

224 movdqa xmm0, XMMWORD [XMMBLOCK(6,0,esi,SIZEOF_JCOEF)]

225 pmullw xmm4, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

226 pmullw xmm5, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

227 pmullw xmm0, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

228

229 pxor xmm1,xmm1

230 pxor xmm2,xmm2

231 punpcklwd xmm1,xmm4 ; xmm1=tmp0L

232 punpckhwd xmm2,xmm4 ; xmm2=tmp0H

233 psrad xmm1,(16-CONST_BITS-1) ; psrad xmm1,16 & pslld xmm1,CONST_BITS +1

234 psrad xmm2,(16-CONST_BITS-1) ; psrad xmm2,16 & pslld xmm2,CONST_BITS +1

235

236 movdqa xmm3,xmm5 ; xmm5=in2=z2

237 punpcklwd xmm5,xmm0 ; xmm0=in6=z3

238 punpckhwd xmm3,xmm0

239 pmaddwd xmm5,[GOTOFF(ebx,PW_F184_MF076)] ; xmm5=tmp2L

240 pmaddwd xmm3,[GOTOFF(ebx,PW_F184_MF076)] ; xmm3=tmp2H

241

242 movdqa xmm4,xmm1

243 movdqa xmm0,xmm2

244 paddd xmm1,xmm5 ; xmm1=tmp10L

245 paddd xmm2,xmm3 ; xmm2=tmp10H

246 psubd xmm4,xmm5 ; xmm4=tmp12L

247 psubd xmm0,xmm3 ; xmm0=tmp12H

248

249 ; -- Final output stage

250

251 movdqa xmm5,xmm1

252 movdqa xmm3,xmm2

253 paddd xmm1,xmm6 ; xmm1=data0L

254 paddd xmm2,xmm7 ; xmm2=data0H

255 psubd xmm5,xmm6 ; xmm5=data3L

256 psubd xmm3,xmm7 ; xmm3=data3H

257

258 movdqa xmm6,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm6=[PD_DESCALE_P1_4]

259

260 paddd xmm1,xmm6

261 paddd xmm2,xmm6

262 psrad xmm1,DESCALE_P1_4

263 psrad xmm2,DESCALE_P1_4

264 paddd xmm5,xmm6

265 paddd xmm3,xmm6

266 psrad xmm5,DESCALE_P1_4

267 psrad xmm3,DESCALE_P1_4

268

269 packssdw xmm1,xmm2 ; xmm1=data0=(00 01 02 03 04 05 06 07)

270 packssdw xmm5,xmm3 ; xmm5=data3=(30 31 32 33 34 35 36 37)

271

272 movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp0L

273 movdqa xmm6, XMMWORD [wk(1)] ; xmm6=tmp0H

274

275 movdqa xmm2,xmm4

276 movdqa xmm3,xmm0

277 paddd xmm4,xmm7 ; xmm4=data1L

278 paddd xmm0,xmm6 ; xmm0=data1H

279 psubd xmm2,xmm7 ; xmm2=data2L

280 psubd xmm3,xmm6 ; xmm3=data2H

281

282 movdqa xmm7,[GOTOFF(ebx,PD_DESCALE_P1_4)] ; xmm7=[PD_DESCALE_P1_4]

283

284 paddd xmm4,xmm7

285 paddd xmm0,xmm7

286 psrad xmm4,DESCALE_P1_4

287 psrad xmm0,DESCALE_P1_4

288 paddd xmm2,xmm7

289 paddd xmm3,xmm7

290 psrad xmm2,DESCALE_P1_4

291 psrad xmm3,DESCALE_P1_4

292

293 packssdw xmm4,xmm0 ; xmm4=data1=(10 11 12 13 14 15 16 17)

294 packssdw xmm2,xmm3 ; xmm2=data2=(20 21 22 23 24 25 26 27)

295

296 movdqa xmm6,xmm1 ; transpose coefficients(phase 1)

297 punpcklwd xmm1,xmm4 ; xmm1=(00 10 01 11 02 12 03 13)

298 punpckhwd xmm6,xmm4 ; xmm6=(04 14 05 15 06 16 07 17)

299 movdqa xmm7,xmm2 ; transpose coefficients(phase 1)

300 punpcklwd xmm2,xmm5 ; xmm2=(20 30 21 31 22 32 23 33)

301 punpckhwd xmm7,xmm5 ; xmm7=(24 34 25 35 26 36 27 37)

302

303 movdqa xmm0,xmm1 ; transpose coefficients(phase 2)

304 punpckldq xmm1,xmm2 ; xmm1=[col0 col1]=(00 10 20 30 01 11 21 31)

305 punpckhdq xmm0,xmm2 ; xmm0=[col2 col3]=(02 12 22 32 03 13 23 33)

306 movdqa xmm3,xmm6 ; transpose coefficients(phase 2)

307 punpckldq xmm6,xmm7 ; xmm6=[col4 col5]=(04 14 24 34 05 15 25 35)

308 punpckhdq xmm3,xmm7 ; xmm3=[col6 col7]=(06 16 26 36 07 17 27 37)

309 .column_end:

310

311 ; -- Prefetch the next coefficient block

312

313 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 032]

314 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 132]

315 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 232]

316 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 332]

317

318 ; ---- Pass 2: process rows, store into output array.

319

320 mov eax, [original_ebp]

321 mov edi, JSAMPARRAY [output_buf(eax)] ; (JSAMPROW *)

322 mov eax, JDIMENSION [output_col(eax)]

323

324 ; -- Even part

325

326 pxor xmm4,xmm4

327 punpcklwd xmm4,xmm1 ; xmm4=tmp0

328 psrad xmm4,(16-CONST_BITS-1) ; psrad xmm4,16 & pslld xmm4,CONST_BITS +1

329

330 ; -- Odd part

331

332 punpckhwd xmm1,xmm0

333 punpckhwd xmm6,xmm3

334 movdqa xmm5,xmm1

335 movdqa xmm2,xmm6

336 pmaddwd xmm1,[GOTOFF(ebx,PW_F256_F089)] ; xmm1=(tmp2)

337 pmaddwd xmm6,[GOTOFF(ebx,PW_MF060_MF050)] ; xmm6=(tmp2)

338 pmaddwd xmm5,[GOTOFF(ebx,PW_F106_MF217)] ; xmm5=(tmp0)

339 pmaddwd xmm2,[GOTOFF(ebx,PW_F145_MF021)] ; xmm2=(tmp0)

340

341 paddd xmm6,xmm1 ; xmm6=tmp2

342 paddd xmm2,xmm5 ; xmm2=tmp0

343

344 ; -- Even part

345

346 punpcklwd xmm0,xmm3

347 pmaddwd xmm0,[GOTOFF(ebx,PW_F184_MF076)] ; xmm0=tmp2

348

349 movdqa xmm7,xmm4

350 paddd xmm4,xmm0 ; xmm4=tmp10

351 psubd xmm7,xmm0 ; xmm7=tmp12

352

353 ; -- Final output stage

354

355 movdqa xmm1,[GOTOFF(ebx,PD_DESCALE_P2_4)] ; xmm1=[PD_DESCALE_P2_4]

356

357 movdqa xmm5,xmm4

358 movdqa xmm3,xmm7

359 paddd xmm4,xmm6 ; xmm4=data0=(00 10 20 30)

360 paddd xmm7,xmm2 ; xmm7=data1=(01 11 21 31)

361 psubd xmm5,xmm6 ; xmm5=data3=(03 13 23 33)

362 psubd xmm3,xmm2 ; xmm3=data2=(02 12 22 32)

363

364 paddd xmm4,xmm1

365 paddd xmm7,xmm1

366 psrad xmm4,DESCALE_P2_4

367 psrad xmm7,DESCALE_P2_4

368 paddd xmm5,xmm1

369 paddd xmm3,xmm1

370 psrad xmm5,DESCALE_P2_4

371 psrad xmm3,DESCALE_P2_4

372

373 packssdw xmm4,xmm3 ; xmm4=(00 10 20 30 02 12 22 32)

374 packssdw xmm7,xmm5 ; xmm7=(01 11 21 31 03 13 23 33)

375

376 movdqa xmm0,xmm4 ; transpose coefficients(phase 1)

377 punpcklwd xmm4,xmm7 ; xmm4=(00 01 10 11 20 21 30 31)

378 punpckhwd xmm0,xmm7 ; xmm0=(02 03 12 13 22 23 32 33)

379

380 movdqa xmm6,xmm4 ; transpose coefficients(phase 2)

381 punpckldq xmm4,xmm0 ; xmm4=(00 01 02 03 10 11 12 13)

382 punpckhdq xmm6,xmm0 ; xmm6=(20 21 22 23 30 31 32 33)

383

384 packsswb xmm4,xmm6 ; xmm4=(00 01 02 03 10 11 12 13 20 ..)

385 paddb xmm4,[GOTOFF(ebx,PB_CENTERJSAMP)]

386

387 pshufd xmm2,xmm4,0x39 ; xmm2=(10 11 12 13 20 21 22 23 30 ..)

388 pshufd xmm1,xmm4,0x4E ; xmm1=(20 21 22 23 30 31 32 33 00 ..)

389 pshufd xmm3,xmm4,0x93 ; xmm3=(30 31 32 33 00 01 02 03 10 ..)

390

391 mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]

392 mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]

393 movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm4

394 movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm2

395 mov edx, JSAMPROW [edi+2*SIZEOF_JSAMPROW]

396 mov esi, JSAMPROW [edi+3*SIZEOF_JSAMPROW]

397 movd XMM_DWORD [edx+eax*SIZEOF_JSAMPLE], xmm1

398 movd XMM_DWORD [esi+eax*SIZEOF_JSAMPLE], xmm3

399

400 pop edi

401 pop esi

402 ; pop edx ; need not be preserved

403 ; pop ecx ; unused

404 poppic ebx

405 mov esp,ebp ; esp <- aligned ebp

406 pop esp ; esp <- original ebp

407 pop ebp

408 ret

409

410

411 ; --------------------------------------------------------------------------

412 ;

413 ; Perform dequantization and inverse DCT on one block of coefficients,

414 ; producing a reduced-size 2x2 output block.

415 ;

416 ; GLOBAL(void)

417 ; jsimd_idct_2x2_sse2 (void * dct_table, JCOEFPTR coef_block,

418 ; JSAMPARRAY output_buf, JDIMENSION output_col)

419 ;

420

421 %define dct_table(b) (b)+8 ; void * dct_table

422 %define coef_block(b) (b)+12 ; JCOEFPTR coef_block

423 %define output_buf(b) (b)+16 ; JSAMPARRAY output_buf

424 %define output_col(b) (b)+20 ; JDIMENSION output_col

425

426 align 16

427 global EXTN(jsimd_idct_2x2_sse2) PRIVATE

428

429 EXTN(jsimd_idct_2x2_sse2):

430 push ebp

431 mov ebp,esp

432 push ebx

433 ; push ecx ; need not be preserved

434 ; push edx ; need not be preserved

435 push esi

436 push edi

437

438 get_GOT ebx ; get GOT address

439

440 ; ---- Pass 1: process columns from input.

441

442 mov edx, POINTER [dct_table(ebp)] ; quantptr

443 mov esi, JCOEFPTR [coef_block(ebp)] ; inptr

444

445 ; \| input: \| result: \|

446 ; \| 00 01 03 05 ** 07 \| \|

447 ; \| 10 11 13 15 ** 17 \| \|

448 ; \| \| \|

449 ; \| 30 31 33 35 ** 37 \| A0 A1 A3 A5 A7 \|

450 ; \| \| B0 B1 B3 B5 B7 \|

451 ; \| 50 51 53 55 ** 57 \| \|

452 ; \| \| \|

453 ; \| 70 71 73 75 ** 77 \| \|

454

455 ; -- Odd part

456

457 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,esi,SIZEOF_JCOEF)]

458 movdqa xmm1, XMMWORD [XMMBLOCK(3,0,esi,SIZEOF_JCOEF)]

459 pmullw xmm0, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

460 pmullw xmm1, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

461 movdqa xmm2, XMMWORD [XMMBLOCK(5,0,esi,SIZEOF_JCOEF)]

462 movdqa xmm3, XMMWORD [XMMBLOCK(7,0,esi,SIZEOF_JCOEF)]

463 pmullw xmm2, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

464 pmullw xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

465

466 ; xmm0=(10 11 13 15 17), xmm1=(30 31 33 35 37)

467 ; xmm2=(50 51 53 55 57), xmm3=(70 71 73 75 77)

468

469 pcmpeqd xmm7,xmm7

470 pslld xmm7,WORD_BIT ; xmm7={0x0000 0xFFFF 0x0000 0xFFFF ..}

471

472 movdqa xmm4,xmm0 ; xmm4=(10 11 13 15 ** 17)

473 movdqa xmm5,xmm2 ; xmm5=(50 51 53 55 ** 57)

474 punpcklwd xmm4,xmm1 ; xmm4=(10 30 11 31 13 33)

475 punpcklwd xmm5,xmm3 ; xmm5=(50 70 51 71 53 73)

476 pmaddwd xmm4,[GOTOFF(ebx,PW_F362_MF127)]

477 pmaddwd xmm5,[GOTOFF(ebx,PW_F085_MF072)]

478

479 psrld xmm0,WORD_BIT ; xmm0=(11 -- 13 -- 15 -- 17 --)

480 pand xmm1,xmm7 ; xmm1=(-- 31 -- 33 -- 35 -- 37)

481 psrld xmm2,WORD_BIT ; xmm2=(51 -- 53 -- 55 -- 57 --)

482 pand xmm3,xmm7 ; xmm3=(-- 71 -- 73 -- 75 -- 77)

483 por xmm0,xmm1 ; xmm0=(11 31 13 33 15 35 17 37)

484 por xmm2,xmm3 ; xmm2=(51 71 53 73 55 75 57 77)

485 pmaddwd xmm0,[GOTOFF(ebx,PW_F362_MF127)]

486 pmaddwd xmm2,[GOTOFF(ebx,PW_F085_MF072)]

487

488 paddd xmm4,xmm5 ; xmm4=tmp0[col0 col1 **** col3]

489 paddd xmm0,xmm2 ; xmm0=tmp0[col1 col3 col5 col7]

490

491 ; -- Even part

492

493 movdqa xmm6, XMMWORD [XMMBLOCK(0,0,esi,SIZEOF_JCOEF)]

494 pmullw xmm6, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_ISLOW_MULT_TYPE)]

495

496 ; xmm6=(00 01 03 05 ** 07)

497

498 movdqa xmm1,xmm6 ; xmm1=(00 01 03 05 ** 07)

499 pslld xmm6,WORD_BIT ; xmm6=(-- 00 -- -- -- **)

500 pand xmm1,xmm7 ; xmm1=(-- 01 -- 03 -- 05 -- 07)

501 psrad xmm6,(WORD_BIT-CONST_BITS-2) ; xmm6=tmp10[col0 ** **]

502 psrad xmm1,(WORD_BIT-CONST_BITS-2) ; xmm1=tmp10[col1 col3 col5 col7]

503

504 ; -- Final output stage

505

506 movdqa xmm3,xmm6

507 movdqa xmm5,xmm1

508 paddd xmm6,xmm4 ; xmm6=data0[col0 ** ]=(A0 )

509 paddd xmm1,xmm0 ; xmm1=data0[col1 col3 col5 col7]=(A1 A3 A5 A7)

510 psubd xmm3,xmm4 ; xmm3=data1[col0 ** ]=(B0 )

511 psubd xmm5,xmm0 ; xmm5=data1[col1 col3 col5 col7]=(B1 B3 B5 B7)

512

513 movdqa xmm2,[GOTOFF(ebx,PD_DESCALE_P1_2)] ; xmm2=[PD_DESCALE_P1_2]

514

515 punpckldq xmm6,xmm3 ; xmm6=(A0 B0 )

516

517 movdqa xmm7,xmm1

518 punpcklqdq xmm1,xmm5 ; xmm1=(A1 A3 B1 B3)

519 punpckhqdq xmm7,xmm5 ; xmm7=(A5 A7 B5 B7)

520

521 paddd xmm6,xmm2

522 psrad xmm6,DESCALE_P1_2

523

524 paddd xmm1,xmm2

525 paddd xmm7,xmm2

526 psrad xmm1,DESCALE_P1_2

527 psrad xmm7,DESCALE_P1_2

528

529 ; -- Prefetch the next coefficient block

530

531 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 032]

532 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 132]

533 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 232]

534 prefetchnta [esi + DCTSIZE2SIZEOF_JCOEF + 332]

535

536 ; ---- Pass 2: process rows, store into output array.

537

538 mov edi, JSAMPARRAY [output_buf(ebp)] ; (JSAMPROW *)

539 mov eax, JDIMENSION [output_col(ebp)]

540

541 ; \| input:\| result:\|

542 ; \| A0 B0 \| \|

543 ; \| A1 B1 \| C0 C1 \|

544 ; \| A3 B3 \| D0 D1 \|

545 ; \| A5 B5 \| \|

546 ; \| A7 B7 \| \|

547

548 ; -- Odd part

549

550 packssdw xmm1,xmm1 ; xmm1=(A1 A3 B1 B3 A1 A3 B1 B3)

551 packssdw xmm7,xmm7 ; xmm7=(A5 A7 B5 B7 A5 A7 B5 B7)

552 pmaddwd xmm1,[GOTOFF(ebx,PW_F362_MF127)]

553 pmaddwd xmm7,[GOTOFF(ebx,PW_F085_MF072)]

554

555 paddd xmm1,xmm7 ; xmm1=tmp0[row0 row1 row0 row1]

556

557 ; -- Even part

558

559 pslld xmm6,(CONST_BITS+2) ; xmm6=tmp10[row0 row1 ** **]

560

561 ; -- Final output stage

562

563 movdqa xmm4,xmm6

564 paddd xmm6,xmm1 ; xmm6=data0[row0 row1 ** ]=(C0 C1 **)

565 psubd xmm4,xmm1 ; xmm4=data1[row0 row1 ** ]=(D0 D1 **)

566

567 punpckldq xmm6,xmm4 ; xmm6=(C0 D0 C1 D1)

568

569 paddd xmm6,[GOTOFF(ebx,PD_DESCALE_P2_2)]

570 psrad xmm6,DESCALE_P2_2

571

572 packssdw xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1)

573 packsswb xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1 ..)

574 paddb xmm6,[GOTOFF(ebx,PB_CENTERJSAMP)]

575

576 pextrw ebx,xmm6,0x00 ; ebx=(C0 D0 -- --)

577 pextrw ecx,xmm6,0x01 ; ecx=(C1 D1 -- --)

578

579 mov edx, JSAMPROW [edi+0*SIZEOF_JSAMPROW]

580 mov esi, JSAMPROW [edi+1*SIZEOF_JSAMPROW]

581 mov WORD [edx+eax*SIZEOF_JSAMPLE], bx

582 mov WORD [esi+eax*SIZEOF_JSAMPLE], cx

583

584 pop edi

585 pop esi

586 ; pop edx ; need not be preserved

587 ; pop ecx ; need not be preserved

588 pop ebx

589 pop ebp

590 ret

591

592 ; For some reason, the OS X linker does not honor the request to align the

593 ; segment unless we do this.

594 align 16

OLD	NEW

« no previous file with comments | « simd/jiss2int-64.asm ('k') | simd/jiss2red-64.asm » ('j') | no next file with comments »