[Mac/GN] Port tweak_info_plist.py and run it on //content targets.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/mac/base_rules.gni")
 
 # Generates Info.plist files for Mac apps and frameworks.
 #
 # Arguments
 #
 #     info_plist:
 #         string, the path to an plist file that will be included in the final
 #         Info.plist generated.
 #
 #     executable_name:
 #         string, name of the generated target used for the product
 #         and executable name as specified in the output Info.plist.
 #
 #     extra_substitutions:
 #         (optional) string array, 'key=value' pairs for extra fields which are
 #         specified in a source Info.plist template.
 template("mac_info_plist") {
+  assert(
+      (defined(invoker.info_plist) || defined(invoker.info_plist_target)) &&

[sdefresne, 2016/04/29 18:23:18]

Can't this be expressed more simply by "defined(invoker.info_plist) !=
defined(invoker.info_plist_target)"?
If neither is defined, or both, then the expression is false, if only one of
them is, then it is true. Or do I miss something?

[Robert Sesek, 2016/05/02 16:53:54]

Ah, yes, that's better.

+          !(defined(invoker.info_plist) && defined(invoker.info_plist_target)),
+      "Only one of info_plist or info_plist_target may be specified in " +
+          target_name)
+
+  if (defined(invoker.info_plist)) {
+    _info_plist = invoker.info_plist
+  } else {
+    _info_plist_target_output = get_target_outputs(invoker.info_plist_target)
+    _info_plist = _info_plist_target_output[0]
+  }
+
   info_plist(target_name) {
     format = "xml1"
     extra_substitutions = []
     if (defined(invoker.extra_substitutions)) {
       extra_substitutions = invoker.extra_substitutions
     }
     extra_substitutions += [
       "MAC_SDK_BUILD=$mac_sdk_build",
       "MAC_SDK_NAME=$mac_sdk_name$mac_sdk_version",
     ]
     plist_templates = [
       "//build/config/mac/BuildInfo.plist",
-      invoker.info_plist,
+      _info_plist,
     ]
-    forward_variables_from(invoker, [ "executable_name" ])
+    if (defined(invoker.info_plist_target)) {
+      deps = [
+        invoker.info_plist_target,
+      ]
+    }
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "executable_name",
+                           ])
   }
 }
 
 # Template to compile and package Mac XIB files as bundle data.
 #
 # Arguments
 #
 #     sources:
 #         list of string, sources to comiple
 #
@@ skipping 46 matching lines @@
 # This template provides two targets to control whether the framework is
 # merely built when targets depend on it, or whether it is linked as well:
 # "$target_name" and "$target_name+link".
 #
 # See the //build/config/mac/base_rules.gni:framework_bundle for a discussion
 # and examples.
 #
 # Arguments
 #
 #     info_plist:
 #         string, path to the Info.plist file that will be used for the bundle.

[sdefresne, 2016/04/29 18:23:18]

nit: info_plist is now also optional, isn't it?

[Robert Sesek, 2016/05/02 16:53:54]

Done.

 #
+#     info_plist_target:
+#         (optional) string, if the info_plist is generated from an action,
+#         rather than a regular source file, specify the target name in lieu
+#         of info_plist. The two arguments are mutually exclusive.
+#
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
 #         (optional) string, version of the framework. Typically this is a
 #         single letter, like "A". If omitted, the Versions/ subdirectory
 #         structure will not be created, and build output will go directly
 #         into the framework subdirectory.
 #
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("mac_framework_bundle") {
   assert(defined(invoker.deps),
          "Dependencies must be specified for $target_name")
-  assert(defined(invoker.info_plist),
+  assert(defined(invoker.info_plist) || defined(invoker.info_plist_target),
          "The Info.plist file must be specified for $target_name")
 
   _info_plist_target = target_name + "_info_plist"
 
   mac_info_plist(_info_plist_target) {
     executable_name = target_name
     if (defined(invoker.output_name)) {
       executable_name = invoker.output_name
     }
-    forward_variables_from(invoker, [ "info_plist" ])
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "info_plist",
+                             "info_plist_target",
+                           ])
   }
 
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
     sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
@@ skipping 10 matching lines @@
     }
     deps += [ ":$_info_plist_bundle_data" ]
   }
 }
 
 # Template to create a Mac executable application bundle.
 #
 # Arguments
 #
 #     info_plist:
 #         string, path to the Info.plist file that will be used for the bundle.

[sdefresne, 2016/04/29 18:23:18]

ditto

[Robert Sesek, 2016/05/02 16:53:54]

Done.

 #
+#     info_plist_target:
+#         (optional) string, if the info_plist is generated from an action,
+#         rather than a regular source file, specify the target name in lieu
+#         of info_plist. The two arguments are mutually exclusive.
+#
 #     output_name:
 #         (optional) string, name of the generated app without the
 #         .app suffix. If omitted, defaults to target_name.
 template("mac_app_bundle") {
-  assert(defined(invoker.info_plist),
+  assert(defined(invoker.info_plist) || defined(invoker.info_plist_target),

[sdefresne, 2016/04/29 18:23:18]

Shouldn't it be the same mutually exclusive test than before?

[Robert Sesek, 2016/05/02 16:53:54]

Does it make sense to duplicate that check? The mac_info_plist template, when
instantiated below, will perform that.

[sdefresne, 2016/05/03 07:12:17]

I wanted to say that we should either do the same check or no check, but not a
different check. Seems strange to have this template say "you can define any of
info_plist or info_plist_target, or none", and then fail if neither is set
because it use a more strict template. Either do no check and let the underlying
template fail, or duplicate the test.

[Robert Sesek, 2016/05/03 13:44:27]

Agreed on your reasoning. Removed the checks in favor of just having the
template do them. Duplication seems bad, since it means changing the check in
three places if it does need to change.

          "The Info.plist file must be specified for $target_name")
 
   _target_name = target_name
   _output_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
   _executable_target = target_name + "_executable"
   _executable_bundle_data = _executable_target + "_bundle_data"
 
+  _info_plist_target = target_name + "_info_plist"
+
+  mac_info_plist(_info_plist_target) {
+    executable_name = _output_name
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "info_plist",
+                             "info_plist_target",
+                           ])
+  }
+
   executable(_executable_target) {
     visibility = [ ":$_executable_bundle_data" ]
     forward_variables_from(invoker,
                            "*",
                            [
                              "assert_no_deps",
                              "data_deps",
                              "info_plist",
                              "output_name",
                              "visibility",
                            ])
     output_name = _output_name
     output_dir = "$target_out_dir/$_executable_target"
   }
 
   bundle_data(_executable_bundle_data) {
     visibility = [ ":$_target_name" ]
     forward_variables_from(invoker, [ "testonly" ])
     sources = [
       "$target_out_dir/$_executable_target/$_output_name",
     ]
     outputs = [
       "{{bundle_executable_dir}}/$_output_name",
     ]
     public_deps = [
       ":$_executable_target",
     ]
   }
 
-  _info_plist_target = target_name + "_info_plist"
-
-  mac_info_plist(_info_plist_target) {
-    executable_name = _output_name
-    forward_variables_from(invoker, [ "info_plist" ])
-  }
-
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
     visibility = [ ":$_target_name" ]
     sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
     public_deps = [
@@ skipping 78 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_output_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }