Recompile .rc files when manifests change in GN.

build/config/win/manifest.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # HOW MANIFESTS WORK IN THE GN BUILD
 #
 # Use the windows_manifest template to declare a manifest generation step.
 # This will combine all listed .manifest files and generate a resource file
 # referencing the resulting manifest. To link this manifest, just depend on
 # the manifest target from your executable or shared library.
@@ skipping 75 matching lines @@
   template("windows_manifest") {
     manifest_action_name = "${target_name}__gen_manifest"
     rc_action_name = "${target_name}__gen_rc"
     source_set_name = target_name
 
     output_manifest = "$target_gen_dir/$source_set_name.manifest"
     rcfile = "$output_manifest.rc"
 
     # Make the final .manifest file.
     action(manifest_action_name) {
-      visibility = [ ":$source_set_name" ]
+      visibility = [
+        ":$source_set_name",
+        ":$rc_action_name",
+      ]
 
       script = "$root_build_dir/gyp-win-tool"
 
       assert(defined(invoker.sources),
              "\"sources\" must be defined for a windows_manifest target")
       inputs = invoker.sources
 
       outputs = [
         output_manifest,
       ]
 
       args = [
         "manifest-wrapper",
         _environment_file,
         "mt.exe",
         "-nologo",
         "-manifest",
       ]
       args += rebase_path(invoker.sources, root_build_dir)
       args += [ "-out:" + rebase_path(output_manifest, root_build_dir) ]
 
       # Apply any dependencies from the invoker to this target, since those
       # dependencies may have created the input manifest files.
       forward_variables_from(invoker, [ "deps" ])
     }
 
-    # Make the .rc file that references the final manifest file. The manifest
-    # generation doesn't need to be a dependency because it's not actually
-    # needed until the .rc is compiled.
+    # Make the .rc file that references the final manifest file.
     #
     # This could easily be combined into one step, but this current separation
     # of .manifest and .rc matches GYP and allows us to re-use gyp-win-tool.
     action(rc_action_name) {
       visibility = [ ":$source_set_name" ]
 
       script = "$root_build_dir/gyp-win-tool"
 
       outputs = [
         rcfile,
@@ skipping 10 matching lines @@
         assert(false, "Bad value of \"type\", Must be \"exe\" or \"dll\"")
       }
 
       args = [
         "manifest-to-rc",
         "$_environment_file",
         rebase_path(output_manifest),
         rebase_path(rcfile, root_build_dir),
         manifest_resource_id,
       ]
+
+      # Although generating this file doesn't technically depend on the
+      # generated manifest, this dependency causes the .rc timestamp to be
+      # updated every time the manifest is updated. Otherwise, updating the
+      # manifest will not cause a recompilation of the .rc file.
+      deps = [
+        ":$manifest_action_name",
+      ]
     }
 
     # This source set only exists to compile and link the resource file.
     source_set(source_set_name) {
       forward_variables_from(invoker, [ "visibility" ])
       sources = [
         rcfile,
       ]
       deps = [
         ":$manifest_action_name",
         ":$rc_action_name",
       ]
     }
   }
 } else {
   # Make a no-op group on non-Windows platforms so windows_manifest
   # instantiations don't need to be inside windows blocks.
   template("windows_manifest") {
     group(target_name) {
       # Prevent unused variable warnings on non-Windows platforms.
       assert(invoker.type == "exe" || invoker.type == "dll")
       assert(invoker.sources != "")
       assert(!defined(invoker.deps) || invoker.deps != "")
       assert(!defined(invoker.visibility) || invoker.visibility != "")
     }
   }
 }