GN: forward_variables_from shouldn't clobber vars.

build/compiled_action.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # This file introduces two related templates that act like action and
 # action_foreach but instead of running a Python script, it will compile a
 # given tool in the host toolchain and run that (either once or over the list
 # of inputs, depending on the variant).
 #
 # Parameters
@@ skipping 63 matching lines @@
 
 template("compiled_action") {
   assert(defined(invoker.tool), "tool must be defined for $target_name")
   assert(defined(invoker.outputs), "outputs must be defined for $target_name")
   assert(defined(invoker.args), "args must be defined for $target_name")
 
   assert(!defined(invoker.sources),
          "compiled_action doesn't take a sources arg. Use inputs instead.")
 
   action(target_name) {
-    deps = []
-    inputs = []
     forward_variables_from(invoker,
                            [
                              "deps",
                              "inputs",
                              "outputs",
                              "testonly",
                              "visibility",
                            ])
+    if (!defined(deps)) {
+      deps = []
+    }
+    if (!defined(inputs)) {
+      inputs = []
+    }
 
     script = "//build/gn_run_binary.py"
 
     # Constuct the host toolchain version of the tool.
     host_tool = invoker.tool + "($host_toolchain)"
 
     # Get the path to the executable. Currently, this assumes that the tool
     # does not specify output_name so that the target name is the name to use.
     # If that's not the case, we'll need another argument to the script to
     # specify this, since we can't know what the output name is (it might be in
@@ skipping 13 matching lines @@
   }
 }
 
 template("compiled_action_foreach") {
   assert(defined(invoker.sources), "sources must be defined for $target_name")
   assert(defined(invoker.tool), "tool must be defined for $target_name")
   assert(defined(invoker.outputs), "outputs must be defined for $target_name")
   assert(defined(invoker.args), "args must be defined for $target_name")
 
   action_foreach(target_name) {
-    deps = []
-    inputs = []
     forward_variables_from(invoker,
                            [
                              "deps",
                              "inputs",
                              "outputs",
                              "sources",
                              "testonly",
                              "visibility",
                            ])
+    if (!defined(deps)) {
+      deps = []
+    }
+    if (!defined(inputs)) {
+      inputs = []
+    }
 
     script = "//build/gn_run_binary.py"
 
     # Constuct the host toolchain version of the tool.
     host_tool = invoker.tool + "($host_toolchain)"
 
     # Get the path to the executable. Currently, this assumes that the tool
     # does not specify output_name so that the target name is the name to use.
     # If that's not the case, we'll need another argument to the script to
     # specify this, since we can't know what the output name is (it might be in
     # another file not processed yet).
     host_executable =
         get_label_info(host_tool, "root_out_dir") + "/" +
         get_label_info(host_tool, "name") + _host_executable_suffix
 
     # Add the executable itself as an input.
     inputs += [ host_executable ]
 
     deps += [ host_tool ]
 
     # The script takes as arguments the binary to run, and then the arguments
     # to pass it.
     args = [ rebase_path(host_executable, root_build_dir) ] + invoker.args
   }
 }