Add a main menu to the shim that matches the one in Chrome.

apps/app_shim/chrome_main_app_mode_mac.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 // On Mac, one can't make shortcuts with command-line arguments. Instead, we
 // produce small app bundles which locate the Chromium framework and load it,
 // passing the appropriate data. This is the entry point into the framework for
 // those app bundles.
 
 #import <Cocoa/Cocoa.h>
@@ skipping 46 matching lines @@
 
 // The AppShimController is responsible for communication with the main Chrome
 // process, and generally controls the lifetime of the app shim process.
 class AppShimController : public IPC::Listener {
  public:
   AppShimController();
 
   // Connects to Chrome and sends a LaunchApp message.
   void Init();
 
+  // Builds main menu bar items.
+  void SetUpMenu();
+
   void SendSetAppHidden(bool hidden);
 
   void SendQuitApp();
 
   // Called when the app is activated, either by the user clicking on it in the
   // dock or by Cmd+Tabbing to it.
   void ActivateApp(bool is_reopen);
 
  private:
   // IPC::Listener implemetation.
@@ skipping 13 matching lines @@
   bool launch_app_done_;
 
   DISALLOW_COPY_AND_ASSIGN(AppShimController);
 };
 
 AppShimController::AppShimController() : channel_(NULL),
                                          launch_app_done_(false) {}
 
 void AppShimController::Init() {
   DCHECK(g_io_thread);
+
+  SetUpMenu();
+
+  // Open an IPC channel to Chrome and send the initial app launch message.
   NSString* chrome_bundle_path =
       base::SysUTF8ToNSString(g_info->chrome_outer_bundle_path.value());
   NSBundle* chrome_bundle = [NSBundle bundleWithPath:chrome_bundle_path];
   base::FilePath user_data_dir;
   if (!chrome::GetUserDataDirectoryForBrowserBundle(chrome_bundle,
                                                     &user_data_dir)) {
     Close();
     return;
   }
 
   base::FilePath socket_path =
       user_data_dir.Append(app_mode::kAppShimSocketName);
   IPC::ChannelHandle handle(socket_path.value());
   channel_ = new IPC::ChannelProxy(handle, IPC::Channel::MODE_NAMED_CLIENT,
       this, g_io_thread->message_loop_proxy().get());
 
   channel_->Send(new AppShimHostMsg_LaunchApp(
       g_info->profile_dir, g_info->app_mode_id,
       CommandLine::ForCurrentProcess()->HasSwitch(app_mode::kNoLaunchApp) ?
           apps::APP_SHIM_LAUNCH_REGISTER_ONLY : apps::APP_SHIM_LAUNCH_NORMAL));
 
   nsapp_delegate_.reset([[AppShimDelegate alloc] initWithController:this]);
   DCHECK(![NSApp delegate]);
   [NSApp setDelegate:nsapp_delegate_];
 }
 
+void AppShimController::SetUpMenu() {
+  // The title of the first item is replaced by OSX with the name of the app and
+  // bold styling. Since the title can't be replaced, it is hidden in Chrome and
+  // the app title has non-bold styling. We can match that here by adding a
+  // first element and hiding it.
+  NSString* title = base::SysUTF16ToNSString(g_info->app_mode_name);
+  base::scoped_nsobject<NSMenu> mainMenu([[NSMenu alloc] initWithTitle:title]);

[tapted, 2013/07/17 07:48:24]

nit: mainMenu -> main_menu, since we're in a C++ class

[jackhou1, 2013/07/22 00:51:46]

Done.

+  for (int i = 0; i < 2; ++i) {

[tapted, 2013/07/17 07:48:24]

Not sure you need the loop.. can you explain the approach some more. E.g. are
you replacing the whole [NSApp mainMenu] to avoid a conflict with the
keyEquivalent on the existing Quit item?

E.g. does something like this work, or are items without submenus skipped in the
mainMenu somehow:

// Put a dummy item at index 0, and hide it.
[[main_menu addItemWithTitle:title
                      action:nil
               keyEquivalent:@""] setHidden:YES];

// Construct an unbolded app menu, to match how it appears with Chrome active.
base::scoped_nsobject<NSMenu> submenu([[NSMenu alloc] initWithTitle:title]);
[submenu addItemWithTitle:[quit stringByAppendingString:title]
                   action:@selector(terminate:)
            keyEquivalent:@"q"];
NSMenuItem* app_name_item = [main_menu addItemWithTitle:title
                                                 action:nil
                                          keyEquivalent:@""];
[app_name_item setSubmenu:submenu];
[NSApp setMainMenu:mainMenu];


And.. is it worth adding Quit at all? i.e. Should the user ever see it? And,
when they do try to use it, is it expected to work, or will it always freeze
(since otherwise it would have focussed Chrome).

[jackhou1, 2013/07/22 00:51:46]

Done.

Yeah, when all of the app's windows are closed, you can still Cmd+Tab to the app
shim. Chrome does not focus because there are no windows for that app.

+    base::scoped_nsobject<NSMenuItem> item(
+        [[NSMenuItem alloc] initWithTitle:title
+                                   action:nil
+                            keyEquivalent:@""]);
+    base::scoped_nsobject<NSMenu> menu([[NSMenu alloc] initWithTitle:title]);
+    [item setSubmenu:menu];
+    [mainMenu addItem:item];
+  }
+  [[mainMenu itemAtIndex:0] setHidden:YES];
+
+  NSMenu* submenu = [[mainMenu itemAtIndex:1] submenu];
+  base::scoped_nsobject<NSMenuItem> item(
+      [[NSMenuItem alloc] initWithTitle:[@"Quit " stringByAppendingString:title]

[tapted, 2013/07/17 07:48:24]

I think you need localization on the string "Quit"

[jackhou1, 2013/07/22 00:51:46]

This turns out to be harder than I thought because the shim doesn't have access
to Chrome's localized resources. The solution will probably be to add IPC
messages to get UI strings from Chrome. I'll do that in another CL.

[tapted, 2013/07/22 02:35:09]

Can you just call

   ResourceBundle::InitSharedInstanceLocaleOnly(
      const std::string& pref_locale, Delegate* delegate);

A NULL delegate might work, otherwise you can probably implement implement a
ResourceBundle::Delegate that implements GetPathForLocalePack, or call one of
the SetOverride*BundlePath functions.

It looks like app_mode_app already depends on the ui library via
infoplist_strings_tool, so you might not even have to add and dependencies (or
you might need a direct dependency to pick up an include path).

[jackhou1, 2013/07/22 11:27:04]

Ah yup, this is necessary. I also needed to add an include to the gypi, and set
the framework bundle path.

+                                 action:@selector(terminate:)
+                          keyEquivalent:@"q"]);
+  [submenu addItem:item];
+
+  [NSApp setMainMenu:mainMenu];
+}
+
 void AppShimController::SendQuitApp() {
   channel_->Send(new AppShimHostMsg_QuitApp);
 }
 
 bool AppShimController::OnMessageReceived(const IPC::Message& message) {
   bool handled = true;
   IPC_BEGIN_MESSAGE_MAP(AppShimController, message)
     IPC_MESSAGE_HANDLER(AppShimMsg_LaunchApp_Done, OnLaunchAppDone)
     IPC_MESSAGE_UNHANDLED(handled = false)
   IPC_END_MESSAGE_MAP()
@@ skipping 262 matching lines @@
   // fully initialized don't receive a reply until its run loop starts. Once
   // the reply is received, Chrome will have opened its IPC port, guaranteed.
   [ReplyEventHandler pingProcess:psn andCall:base::Bind(&OnPingChromeReply)];
 
   base::MessageLoopForUI main_message_loop;
   main_message_loop.set_thread_name("MainThread");
   base::PlatformThread::SetName("CrAppShimMain");
   main_message_loop.Run();
   return 0;
 }