MacViews: support Views permission bubble

chrome/browser/ui/cocoa/website_settings/permission_bubble_anchor_delegate_views_cocoa.mm

Index: chrome/browser/ui/cocoa/website_settings/permission_bubble_anchor_delegate_views_cocoa.mm
diff --git a/chrome/browser/ui/cocoa/website_settings/permission_bubble_anchor_delegate_views_cocoa.mm b/chrome/browser/ui/cocoa/website_settings/permission_bubble_anchor_delegate_views_cocoa.mm
new file mode 100644
index 0000000000000000000000000000000000000000..bf89ffb4d8ee540ff1e00330f5ebc2f5da6dff75
--- /dev/null
+++ b/chrome/browser/ui/cocoa/website_settings/permission_bubble_anchor_delegate_views_cocoa.mm
@@ -0,0 +1,73 @@
+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "base/memory/ptr_util.h"
+#include "chrome/browser/ui/browser.h"
+#include "chrome/browser/ui/browser_dialogs.h"
+#include "chrome/browser/ui/browser_window.h"
+#import "chrome/browser/ui/cocoa/browser_window_controller.h"
+#import "chrome/browser/ui/cocoa/website_settings/permission_bubble_cocoa.h"
+#import "chrome/browser/ui/cocoa/website_settings/permission_bubble_controller.h"
+#import "chrome/browser/ui/cocoa/location_bar/location_bar_view_mac.h"
+#include "chrome/browser/ui/views/website_settings/permissions_bubble_view.h"
+#import "ui/base/cocoa/cocoa_base_utils.h"
+#import "ui/gfx/mac/coordinate_conversion.h"
+
+namespace {
+
+// Implementation of PermissionBubbleViewViews' AnchorDelegate for Cocoa
+// browsers. In Cocoa browsers there is no parent views::View for the permission
+// bubble, so this class supplies an anchor point instead.
+class PermissionBubbleAnchorDelegateViewsCocoa
+    : public PermissionBubbleViewViews::AnchorDelegate {
+ public:
+  explicit PermissionBubbleAnchorDelegateViewsCocoa(Browser* browser);
+
+  // AnchorDelegate:
+  views::View* GetAnchorView() override;
+  gfx::Point GetAnchorPoint() override;
+  views::BubbleBorder::Arrow GetAnchorArrow() override;
+
+ private:
+  Browser* browser_;
+
+  DISALLOW_COPY_AND_ASSIGN(PermissionBubbleAnchorDelegateViewsCocoa);
+};
+
+PermissionBubbleAnchorDelegateViewsCocoa::
+    PermissionBubbleAnchorDelegateViewsCocoa(Browser* browser)
+    : browser_(browser) {}
+
+views::View* PermissionBubbleAnchorDelegateViewsCocoa::GetAnchorView() {
+  return nullptr;
+}
+
+gfx::Point PermissionBubbleAnchorDelegateViewsCocoa::GetAnchorPoint() {
+  return gfx::ScreenPointFromNSPoint(
+      [PermissionBubbleController getAnchorPointForBrowser:browser_]);
+}
+
+views::BubbleBorder::Arrow
+PermissionBubbleAnchorDelegateViewsCocoa::GetAnchorArrow() {
+  return [PermissionBubbleController hasVisibleLocationBarForBrowser:browser_]
+             ? views::BubbleBorder::TOP_LEFT
+             : views::BubbleBorder::NONE;
+}
+
+}  // namespace
+
+// static
+std::unique_ptr<PermissionBubbleViewViews::AnchorDelegate>
+PermissionBubbleViewViews::CreateAnchorDelegate(Browser* browser) {
+  return base::WrapUnique(
+      new PermissionBubbleAnchorDelegateViewsCocoa(browser));
+}
+
+// static
+std::unique_ptr<PermissionBubbleView> PermissionBubbleView::Create(
+    Browser* browser) {
+  if (chrome::ToolkitViewsWebUIDialogsEnabled())
+    return base::WrapUnique(new PermissionBubbleViewViews(browser));
+  return base::WrapUnique(new PermissionBubbleCocoa(browser));
+}