[Mac/GN] Move the bundle ID and creator code into the BRANDING file, and use it.

components/policy/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/features.gni")
 import("//components/policy/resources/policy_templates.gni")
 import("//third_party/protobuf/proto_library.gni")
 import("//tools/grit/grit_rule.gni")
 
+if (is_mac) {
+  import("//build/util/branding.gni")
+}
+
 # About the policy component:
 #
 # There should really be two components. One called "policy" that includes all
 # generated code, and one "policy/proto" like we have now. The proto needs to
 # be separate for cases like SesssionManagerClient which uses the protos to
 # communicate with the Chrome OS system layer, but doesn't need the rest of the
 # policy stuff).
 #
 # The reason the rest of the targets exist are artifacts of the way the GYP
 # build works. The current "policy" target which is really just some generated
@@ skipping 114 matching lines @@
     outputs = policy_templates_doc_outputs
     if (is_android) {
       outputs += policy_templates_android_outputs
     }
     if (is_linux) {
       outputs += policy_templates_linux_outputs
     }
     if (is_mac) {
       outputs += policy_templates_mac_outputs
 
-      # TODO(knn) : Move this out once more targets use this.
-      if (is_chrome_branded) {
-        mac_bundle_id = "com.google.Chrome"
-      } else {
-        mac_bundle_id = "org.chromium.Chromium"
-      }
-      defines = [ "mac_bundle_id=$mac_bundle_id" ]
+      defines = [ "mac_bundle_id=$chrome_mac_bundle_id" ]
     }
     if (is_win) {
       outputs += policy_templates_windows_outputs
     }
   }
 
   # Run the proto compiler over the generated file and make it a component.
   component("cloud_policy_proto_generated_compile") {
     public_deps = [
       ":cloud_policy_proto_generated_compile_proto",
@@ skipping 165 matching lines @@
         ":policy_templates_grit",  # For policy_templates_android_outputs.
       ]
     }
 
     group("app_restrictions_resources") {
       deps = [
         ":$build_config_target_name",
         ":$zip_target_name",
       ]
     }
+  } else if (is_mac) {
+    action("convert_mcx_plist") {
+      script = "//build/config/mac/xcrun.py"
+      sources = [
+        "$policy_templates_base_dir/mac/app-Manifest.plist",
+      ]
+      inputs = [
+        script,
+      ]
+      outputs = [
+        "$target_gen_dir/$chrome_mac_bundle_id.plist",
+      ]
+
+      args = [
+               "xcrun",
+               "plutil",
+               "-convert",
+               "xml1",
+             ] + rebase_path(sources, root_out_dir) + [ "-o" ] +
+             rebase_path(outputs, root_out_dir)
+
+      deps = [
+        ":policy_templates",
+      ]
+    }
+
+    bundle_data("manifest_bundle_data") {
+      sources = get_target_outputs(":convert_mcx_plist")
+      outputs = [
+        "{{bundle_resources_dir}}/{{source_file_part}}",
+      ]
+      public_deps = [
+        ":convert_mcx_plist",
+      ]
+    }
+
+    # The reason we are not enumerating all the locales is that
+    # the translations would eat up 3.5MB disk space in the
+    # application bundle.
+    bundle_data("manifest_strings_bundle_data") {
+      sources = [
+        "$policy_templates_base_dir/mac/strings/en.lproj/Localizable.strings",
+      ]
+      outputs = [
+        "{{bundle_resources_dir}}/en.lproj/{{source_file_part}}",
+      ]
+      public_deps = [
+        ":policy_templates",
+      ]
+    }
+
+    create_bundle("chrome_manifest_bundle") {
+      bundle_root_dir = "$root_out_dir/$chrome_mac_bundle_id.manifest/Contents"
+      bundle_resources_dir = "$bundle_root_dir/Resources"
+
+      deps = [
+        ":manifest_bundle_data",
+        ":manifest_strings_bundle_data",
+      ]
+    }
   }
 }
-#TODO(GYP) chrome_manifest_bundle