GN: Add video_{de,en}code_accelerator_unittest targets

content/test/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build_overrides/v8.gni")
@@ skipping 890 matching lines @@
     "//testing/perf",
     "//ui/gfx",
     "//ui/gfx/geometry",
   ]
 
   if (is_android) {
     deps += [ "//testing/android/native_test:native_test_native_code" ]
   }
 }
 
-if (is_android) {
-  # TODO(GYP): Port Windows and ChromeOS logic.
+if (is_android || is_chromeos) {
+  # TODO(GYP): Port Windows logic.
   test("video_decode_accelerator_unittest") {
     deps = [
       "//base",
       "//content",
       "//media",
       "//testing/gtest",
       "//ui/base",
       "//ui/gfx",
       "//ui/gfx:test_support",
       "//ui/gfx/geometry",
       "//ui/gl",
       "//ui/gl:test_support",
     ]
     configs += [ "//third_party/khronos:khronos_headers" ]
+    if (is_chromeos && target_cpu != "arm") {
+      configs += [ "//third_party/libva:libva_config" ]
+    }

[piman, 2016/04/28 23:36:48]

nit: Why is this needed? the sources don't include anything from
third_party/libva. Is it a missing exported config from a dependency?

[stevenjb, 2016/04/29 17:17:56]

Otherwise we get this:

In file included from
../../content/common/gpu/media/video_decode_accelerator_unittest.cc:71:
In file included from
../../content/common/gpu/media/vaapi_video_decode_accelerator.h:32:
In file included from ../../content/common/gpu/media/vaapi_wrapper.h:25:
In file included from ../../content/common/gpu/media/va_surface.h:15:
../../third_party/libva/va/va.h:83:10: fatal error: 'va/va_version.h' file not
found
#include <va/va_version.h>

This was copeid from the .gyp file. I'm not sure if there is a better way to do
this in GN?

[Dirk Pranke, 2016/04/29 21:58:50]

//content/common should be exporting this as a public_config as well as listing
it in a config.

These test binaries should probably also be depending on the sub-componets of
content like content_common directly, rather than content as a whole.

     sources = [
       "//content/common/gpu/media/video_accelerator_unittest_helpers.h",
     ]
     if (is_android) {
       sources += [ "//content/common/gpu/media/android_video_decode_accelerator_unittest.cc" ]
     } else {
       sources += [
         "//content/common/gpu/media/rendering_helper.cc",
         "//content/common/gpu/media/rendering_helper.h",
         "//content/common/gpu/media/video_decode_accelerator_unittest.cc",
       ]
     }
 
     if (is_android) {
       deps += [
         "//gpu:test_support",
         "//media/base/android",
         "//media/base/android:media_java",
         "//media/capture/video/android:capture_java",
         "//testing/gmock",
         "//ui/android:ui_java",
       ]
     }
+    if (is_chromeos && use_ozone) {
+      deps += [
+        "//ui/display",  # Used by rendering_helper.cc
+        "//ui/ozone",  # Used by rendering_helper.cc
+      ]
+    }
+    if (use_x11) {
+      configs += [ "//build/config/linux:x11" ]
+      deps += [ "//ui/gfx/x" ]
+    }
   }
 }
+
+if (is_chromeos || is_mac) {
+  test("video_encode_accelerator_unittest") {
+    deps = [
+      "//base",
+      "//content",
+      "//media",
+      "//media/base:test_support",
+      "//testing/gtest",
+      "//ui/base",
+      "//ui/gfx",
+      "//ui/gfx:test_support",
+      "//ui/gfx/geometry",
+      "//ui/gl",
+      "//ui/gl:test_support",
+    ]
+    configs += [
+      "//third_party/libva:libva_config",
+      "//third_party/libyuv:libyuv_config",

[piman, 2016/04/28 23:36:48]

ditto (both)

[stevenjb, 2016/04/29 17:17:57]

ditto

[Dirk Pranke, 2016/04/29 21:58:50]

ditto.

+    ]
+    sources = [
+      "//content/common/gpu/media/video_accelerator_unittest_helpers.h",
+      "//content/common/gpu/media/video_encode_accelerator_unittest.cc",
+    ]
+    if (use_x11) {
+      deps += [ "//ui/gfx/x" ]
+    }
+    if (use_ozone) {
+      deps += [ "//ui/ozone" ]
+    }
+  }
+}