[Cronet] Use gn desc deps to find third_party licenses.

components/cronet/ios/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/buildflag_header.gni")
+import("//build/util/version.gni")

[brettw, 2016/05/03 22:13:03]

You can delete this when you change the version processing below.

[mef, 2016/05/11 15:57:27]

Hrm, process_version is undefined without it.

+import("//chrome/version.gni")
+import("//testing/test.gni")
+import("//url/features.gni")
+
+assert(!is_component_build, "Cronet requires static library build.")

[brettw, 2016/05/03 22:13:03]

The link you have going into this file should match this condition or the builds
will fail.

[mef, 2016/05/11 15:57:27]

Done.

+
+declare_args() {
+  cronet_enable_data_reduction_proxy_support = false
+}
+
+_cronet_version_header_include_dir = "$target_gen_dir/cronet_version_header"
+process_version("cronet_version_header") {
+  template_file = "//components/cronet/version.h.in"
+  output = "$_cronet_version_header_include_dir/components/cronet/version.h"
+  extra_args = [
+    "-e",
+    "VERSION_FULL=\"$chrome_version_full\"",

[brettw, 2016/05/03 22:13:03]

I don't like chrome_version_full and we should only use this when necessary. See
components/data_reduction_proxy/core/common:version_header for how to express
this without depending on data being read from the version file at GN-time.

[mef, 2016/05/11 15:57:27]

Done.

+  ]
+}
+
+# Currently Cronet is used outside of chromium as a prebuilt static library.
+# TODO(mef): Convert 'cronet_static' into source_set or merge into libcronet
+# cronet dynamic framework is supported.
+static_library("cronet_static") {

[brettw, 2016/05/03 22:13:03]

source_set.

[mef, 2016/05/11 15:57:27]

Done.

+  deps = [
+    ":cronet_version_header",
+    "//net",
+    "//url",
+  ]
+
+  sources = [
+    "../histogram_manager.cc",
+    "../histogram_manager.h",
+    "../url_request_context_config.cc",
+    "../url_request_context_config.h",
+    "Cronet.h",
+    "Cronet.mm",
+    "cronet_bidirectional_stream.cc",
+    "cronet_bidirectional_stream.h",
+    "cronet_c_for_grpc.cc",
+    "cronet_c_for_grpc.h",
+    "cronet_environment.cc",
+    "cronet_environment.h",
+  ]
+
+  include_dirs = [ _cronet_version_header_include_dir ]
+
+  if (!use_platform_icu_alternatives) {
+    deps += [ "//base:i18n" ]
+  }
+}
+
+shared_library("libcronet") {
+  sources = [
+    "Cronet.h",
+    "Cronet.mm",
+    "cronet_c_for_grpc.cc",
+    "cronet_c_for_grpc.h",
+  ]
+  deps = [
+    ":cronet_static",
+    "//base",
+    "//net:net",
+  ]
+  libs = [ "UIKit.Framework" ]
+}
+
+bundle_data("cronet_test_bundle_data") {
+  testonly = true
+  sources = [
+    "//net/data/ssl/certificates/quic_test.example.com.crt",
+    "//net/data/ssl/certificates/quic_test.example.com.key",
+    "//net/data/ssl/certificates/quic_test.example.com.key.pkcs8",
+    "//net/data/ssl/certificates/quic_test.example.com.key.sct",
+  ]
+  outputs = [
+    "{{bundle_resources_dir}}/{{source_file_part}}",
+  ]
+}
+
+test("cronet_test") {
+  testonly = true
+  sources = [
+    "test/cronet_bidirectional_stream_test.mm",
+    "test/cronet_test_runner.mm",
+    "test/quic_test_server.cc",
+    "test/quic_test_server.h",
+  ]
+
+  deps = [
+    ":cronet_static",
+    ":cronet_test_bundle_data",
+    ":cronet_version_header",
+    "//base",
+    "//base:i18n",
+    "//net",
+    "//net:simple_quic_tools",
+    "//net:test_support",
+    "//third_party/icu",
+  ]
+
+  include_dirs = [ _cronet_version_header_include_dir ]
+}
+
+test("cronet_unittests") {
+  sources = [
+    "//components/cronet/histogram_manager_unittest.cc",
+    "//components/cronet/run_all_unittests.cc",
+    "//components/cronet/url_request_context_config_unittest.cc",
+  ]
+
+  deps = [
+    ":cronet_static",
+    "//base",
+    "//base/test:test_support",
+    "//components/metrics",
+    "//net",
+    "//testing/gtest",
+  ]
+}
+
+_package_dir = "$root_out_dir/cronet"
+
+action("generate_license") {
+  _license_path = "$_package_dir/LICENSE"
+
+  script = "//components/cronet/tools/cronet_licenses.py"
+  outputs = [
+    _license_path,
+  ]
+  args = [
+    "license",
+    rebase_path(_license_path, root_build_dir),
+    "--gn_out_dir=" + rebase_path(root_build_dir),

[brettw, 2016/05/03 22:13:03]

This is a bit suspicious because it will always be the absolute path to the
scripts working directory. It seems pointless to pass this in.

[mef, 2016/05/11 15:57:27]

Done.

+  ]
+}
+
+copy("cronet_package_copy") {
+  sources = [
+    "//AUTHORS",
+    "//chrome/VERSION",
+    "//components/cronet/ios/Cronet.h",
+    "//components/cronet/ios/cronet_c_for_grpc.h",
+  ]
+  outputs = [
+    "$_package_dir/{{source_file_part}}",
+  ]
+
+  deps = []
+}
+
+group("cronet_package") {
+  deps = [
+    ":cronet_package_copy",
+    ":cronet_static",
+    ":generate_license",
+  ]
+}