| OLD | NEW |
|---|
| (Empty) | |
| 1 ; |
| 2 ; jidctred.asm - reduced-size IDCT (64-bit SSE2) |
| 3 ; |
| 4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB |
| 5 ; Copyright 2009 D. R. Commander |
| 6 ; |
| 7 ; Based on |
| 8 ; x86 SIMD extension for IJG JPEG library |
| 9 ; Copyright (C) 1999-2006, MIYASAKA Masaru. |
| 10 ; For conditions of distribution and use, see copyright notice in jsimdext.inc |
| 11 ; |
| 12 ; This file should be assembled with NASM (Netwide Assembler), |
| 13 ; can *not* be assembled with Microsoft's MASM or any compatible |
| 14 ; assembler (including Borland's Turbo Assembler). |
| 15 ; NASM is available from http://nasm.sourceforge.net/ or |
| 16 ; http://sourceforge.net/project/showfiles.php?group_id=6208 |
| 17 ; |
| 18 ; This file contains inverse-DCT routines that produce reduced-size |
| 19 ; output: either 4x4 or 2x2 pixels from an 8x8 DCT block. |
| 20 ; The following code is based directly on the IJG's original jidctred.c; |
| 21 ; see the jidctred.c for more details. |
| 22 ; |
| 23 ; [TAB8] |
| 24 |
| 25 %include "jsimdext.inc" |
| 26 %include "jdct.inc" |
| 27 |
| 28 ; -------------------------------------------------------------------------- |
| 29 |
| 30 %define CONST_BITS 13 |
| 31 %define PASS1_BITS 2 |
| 32 |
| 33 %define DESCALE_P1_4 (CONST_BITS-PASS1_BITS+1) |
| 34 %define DESCALE_P2_4 (CONST_BITS+PASS1_BITS+3+1) |
| 35 %define DESCALE_P1_2 (CONST_BITS-PASS1_BITS+2) |
| 36 %define DESCALE_P2_2 (CONST_BITS+PASS1_BITS+3+2) |
| 37 |
| 38 %if CONST_BITS == 13 |
| 39 F_0_211 equ 1730 ; FIX(0.211164243) |
| 40 F_0_509 equ 4176 ; FIX(0.509795579) |
| 41 F_0_601 equ 4926 ; FIX(0.601344887) |
| 42 F_0_720 equ 5906 ; FIX(0.720959822) |
| 43 F_0_765 equ 6270 ; FIX(0.765366865) |
| 44 F_0_850 equ 6967 ; FIX(0.850430095) |
| 45 F_0_899 equ 7373 ; FIX(0.899976223) |
| 46 F_1_061 equ 8697 ; FIX(1.061594337) |
| 47 F_1_272 equ 10426 ; FIX(1.272758580) |
| 48 F_1_451 equ 11893 ; FIX(1.451774981) |
| 49 F_1_847 equ 15137 ; FIX(1.847759065) |
| 50 F_2_172 equ 17799 ; FIX(2.172734803) |
| 51 F_2_562 equ 20995 ; FIX(2.562915447) |
| 52 F_3_624 equ 29692 ; FIX(3.624509785) |
| 53 %else |
| 54 ; NASM cannot do compile-time arithmetic on floating-point constants. |
| 55 %define DESCALE(x,n) (((x)+(1<<((n)-1)))>>(n)) |
| 56 F_0_211 equ DESCALE( 226735879,30-CONST_BITS) ; FIX(0.211164243) |
| 57 F_0_509 equ DESCALE( 547388834,30-CONST_BITS) ; FIX(0.509795579) |
| 58 F_0_601 equ DESCALE( 645689155,30-CONST_BITS) ; FIX(0.601344887) |
| 59 F_0_720 equ DESCALE( 774124714,30-CONST_BITS) ; FIX(0.720959822) |
| 60 F_0_765 equ DESCALE( 821806413,30-CONST_BITS) ; FIX(0.765366865) |
| 61 F_0_850 equ DESCALE( 913142361,30-CONST_BITS) ; FIX(0.850430095) |
| 62 F_0_899 equ DESCALE( 966342111,30-CONST_BITS) ; FIX(0.899976223) |
| 63 F_1_061 equ DESCALE(1139878239,30-CONST_BITS) ; FIX(1.061594337) |
| 64 F_1_272 equ DESCALE(1366614119,30-CONST_BITS) ; FIX(1.272758580) |
| 65 F_1_451 equ DESCALE(1558831516,30-CONST_BITS) ; FIX(1.451774981) |
| 66 F_1_847 equ DESCALE(1984016188,30-CONST_BITS) ; FIX(1.847759065) |
| 67 F_2_172 equ DESCALE(2332956230,30-CONST_BITS) ; FIX(2.172734803) |
| 68 F_2_562 equ DESCALE(2751909506,30-CONST_BITS) ; FIX(2.562915447) |
| 69 F_3_624 equ DESCALE(3891787747,30-CONST_BITS) ; FIX(3.624509785) |
| 70 %endif |
| 71 |
| 72 ; -------------------------------------------------------------------------- |
| 73 SECTION SEG_CONST |
| 74 |
| 75 alignz 16 |
| 76 global EXTN(jconst_idct_red_sse2) |
| 77 |
| 78 EXTN(jconst_idct_red_sse2): |
| 79 |
| 80 PW_F184_MF076 times 4 dw F_1_847,-F_0_765 |
| 81 PW_F256_F089 times 4 dw F_2_562, F_0_899 |
| 82 PW_F106_MF217 times 4 dw F_1_061,-F_2_172 |
| 83 PW_MF060_MF050 times 4 dw -F_0_601,-F_0_509 |
| 84 PW_F145_MF021 times 4 dw F_1_451,-F_0_211 |
| 85 PW_F362_MF127 times 4 dw F_3_624,-F_1_272 |
| 86 PW_F085_MF072 times 4 dw F_0_850,-F_0_720 |
| 87 PD_DESCALE_P1_4 times 4 dd 1 << (DESCALE_P1_4-1) |
| 88 PD_DESCALE_P2_4 times 4 dd 1 << (DESCALE_P2_4-1) |
| 89 PD_DESCALE_P1_2 times 4 dd 1 << (DESCALE_P1_2-1) |
| 90 PD_DESCALE_P2_2 times 4 dd 1 << (DESCALE_P2_2-1) |
| 91 PB_CENTERJSAMP times 16 db CENTERJSAMPLE |
| 92 |
| 93 alignz 16 |
| 94 |
| 95 ; -------------------------------------------------------------------------- |
| 96 SECTION SEG_TEXT |
| 97 BITS 64 |
| 98 ; |
| 99 ; Perform dequantization and inverse DCT on one block of coefficients, |
| 100 ; producing a reduced-size 4x4 output block. |
| 101 ; |
| 102 ; GLOBAL(void) |
| 103 ; jsimd_idct_4x4_sse2 (void *dct_table, JCOEFPTR coef_block, |
| 104 ; JSAMPARRAY output_buf, JDIMENSION output_col) |
| 105 ; |
| 106 |
| 107 ; r10 = void *dct_table |
| 108 ; r11 = JCOEFPTR coef_block |
| 109 ; r12 = JSAMPARRAY output_buf |
| 110 ; r13 = JDIMENSION output_col |
| 111 |
| 112 %define original_rbp rbp+0 |
| 113 %define wk(i) rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM] |
| 114 %define WK_NUM 2 |
| 115 |
| 116 align 16 |
| 117 global EXTN(jsimd_idct_4x4_sse2) |
| 118 |
| 119 EXTN(jsimd_idct_4x4_sse2): |
| 120 push rbp |
| 121 mov rax,rsp ; rax = original rbp |
| 122 sub rsp, byte 4 |
| 123 and rsp, byte (-SIZEOF_XMMWORD) ; align to 128 bits |
| 124 mov [rsp],rax |
| 125 mov rbp,rsp ; rbp = aligned rbp |
| 126 lea rsp, [wk(0)] |
| 127 collect_args |
| 128 |
| 129 ; ---- Pass 1: process columns from input. |
| 130 |
| 131 mov rdx, r10 ; quantptr |
| 132 mov rsi, r11 ; inptr |
| 133 |
| 134 %ifndef NO_ZERO_COLUMN_TEST_4X4_SSE2 |
| 135 mov eax, DWORD [DWBLOCK(1,0,rsi,SIZEOF_JCOEF)] |
| 136 or eax, DWORD [DWBLOCK(2,0,rsi,SIZEOF_JCOEF)] |
| 137 jnz short .columnDCT |
| 138 |
| 139 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)] |
| 140 movdqa xmm1, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)] |
| 141 por xmm0, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)] |
| 142 por xmm1, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)] |
| 143 por xmm0, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)] |
| 144 por xmm1, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)] |
| 145 por xmm0,xmm1 |
| 146 packsswb xmm0,xmm0 |
| 147 packsswb xmm0,xmm0 |
| 148 movd eax,xmm0 |
| 149 test rax,rax |
| 150 jnz short .columnDCT |
| 151 |
| 152 ; -- AC terms all zero |
| 153 |
| 154 movdqa xmm0, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)] |
| 155 pmullw xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 156 |
| 157 psllw xmm0,PASS1_BITS |
| 158 |
| 159 movdqa xmm3,xmm0 ; xmm0=in0=(00 01 02 03 04 05 06 07) |
| 160 punpcklwd xmm0,xmm0 ; xmm0=(00 00 01 01 02 02 03 03) |
| 161 punpckhwd xmm3,xmm3 ; xmm3=(04 04 05 05 06 06 07 07) |
| 162 |
| 163 pshufd xmm1,xmm0,0x50 ; xmm1=[col0 col1]=(00 00 00 00 01 01 01 01) |
| 164 pshufd xmm0,xmm0,0xFA ; xmm0=[col2 col3]=(02 02 02 02 03 03 03 03) |
| 165 pshufd xmm6,xmm3,0x50 ; xmm6=[col4 col5]=(04 04 04 04 05 05 05 05) |
| 166 pshufd xmm3,xmm3,0xFA ; xmm3=[col6 col7]=(06 06 06 06 07 07 07 07) |
| 167 |
| 168 jmp near .column_end |
| 169 %endif |
| 170 .columnDCT: |
| 171 |
| 172 ; -- Odd part |
| 173 |
| 174 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)] |
| 175 movdqa xmm1, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)] |
| 176 pmullw xmm0, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 177 pmullw xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 178 movdqa xmm2, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)] |
| 179 movdqa xmm3, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)] |
| 180 pmullw xmm2, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 181 pmullw xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 182 |
| 183 movdqa xmm4,xmm0 |
| 184 movdqa xmm5,xmm0 |
| 185 punpcklwd xmm4,xmm1 |
| 186 punpckhwd xmm5,xmm1 |
| 187 movdqa xmm0,xmm4 |
| 188 movdqa xmm1,xmm5 |
| 189 pmaddwd xmm4,[rel PW_F256_F089] ; xmm4=(tmp2L) |
| 190 pmaddwd xmm5,[rel PW_F256_F089] ; xmm5=(tmp2H) |
| 191 pmaddwd xmm0,[rel PW_F106_MF217] ; xmm0=(tmp0L) |
| 192 pmaddwd xmm1,[rel PW_F106_MF217] ; xmm1=(tmp0H) |
| 193 |
| 194 movdqa xmm6,xmm2 |
| 195 movdqa xmm7,xmm2 |
| 196 punpcklwd xmm6,xmm3 |
| 197 punpckhwd xmm7,xmm3 |
| 198 movdqa xmm2,xmm6 |
| 199 movdqa xmm3,xmm7 |
| 200 pmaddwd xmm6,[rel PW_MF060_MF050] ; xmm6=(tmp2L) |
| 201 pmaddwd xmm7,[rel PW_MF060_MF050] ; xmm7=(tmp2H) |
| 202 pmaddwd xmm2,[rel PW_F145_MF021] ; xmm2=(tmp0L) |
| 203 pmaddwd xmm3,[rel PW_F145_MF021] ; xmm3=(tmp0H) |
| 204 |
| 205 paddd xmm6,xmm4 ; xmm6=tmp2L |
| 206 paddd xmm7,xmm5 ; xmm7=tmp2H |
| 207 paddd xmm2,xmm0 ; xmm2=tmp0L |
| 208 paddd xmm3,xmm1 ; xmm3=tmp0H |
| 209 |
| 210 movdqa XMMWORD [wk(0)], xmm2 ; wk(0)=tmp0L |
| 211 movdqa XMMWORD [wk(1)], xmm3 ; wk(1)=tmp0H |
| 212 |
| 213 ; -- Even part |
| 214 |
| 215 movdqa xmm4, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)] |
| 216 movdqa xmm5, XMMWORD [XMMBLOCK(2,0,rsi,SIZEOF_JCOEF)] |
| 217 movdqa xmm0, XMMWORD [XMMBLOCK(6,0,rsi,SIZEOF_JCOEF)] |
| 218 pmullw xmm4, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 219 pmullw xmm5, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 220 pmullw xmm0, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 221 |
| 222 pxor xmm1,xmm1 |
| 223 pxor xmm2,xmm2 |
| 224 punpcklwd xmm1,xmm4 ; xmm1=tmp0L |
| 225 punpckhwd xmm2,xmm4 ; xmm2=tmp0H |
| 226 psrad xmm1,(16-CONST_BITS-1) ; psrad xmm1,16 & pslld xmm1,CONST_BITS
+1 |
| 227 psrad xmm2,(16-CONST_BITS-1) ; psrad xmm2,16 & pslld xmm2,CONST_BITS
+1 |
| 228 |
| 229 movdqa xmm3,xmm5 ; xmm5=in2=z2 |
| 230 punpcklwd xmm5,xmm0 ; xmm0=in6=z3 |
| 231 punpckhwd xmm3,xmm0 |
| 232 pmaddwd xmm5,[rel PW_F184_MF076] ; xmm5=tmp2L |
| 233 pmaddwd xmm3,[rel PW_F184_MF076] ; xmm3=tmp2H |
| 234 |
| 235 movdqa xmm4,xmm1 |
| 236 movdqa xmm0,xmm2 |
| 237 paddd xmm1,xmm5 ; xmm1=tmp10L |
| 238 paddd xmm2,xmm3 ; xmm2=tmp10H |
| 239 psubd xmm4,xmm5 ; xmm4=tmp12L |
| 240 psubd xmm0,xmm3 ; xmm0=tmp12H |
| 241 |
| 242 ; -- Final output stage |
| 243 |
| 244 movdqa xmm5,xmm1 |
| 245 movdqa xmm3,xmm2 |
| 246 paddd xmm1,xmm6 ; xmm1=data0L |
| 247 paddd xmm2,xmm7 ; xmm2=data0H |
| 248 psubd xmm5,xmm6 ; xmm5=data3L |
| 249 psubd xmm3,xmm7 ; xmm3=data3H |
| 250 |
| 251 movdqa xmm6,[rel PD_DESCALE_P1_4] ; xmm6=[rel PD_DESCALE_P1_4] |
| 252 |
| 253 paddd xmm1,xmm6 |
| 254 paddd xmm2,xmm6 |
| 255 psrad xmm1,DESCALE_P1_4 |
| 256 psrad xmm2,DESCALE_P1_4 |
| 257 paddd xmm5,xmm6 |
| 258 paddd xmm3,xmm6 |
| 259 psrad xmm5,DESCALE_P1_4 |
| 260 psrad xmm3,DESCALE_P1_4 |
| 261 |
| 262 packssdw xmm1,xmm2 ; xmm1=data0=(00 01 02 03 04 05 06 07) |
| 263 packssdw xmm5,xmm3 ; xmm5=data3=(30 31 32 33 34 35 36 37) |
| 264 |
| 265 movdqa xmm7, XMMWORD [wk(0)] ; xmm7=tmp0L |
| 266 movdqa xmm6, XMMWORD [wk(1)] ; xmm6=tmp0H |
| 267 |
| 268 movdqa xmm2,xmm4 |
| 269 movdqa xmm3,xmm0 |
| 270 paddd xmm4,xmm7 ; xmm4=data1L |
| 271 paddd xmm0,xmm6 ; xmm0=data1H |
| 272 psubd xmm2,xmm7 ; xmm2=data2L |
| 273 psubd xmm3,xmm6 ; xmm3=data2H |
| 274 |
| 275 movdqa xmm7,[rel PD_DESCALE_P1_4] ; xmm7=[rel PD_DESCALE_P1_4] |
| 276 |
| 277 paddd xmm4,xmm7 |
| 278 paddd xmm0,xmm7 |
| 279 psrad xmm4,DESCALE_P1_4 |
| 280 psrad xmm0,DESCALE_P1_4 |
| 281 paddd xmm2,xmm7 |
| 282 paddd xmm3,xmm7 |
| 283 psrad xmm2,DESCALE_P1_4 |
| 284 psrad xmm3,DESCALE_P1_4 |
| 285 |
| 286 packssdw xmm4,xmm0 ; xmm4=data1=(10 11 12 13 14 15 16 17) |
| 287 packssdw xmm2,xmm3 ; xmm2=data2=(20 21 22 23 24 25 26 27) |
| 288 |
| 289 movdqa xmm6,xmm1 ; transpose coefficients(phase 1) |
| 290 punpcklwd xmm1,xmm4 ; xmm1=(00 10 01 11 02 12 03 13) |
| 291 punpckhwd xmm6,xmm4 ; xmm6=(04 14 05 15 06 16 07 17) |
| 292 movdqa xmm7,xmm2 ; transpose coefficients(phase 1) |
| 293 punpcklwd xmm2,xmm5 ; xmm2=(20 30 21 31 22 32 23 33) |
| 294 punpckhwd xmm7,xmm5 ; xmm7=(24 34 25 35 26 36 27 37) |
| 295 |
| 296 movdqa xmm0,xmm1 ; transpose coefficients(phase 2) |
| 297 punpckldq xmm1,xmm2 ; xmm1=[col0 col1]=(00 10 20 30 01 11 21 31) |
| 298 punpckhdq xmm0,xmm2 ; xmm0=[col2 col3]=(02 12 22 32 03 13 23 33) |
| 299 movdqa xmm3,xmm6 ; transpose coefficients(phase 2) |
| 300 punpckldq xmm6,xmm7 ; xmm6=[col4 col5]=(04 14 24 34 05 15 25 35) |
| 301 punpckhdq xmm3,xmm7 ; xmm3=[col6 col7]=(06 16 26 36 07 17 27 37) |
| 302 .column_end: |
| 303 |
| 304 ; -- Prefetch the next coefficient block |
| 305 |
| 306 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 0*32] |
| 307 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 1*32] |
| 308 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 2*32] |
| 309 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 3*32] |
| 310 |
| 311 ; ---- Pass 2: process rows, store into output array. |
| 312 |
| 313 mov rax, [original_rbp] |
| 314 mov rdi, r12 ; (JSAMPROW *) |
| 315 mov eax, r13d |
| 316 |
| 317 ; -- Even part |
| 318 |
| 319 pxor xmm4,xmm4 |
| 320 punpcklwd xmm4,xmm1 ; xmm4=tmp0 |
| 321 psrad xmm4,(16-CONST_BITS-1) ; psrad xmm4,16 & pslld xmm4,CONST_BITS
+1 |
| 322 |
| 323 ; -- Odd part |
| 324 |
| 325 punpckhwd xmm1,xmm0 |
| 326 punpckhwd xmm6,xmm3 |
| 327 movdqa xmm5,xmm1 |
| 328 movdqa xmm2,xmm6 |
| 329 pmaddwd xmm1,[rel PW_F256_F089] ; xmm1=(tmp2) |
| 330 pmaddwd xmm6,[rel PW_MF060_MF050] ; xmm6=(tmp2) |
| 331 pmaddwd xmm5,[rel PW_F106_MF217] ; xmm5=(tmp0) |
| 332 pmaddwd xmm2,[rel PW_F145_MF021] ; xmm2=(tmp0) |
| 333 |
| 334 paddd xmm6,xmm1 ; xmm6=tmp2 |
| 335 paddd xmm2,xmm5 ; xmm2=tmp0 |
| 336 |
| 337 ; -- Even part |
| 338 |
| 339 punpcklwd xmm0,xmm3 |
| 340 pmaddwd xmm0,[rel PW_F184_MF076] ; xmm0=tmp2 |
| 341 |
| 342 movdqa xmm7,xmm4 |
| 343 paddd xmm4,xmm0 ; xmm4=tmp10 |
| 344 psubd xmm7,xmm0 ; xmm7=tmp12 |
| 345 |
| 346 ; -- Final output stage |
| 347 |
| 348 movdqa xmm1,[rel PD_DESCALE_P2_4] ; xmm1=[rel PD_DESCALE_P2_4] |
| 349 |
| 350 movdqa xmm5,xmm4 |
| 351 movdqa xmm3,xmm7 |
| 352 paddd xmm4,xmm6 ; xmm4=data0=(00 10 20 30) |
| 353 paddd xmm7,xmm2 ; xmm7=data1=(01 11 21 31) |
| 354 psubd xmm5,xmm6 ; xmm5=data3=(03 13 23 33) |
| 355 psubd xmm3,xmm2 ; xmm3=data2=(02 12 22 32) |
| 356 |
| 357 paddd xmm4,xmm1 |
| 358 paddd xmm7,xmm1 |
| 359 psrad xmm4,DESCALE_P2_4 |
| 360 psrad xmm7,DESCALE_P2_4 |
| 361 paddd xmm5,xmm1 |
| 362 paddd xmm3,xmm1 |
| 363 psrad xmm5,DESCALE_P2_4 |
| 364 psrad xmm3,DESCALE_P2_4 |
| 365 |
| 366 packssdw xmm4,xmm3 ; xmm4=(00 10 20 30 02 12 22 32) |
| 367 packssdw xmm7,xmm5 ; xmm7=(01 11 21 31 03 13 23 33) |
| 368 |
| 369 movdqa xmm0,xmm4 ; transpose coefficients(phase 1) |
| 370 punpcklwd xmm4,xmm7 ; xmm4=(00 01 10 11 20 21 30 31) |
| 371 punpckhwd xmm0,xmm7 ; xmm0=(02 03 12 13 22 23 32 33) |
| 372 |
| 373 movdqa xmm6,xmm4 ; transpose coefficients(phase 2) |
| 374 punpckldq xmm4,xmm0 ; xmm4=(00 01 02 03 10 11 12 13) |
| 375 punpckhdq xmm6,xmm0 ; xmm6=(20 21 22 23 30 31 32 33) |
| 376 |
| 377 packsswb xmm4,xmm6 ; xmm4=(00 01 02 03 10 11 12 13 20 ..) |
| 378 paddb xmm4,[rel PB_CENTERJSAMP] |
| 379 |
| 380 pshufd xmm2,xmm4,0x39 ; xmm2=(10 11 12 13 20 21 22 23 30 ..) |
| 381 pshufd xmm1,xmm4,0x4E ; xmm1=(20 21 22 23 30 31 32 33 00 ..) |
| 382 pshufd xmm3,xmm4,0x93 ; xmm3=(30 31 32 33 00 01 02 03 10 ..) |
| 383 |
| 384 mov rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW] |
| 385 mov rsi, JSAMPROW [rdi+1*SIZEOF_JSAMPROW] |
| 386 movd XMM_DWORD [rdx+rax*SIZEOF_JSAMPLE], xmm4 |
| 387 movd XMM_DWORD [rsi+rax*SIZEOF_JSAMPLE], xmm2 |
| 388 mov rdx, JSAMPROW [rdi+2*SIZEOF_JSAMPROW] |
| 389 mov rsi, JSAMPROW [rdi+3*SIZEOF_JSAMPROW] |
| 390 movd XMM_DWORD [rdx+rax*SIZEOF_JSAMPLE], xmm1 |
| 391 movd XMM_DWORD [rsi+rax*SIZEOF_JSAMPLE], xmm3 |
| 392 |
| 393 uncollect_args |
| 394 mov rsp,rbp ; rsp <- aligned rbp |
| 395 pop rsp ; rsp <- original rbp |
| 396 pop rbp |
| 397 ret |
| 398 |
| 399 |
| 400 ; -------------------------------------------------------------------------- |
| 401 ; |
| 402 ; Perform dequantization and inverse DCT on one block of coefficients, |
| 403 ; producing a reduced-size 2x2 output block. |
| 404 ; |
| 405 ; GLOBAL(void) |
| 406 ; jsimd_idct_2x2_sse2 (void *dct_table, JCOEFPTR coef_block, |
| 407 ; JSAMPARRAY output_buf, JDIMENSION output_col) |
| 408 ; |
| 409 |
| 410 ; r10 = void *dct_table |
| 411 ; r11 = JCOEFPTR coef_block |
| 412 ; r12 = JSAMPARRAY output_buf |
| 413 ; r13 = JDIMENSION output_col |
| 414 |
| 415 align 16 |
| 416 global EXTN(jsimd_idct_2x2_sse2) |
| 417 |
| 418 EXTN(jsimd_idct_2x2_sse2): |
| 419 push rbp |
| 420 mov rax,rsp |
| 421 mov rbp,rsp |
| 422 collect_args |
| 423 push rbx |
| 424 |
| 425 ; ---- Pass 1: process columns from input. |
| 426 |
| 427 mov rdx, r10 ; quantptr |
| 428 mov rsi, r11 ; inptr |
| 429 |
| 430 ; | input: | result: | |
| 431 ; | 00 01 ** 03 ** 05 ** 07 | | |
| 432 ; | 10 11 ** 13 ** 15 ** 17 | | |
| 433 ; | ** ** ** ** ** ** ** ** | | |
| 434 ; | 30 31 ** 33 ** 35 ** 37 | A0 A1 A3 A5 A7 | |
| 435 ; | ** ** ** ** ** ** ** ** | B0 B1 B3 B5 B7 | |
| 436 ; | 50 51 ** 53 ** 55 ** 57 | | |
| 437 ; | ** ** ** ** ** ** ** ** | | |
| 438 ; | 70 71 ** 73 ** 75 ** 77 | | |
| 439 |
| 440 ; -- Odd part |
| 441 |
| 442 movdqa xmm0, XMMWORD [XMMBLOCK(1,0,rsi,SIZEOF_JCOEF)] |
| 443 movdqa xmm1, XMMWORD [XMMBLOCK(3,0,rsi,SIZEOF_JCOEF)] |
| 444 pmullw xmm0, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 445 pmullw xmm1, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 446 movdqa xmm2, XMMWORD [XMMBLOCK(5,0,rsi,SIZEOF_JCOEF)] |
| 447 movdqa xmm3, XMMWORD [XMMBLOCK(7,0,rsi,SIZEOF_JCOEF)] |
| 448 pmullw xmm2, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 449 pmullw xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 450 |
| 451 ; xmm0=(10 11 ** 13 ** 15 ** 17), xmm1=(30 31 ** 33 ** 35 ** 37) |
| 452 ; xmm2=(50 51 ** 53 ** 55 ** 57), xmm3=(70 71 ** 73 ** 75 ** 77) |
| 453 |
| 454 pcmpeqd xmm7,xmm7 |
| 455 pslld xmm7,WORD_BIT ; xmm7={0x0000 0xFFFF 0x0000 0xFFFF ..} |
| 456 |
| 457 movdqa xmm4,xmm0 ; xmm4=(10 11 ** 13 ** 15 ** 17) |
| 458 movdqa xmm5,xmm2 ; xmm5=(50 51 ** 53 ** 55 ** 57) |
| 459 punpcklwd xmm4,xmm1 ; xmm4=(10 30 11 31 ** ** 13 33) |
| 460 punpcklwd xmm5,xmm3 ; xmm5=(50 70 51 71 ** ** 53 73) |
| 461 pmaddwd xmm4,[rel PW_F362_MF127] |
| 462 pmaddwd xmm5,[rel PW_F085_MF072] |
| 463 |
| 464 psrld xmm0,WORD_BIT ; xmm0=(11 -- 13 -- 15 -- 17 --) |
| 465 pand xmm1,xmm7 ; xmm1=(-- 31 -- 33 -- 35 -- 37) |
| 466 psrld xmm2,WORD_BIT ; xmm2=(51 -- 53 -- 55 -- 57 --) |
| 467 pand xmm3,xmm7 ; xmm3=(-- 71 -- 73 -- 75 -- 77) |
| 468 por xmm0,xmm1 ; xmm0=(11 31 13 33 15 35 17 37) |
| 469 por xmm2,xmm3 ; xmm2=(51 71 53 73 55 75 57 77) |
| 470 pmaddwd xmm0,[rel PW_F362_MF127] |
| 471 pmaddwd xmm2,[rel PW_F085_MF072] |
| 472 |
| 473 paddd xmm4,xmm5 ; xmm4=tmp0[col0 col1 **** col3] |
| 474 paddd xmm0,xmm2 ; xmm0=tmp0[col1 col3 col5 col7] |
| 475 |
| 476 ; -- Even part |
| 477 |
| 478 movdqa xmm6, XMMWORD [XMMBLOCK(0,0,rsi,SIZEOF_JCOEF)] |
| 479 pmullw xmm6, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_ISLOW_MULT_TYPE)] |
| 480 |
| 481 ; xmm6=(00 01 ** 03 ** 05 ** 07) |
| 482 |
| 483 movdqa xmm1,xmm6 ; xmm1=(00 01 ** 03 ** 05 ** 07) |
| 484 pslld xmm6,WORD_BIT ; xmm6=(-- 00 -- ** -- ** -- **) |
| 485 pand xmm1,xmm7 ; xmm1=(-- 01 -- 03 -- 05 -- 07) |
| 486 psrad xmm6,(WORD_BIT-CONST_BITS-2) ; xmm6=tmp10[col0 **** **** ****] |
| 487 psrad xmm1,(WORD_BIT-CONST_BITS-2) ; xmm1=tmp10[col1 col3 col5 col7] |
| 488 |
| 489 ; -- Final output stage |
| 490 |
| 491 movdqa xmm3,xmm6 |
| 492 movdqa xmm5,xmm1 |
| 493 paddd xmm6,xmm4 ; xmm6=data0[col0 **** **** ****]=(A0 ** ** **) |
| 494 paddd xmm1,xmm0 ; xmm1=data0[col1 col3 col5 col7]=(A1 A3 A5 A7) |
| 495 psubd xmm3,xmm4 ; xmm3=data1[col0 **** **** ****]=(B0 ** ** **) |
| 496 psubd xmm5,xmm0 ; xmm5=data1[col1 col3 col5 col7]=(B1 B3 B5 B7) |
| 497 |
| 498 movdqa xmm2,[rel PD_DESCALE_P1_2] ; xmm2=[rel PD_DESCALE_P1_2] |
| 499 |
| 500 punpckldq xmm6,xmm3 ; xmm6=(A0 B0 ** **) |
| 501 |
| 502 movdqa xmm7,xmm1 |
| 503 punpcklqdq xmm1,xmm5 ; xmm1=(A1 A3 B1 B3) |
| 504 punpckhqdq xmm7,xmm5 ; xmm7=(A5 A7 B5 B7) |
| 505 |
| 506 paddd xmm6,xmm2 |
| 507 psrad xmm6,DESCALE_P1_2 |
| 508 |
| 509 paddd xmm1,xmm2 |
| 510 paddd xmm7,xmm2 |
| 511 psrad xmm1,DESCALE_P1_2 |
| 512 psrad xmm7,DESCALE_P1_2 |
| 513 |
| 514 ; -- Prefetch the next coefficient block |
| 515 |
| 516 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 0*32] |
| 517 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 1*32] |
| 518 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 2*32] |
| 519 prefetchnta [rsi + DCTSIZE2*SIZEOF_JCOEF + 3*32] |
| 520 |
| 521 ; ---- Pass 2: process rows, store into output array. |
| 522 |
| 523 mov rdi, r12 ; (JSAMPROW *) |
| 524 mov eax, r13d |
| 525 |
| 526 ; | input:| result:| |
| 527 ; | A0 B0 | | |
| 528 ; | A1 B1 | C0 C1 | |
| 529 ; | A3 B3 | D0 D1 | |
| 530 ; | A5 B5 | | |
| 531 ; | A7 B7 | | |
| 532 |
| 533 ; -- Odd part |
| 534 |
| 535 packssdw xmm1,xmm1 ; xmm1=(A1 A3 B1 B3 A1 A3 B1 B3) |
| 536 packssdw xmm7,xmm7 ; xmm7=(A5 A7 B5 B7 A5 A7 B5 B7) |
| 537 pmaddwd xmm1,[rel PW_F362_MF127] |
| 538 pmaddwd xmm7,[rel PW_F085_MF072] |
| 539 |
| 540 paddd xmm1,xmm7 ; xmm1=tmp0[row0 row1 row0 row1] |
| 541 |
| 542 ; -- Even part |
| 543 |
| 544 pslld xmm6,(CONST_BITS+2) ; xmm6=tmp10[row0 row1 **** ****] |
| 545 |
| 546 ; -- Final output stage |
| 547 |
| 548 movdqa xmm4,xmm6 |
| 549 paddd xmm6,xmm1 ; xmm6=data0[row0 row1 **** ****]=(C0 C1 ** **) |
| 550 psubd xmm4,xmm1 ; xmm4=data1[row0 row1 **** ****]=(D0 D1 ** **) |
| 551 |
| 552 punpckldq xmm6,xmm4 ; xmm6=(C0 D0 C1 D1) |
| 553 |
| 554 paddd xmm6,[rel PD_DESCALE_P2_2] |
| 555 psrad xmm6,DESCALE_P2_2 |
| 556 |
| 557 packssdw xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1) |
| 558 packsswb xmm6,xmm6 ; xmm6=(C0 D0 C1 D1 C0 D0 C1 D1 ..) |
| 559 paddb xmm6,[rel PB_CENTERJSAMP] |
| 560 |
| 561 pextrw ebx,xmm6,0x00 ; ebx=(C0 D0 -- --) |
| 562 pextrw ecx,xmm6,0x01 ; ecx=(C1 D1 -- --) |
| 563 |
| 564 mov rdx, JSAMPROW [rdi+0*SIZEOF_JSAMPROW] |
| 565 mov rsi, JSAMPROW [rdi+1*SIZEOF_JSAMPROW] |
| 566 mov WORD [rdx+rax*SIZEOF_JSAMPLE], bx |
| 567 mov WORD [rsi+rax*SIZEOF_JSAMPLE], cx |
| 568 |
| 569 pop rbx |
| 570 uncollect_args |
| 571 pop rbp |
| 572 ret |
| 573 |
| 574 ; For some reason, the OS X linker does not honor the request to align the |
| 575 ; segment unless we do this. |
| 576 align 16 |
| OLD | NEW |
|---|
Chromium Code Reviews
Issue 1953443002:
Update to libjpeg_turbo 1.4.90 (Closed)
Base URL: https://chromium.googlesource.com/chromium/deps/libjpeg_turbo.git@master