Change webapk packages and directory structure

web_apks/minting_example/BUILD.gn

-# Copyright 2015 The Chromium Authors. All rights reserved.
-# Use of this source code is governed by a BSD-style license that can be
-# found in the LICENSE file.
-
-import("//build/config/android/rules.gni")
-
-declare_args() {
-  # The origin URL of minted apks, for example: "foo.com"
-  manifest_package_minting_origin = "template"
-
-  # The browser to which WebAPKs will be bound.
-  runtime_host = "com.google.android.apps.chrome"
-
-  # The URL for the minted apks, for example: "https://foo.com"
-  host_url = "https://www.template.com/home_page"
-  scope_url_host = "www.template.com"
-
-  # The message authentication code from Chrome for identity verification.
-  mac = "template"
-
-  # The scope of the Urls that the Minted APKs could navigate to.
-  scope = "https://www.template.com"
-}
-
-manifest_package_minting = "org.chromium.minting"
-minting_example_dir = "//web_apks/minting_example"
-minting_libs_dir = "$minting_example_dir/libs"
-minting_client_dir = "$minting_libs_dir/client"
-minting_common_dir = "$minting_libs_dir/common"
-minting_runtime_library_dir = "$minting_libs_dir/runtime_library"
-minting_runtime_library_junit_dir =
-    "$minting_example_dir/junit/libs/runtime_library"
-
-runtime_dex_version = 1
-runtime_dex_asset_name = "web_apk$runtime_dex_version.dex"
-
-minting_example_manifest =
-    "$target_gen_dir/minting_example_manifest/AndroidManifest.xml"
-
-jinja_template("minting_example_manifest") {
-  input = "$minting_example_dir/AndroidManifest.xml"
-  output = minting_example_manifest
-
-  # The variable values must be non empty and globally unique in
-  # AndroidManifest.xml in order for the string substitution in APKMinting.java
-  # to work.
-  variables = [
-    "manifest_package=$manifest_package_minting.$manifest_package_minting_origin",
-    "min_sdk_version=16",
-    "target_sdk_version=23",
-    "host_url=$host_url",
-    "runtime_host=$runtime_host",
-    "scope_url_host=$scope_url_host",
-    "mac=$mac",
-    "scope=$scope",
-  ]
-}
-
-android_resources("minting_apk_resources") {
-  resource_dirs = [ "$minting_example_dir/res" ]
-  custom_package = "$manifest_package_minting"
-}
-
-android_library("minting_client_lib") {
-  java_files = [
-    "$minting_client_dir/org/chromium/minting/lib/client/DexOptimizer.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/WebApkStateParams.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/NavigationClient.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/NotificationBuilderDelegate.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/NotificationClient.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/WebApkValidator.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/WebApkSwitches.java",
-    "$minting_client_dir/org/chromium/minting/lib/client/WebApkVersionManager.java",
-  ]
-  deps = [
-    ":minting_common_lib",
-    "//base:base_java",
-    "//third_party/android_tools:android_support_v13_java",
-  ]
-  srcjar_deps = [
-    ":minting_service_aidl",
-    ":runtime_dex_version_java",
-  ]
-}
-
-java_cpp_template("runtime_dex_version_java") {
-  package_name = "org/chromium/minting/lib/client"
-  sources = [
-    "$minting_client_dir/org/chromium/minting/lib/client/WebApkVersion.template",
-  ]
-  defines = [ "CURRENT_RUNTIME_DEX_VERSION_VALUE=$runtime_dex_version" ]
-}
-
-android_library("minting_common_lib") {
-  java_files = [
-    "$minting_common_dir/org/chromium/minting/lib/common/WebApkConstants.java",
-    "$minting_common_dir/org/chromium/minting/lib/common/WebApkUtils.java",
-  ]
-}
-
-android_aidl("minting_service_aidl") {
-  import_include = "$minting_runtime_library_dir/src/org/chromium/minting/libs/runtime_library"
-  interface_file = "$minting_runtime_library_dir/src/org/chromium/minting/libs/runtime_library/common.aidl"
-  sources = [
-    "$minting_runtime_library_dir/src/org/chromium/minting/libs/runtime_library/IWebApkApi.aidl",
-  ]
-}
-
-android_library("minting_runtime_library") {
-  dex_path = "$target_gen_dir/$runtime_dex_asset_name"
-  java_files = [ "$minting_runtime_library_dir/src/org/chromium/minting/libs/runtime_library/WebApkServiceImpl.java" ]
-  chromium_code = false
-  srcjar_deps = [ ":minting_service_aidl" ]
-}
-
-android_assets("minting_runtime_library_assets") {
-  write_file("$target_gen_dir/web_apk_dex_version.txt", runtime_dex_version)
-
-  sources = [
-    "$target_gen_dir/$runtime_dex_asset_name",
-    "$target_gen_dir/web_apk_dex_version.txt",
-  ]
-  disable_compression = true
-
-  deps = [
-    ":minting_runtime_library",
-  ]
-}
-
-android_library("dex_loader_lib") {
-  java_files =
-      [ "$minting_example_dir/src/org/chromium/minting/DexLoader.java" ]
-}
-
-android_apk("minting_example_apk") {
-  android_manifest = minting_example_manifest
-  apk_name = "MintingExample.$manifest_package_minting_origin"
-  native_lib_placeholders = [ "libfoo.so" ]
-  java_files = [
-    "$minting_example_dir/src/org/chromium/minting/MainActivity.java",
-    "$minting_example_dir/src/org/chromium/minting/WebApkApplication.java",
-    "$minting_example_dir/src/org/chromium/minting/WebApkServiceFactory.java",
-    "$minting_example_dir/src/org/chromium/minting/Reflect.java",
-  ]
-  chromium_code = false
-  proguard_enabled = true
-  proguard_configs = [ "proguard.flags" ]
-  deps = [
-    ":dex_loader_lib",
-    ":minting_apk_resources",
-    ":minting_common_lib",
-    ":minting_example_manifest",
-  ]
-}
-
-android_library("web_apk_javatests") {
-  testonly = true
-  java_files = [ "$minting_example_dir/javatests/src/org/chromium/minting/DexLoaderTest.java" ]
-  deps = [
-    ":dex_loader_lib",
-    ":minting_common_lib",
-    "//base:base_java",
-    "//content/public/test/android:content_java_test_support",
-  ]
-  srcjar_deps = [ "//web_apks/minting_example/javatests/dex_optimizer:dex_optimizer_service_aidl" ]
-}
-
-junit_binary("minting_runtime_library_junit_tests") {
-  java_files = [ "$minting_runtime_library_junit_dir/src/org/chromium/minting/libs/runtime_library/WebApkServiceImplTest.java" ]
-  deps = [
-    ":minting_runtime_library",
-    "//base:base_java",
-    "//base:base_junit_test_support",
-  ]
-}