Windows GN clobber error fixes

build/toolchain/win/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/config/win/visual_studio_version.gni")
 import("//build/toolchain/goma.gni")
 import("//build/toolchain/toolchain.gni")
 
 # Should only be running on Windows.
@@ skipping 220 matching lines @@
     }
 
     # When invoking this toolchain not as the default one, these args will be
     # passed to the build. They are ignored when this is the default toolchain.
     toolchain_args() {
       current_cpu = invoker.toolchain_cpu
       if (defined(invoker.toolchain_os)) {
         current_os = invoker.toolchain_os
       }
 
-      forward_variables_from(invoker,
-                             [
-                               "is_clang",
-                               "is_component_build",
-                             ])
+      if (defined(invoker.is_clang)) {
+        is_clang = invoker.is_clang
+      }
+      if (defined(invoker.is_component_build)) {
+        is_component_build = invoker.is_component_build
+      }

[Dirk Pranke, 2016/05/03 17:48:50]

I'm confused; isn't this exactly the same?

[brettw, 2016/05/03 18:00:43]

With the new changes to forward_variables_from, it won't clobber a variable
implicitly. In the rare cases where you want to clobber, you need to do it
explicitly which is what happens here.

[Dirk Pranke, 2016/05/03 20:06:33]

Ah, right, I was thinking they weren't already in scope but I wasn't thinking of
the top level declared_args.

Maybe add a comment indicating why using forward_variables_from() is the wrong
thing to do here and below, since that's non-obvious (although probably true for
all toolchain() rules)?

 
       # This value needs to be passed through unchanged.
       host_toolchain = host_toolchain
     }
   }
 }
 
 if (host_os == "win") {
   clang_cl = "clang-cl.exe"
 } else {
@@ skipping 50 matching lines @@
   goma_prefix = invoker.goma_prefix
   x64_toolchain_data = invoker.x64_toolchain_data
   clang_cl = invoker.clang_cl
 
   msvc_toolchain(target_name) {
     environment = "environment.x64"
     toolchain_cpu = "x64"
     cl = "${goma_prefix}\"${x64_toolchain_data.vc_bin_dir}/cl.exe\""
     is_clang = false
 
-    forward_variables_from(invoker, [ "is_component_build" ])
+    if (defined(invoker.is_component_build)) {
+      is_component_build = invoker.is_component_build
+    }
   }
 
   msvc_toolchain("clang_" + target_name) {
     environment = "environment.x64"
     toolchain_cpu = "x64"
     prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
                          root_build_dir)
     cl = "${goma_prefix}$prefix/${clang_cl}"
     toolchain_os = "win"
     is_clang = true
 
-    forward_variables_from(invoker, [ "is_component_build" ])
+    if (defined(invoker.is_component_build)) {
+      is_component_build = invoker.is_component_build
+    }
   }
 }
 
 win_x64_toolchains("x64") {
   # TODO(mcgrathr): These assignments are only required because of
   # crbug.com/395883.  Drop them if that ever gets fixed in GN.
   concurrent_links = concurrent_links
   goma_prefix = goma_prefix
   x64_toolchain_data = x64_toolchain_data
 }
@@ skipping 32 matching lines @@
 
   msvc_toolchain("winrt_x64") {
     environment = "environment.winrt_x64"
     cl = "${goma_prefix}\"${vc_bin_dir}/cl.exe\""
     is_clang = false
 
     toolchain_cpu = "x64"
     toolchain_os = current_os
   }
 }