Make the GN build flag 'use_lld' usable on Linux.

build/config/compiler/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/chrome_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/nacl/config.gni")
 import("//build/toolchain/cc_wrapper.gni")
 import("//build/toolchain/toolchain.gni")
@@ skipping 27 matching lines @@
   binutils_path = rebase_path("//third_party/binutils/Linux_x64/Release/bin",
                               root_build_dir)
 
   # Compile in such a way as to make it possible for the profiler to unwind full
   # stack frames. Setting this flag has a large effect on the performance of the
   # generated code than just setting profiling, but gives the profiler more
   # information to analyze.
   # Requires profiling to be set to true.
   enable_full_stack_frames_for_profiling = false
 
+  # Set to true to use lld, the LLVM linker.

[brettw, 2016/04/27 22:55:46]

It seems this is Posixonly. If so, can you wrap this in an is_posix block so
it's not listed as available for other platforms? Put the comment inside the
block (the args help looks at the comment immediately above the variable and an
if statement in between will confuse it). If not or if this is going to change,
the comment should talk about when this flag is applicable.

[pcc1, 2016/04/27 23:21:05]

It's also available on Windows. I've added more information to the comment.

+  use_lld = false
+
   # TODO(GYP): We should be using 64-bit gold for linking on both 64-bit Linux
   # and 32-bit linux; 32-bit Gold runs out of address-space on 32-bit builds.
   # However, something isn't quite working right on the 32-bit builds.
-  use_gold = is_linux && (current_cpu == "x64" || current_cpu == "arm")
+  use_gold =
+      is_linux && (current_cpu == "x64" || current_cpu == "arm") && !use_lld

[brettw, 2016/04/27 22:55:46]

This won't actually do what you want. The build overrides are applied at the end
of the declare_args block so this won't see any user overrides of the use_lld
variable.

To fix this, make a new declare_args block after the current one and move
use_gold into it.

[pcc1, 2016/04/27 23:21:05]

Done.

 
   # When we are going to use gold we need to find it.
   # This is initialized below, after use_gold might have been overridden.
   gold_path = false
 
   # use_debug_fission: whether to use split DWARF debug info
   # files. This can reduce link time significantly, but is incompatible
   # with some utilities such as icecc and ccache. Requires gold and
   # gcc >= 4.8 or clang.
   # http://gcc.gnu.org/wiki/DebugFission
@@ skipping 223 matching lines @@
       "-Wl,-z,now",
       "-Wl,-z,relro",
     ]
     if (!using_sanitizer && !use_cfi_diag) {
       ldflags += [ "-Wl,-z,defs" ]
     }
   }
 
   # Linux-specific compiler flags setup.
   # ------------------------------------
-  if (use_gold) {
+  if (is_posix && use_lld) {
+    ldflags += [ "-fuse-ld=lld" ]
+  } else if (use_gold) {
     ldflags += [
       "-B$gold_path",
 
       # Newer gccs and clangs support -fuse-ld, use the flag to force gold
       # selection.
       # gcc -- http://gcc.gnu.org/onlinedocs/gcc-4.8.0/gcc/Optimize-Options.html
       "-fuse-ld=gold",
 
       # Experimentation found that using four linking threads
       # saved ~20% of link time.
       # https://groups.google.com/a/chromium.org/group/chromium-dev/browse_thread/thread/281527606915bb36
       # Only apply this to the target linker, since the host
       # linker might not be gold, but isn't used much anyway.
       # TODO(raymes): Disable threading because gold is frequently
       # crashing on the bots: crbug.com/161942.
       #"-Wl,--threads",
       #"-Wl,--thread-count=4",
     ]
 
     if (gdb_index) {
       ldflags += [ "-Wl,--gdb-index" ]
     }
 
-    if (!using_sanitizer && !(is_android && use_order_profiling)) {
-      # TODO(brettw) common.gypi has this only for target toolset.
-      ldflags += [ "-Wl,--icf=all" ]
-    }
-
     # TODO(thestig): Make this flag work with GN.
     #if (!is_official_build && !is_chromeos && !(is_asan || is_lsan || is_tsan || is_msan)) {
     #  ldflags += [
     #    "-Wl,--detect-odr-violations",
     #  ]
     #}
   } else if (linux_use_bundled_binutils) {
     # Gold is the default linker for the bundled binutils so we explicitly
     # enable the bfd linker when use_gold is not set.
     ldflags += [ "-fuse-ld=bfd" ]
   }
 
+  if (is_posix && (use_gold || use_lld) && !using_sanitizer &&
+      !(is_android && use_order_profiling)) {
+    # TODO(brettw) common.gypi has this only for target toolset.

[brettw, 2016/04/27 22:55:46]

I think you can delete this comment.

[pcc1, 2016/04/27 23:21:05]

Done.

+    ldflags += [ "-Wl,--icf=all" ]
+  }
+
   if (linux_use_bundled_binutils) {
     cflags += [ "-B$binutils_path" ]
   }
 
   # Clang-specific compiler flags setup.
   # ------------------------------------
   if (is_clang) {
     cflags += [ "-fcolor-diagnostics" ]
   }
 
@@ skipping 60 matching lines @@
   # that reason, we cannot allow targets to enable or disable these flags, for
   # example by disabling the optimize configuration.
   # TODO(pcc): Make this conditional on is_official_build rather than on gn
   # flags for specific features.
   if (!is_debug && (allow_posix_link_time_opt || is_cfi) && !is_nacl) {
     cflags += [ "-flto" ]
     ldflags += [ "-flto" ]
 
     # Apply a lower LTO optimization level as the default is too slow.
     if (is_linux) {
-      ldflags += [ "-Wl,-plugin-opt,O1" ]
+      if (use_lld) {
+        ldflags += [ "-Wl,--lto-O1" ]
+      } else {
+        ldflags += [ "-Wl,-plugin-opt,O1" ]
+      }
     } else if (is_mac) {
       ldflags += [ "-Wl,-mllvm,-O1" ]
     }
 
     # Work-around for http://openradar.appspot.com/20356002
     if (is_mac) {
       ldflags += [ "-Wl,-all_load" ]
     }
 
     # Allows the linker to apply ICF to the LTO object file. Also, when
@@ skipping 1016 matching lines @@
 
 if (is_ios || is_mac) {
   # On Mac and iOS, this enables support for ARC (automatic ref-counting).
   # See http://clang.llvm.org/docs/AutomaticReferenceCounting.html.
   config("enable_arc") {
     common_flags = [ "-fobjc-arc" ]
     cflags_objc = common_flags
     cflags_objcc = common_flags
   }
 }