Reland of Generate Android .isolate files used for test()s

testing/test.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # ==============================================================================
 # TEST SETUP
 # ==============================================================================
 
+template("_gen_isolate") {
+  testonly = true
+  _runtime_deps_file = "$target_gen_dir/$target_name.runtime_deps"
+  group("${target_name}__write_deps") {
+    forward_variables_from(invoker,
+                           [
+                             "data",
+                             "data_deps",
+                             "deps",
+                             "public_deps",
+                           ])
+    write_runtime_deps = _runtime_deps_file
+  }
+
+  action(target_name) {
+    script = "//testing/generate_isolate.py"
+    outputs = [
+      invoker.output,
+    ]
+    args = [
+      "--output-directory=.",
+      "--out-file",
+      rebase_path(invoker.output, root_build_dir),
+      "--runtime-deps-file",
+      rebase_path(_runtime_deps_file, root_build_dir),
+    ]
+    if (is_android) {
+      args += [ "--apply-android-filters" ]
+    }
+    if (defined(invoker.apply_device_filters) && invoker.apply_device_filters) {
+      args += [ "--apply-device-filters" ]
+    }
+    _assert_no_odd_data =
+        defined(invoker.assert_no_odd_data) && invoker.assert_no_odd_data
+    if (_assert_no_odd_data) {
+      args += [ "--assert-no-odd-data" ]
+    }
+    if (defined(invoker.command)) {
+      _isolate_dir = get_path_info(invoker.output, "dir")
+      args += [
+        "--command",
+        rebase_path(invoker.command, _isolate_dir),
+      ]
+    }
+    deps = [
+      ":${invoker.target_name}__write_deps",
+    ]
+  }
+}
+
 # Define a test as an executable (or apk on Android) with the "testonly" flag
 # set.
 # Variable:
 #   use_raw_android_executable: Use executable() rather than android_apk().
 template("test") {
   if (is_android) {
     import("//build/config/android/config.gni")
     import("//build/config/android/rules.gni")
 
     _use_raw_android_executable = defined(invoker.use_raw_android_executable) &&
                                   invoker.use_raw_android_executable
 
     # output_name is used to allow targets with the same name but in different
     # packages to still produce unique runner scripts.
     _output_name = invoker.target_name
     if (defined(invoker.output_name)) {
       _output_name = invoker.output_name
     }
 
     _test_runner_target = "${_output_name}__test_runner_script"
     _wrapper_script_vars = [
       "isolate_file",
       "shard_timeout",
     ]
+    _gen_isolate_vars = [
+      "allow_odd_runtime_deps",
+      "ignore_all_data_deps",
+    ]
+
+    # TODO(agrieve): Delete all manually passed-in .isolate files now that they
+    #     are unused. http://crbug.com/589318
+    assert(!defined(invoker.isolate_file) || invoker.isolate_file != "")  # Mark used.
+    _generate_device_isolate =
+        !defined(invoker.ignore_all_data_deps) || !invoker.ignore_all_data_deps
+
+    if (_generate_device_isolate) {
+      _allow_odd_runtime_deps = defined(invoker.allow_odd_runtime_deps) &&
+                                invoker.allow_odd_runtime_deps
+
+      # The device isolate is needed at runtime, so it cannot go in
+      # target_gen_dir, as builder/tester configurations do not include it.
+      _target_dir_name = get_label_info(":$target_name", "dir")
+      _device_isolate_path = "$root_out_dir/gen.runtime/$_target_dir_name/$target_name.device.isolate"
+      _gen_isolate_target_name = "${target_name}__isolate"
+      _gen_isolate(_gen_isolate_target_name) {
+        data_deps = []
+        forward_variables_from(invoker,
+                               [
+                                 "data",
+                                 "data_deps",
+                                 "deps",
+                                 "public_deps",
+                               ])
+        assert_no_odd_data = !_allow_odd_runtime_deps
+        output = _device_isolate_path
+        apply_device_filters = true
+      }
+    }
 
     if (_use_raw_android_executable) {
       _exec_target = "${target_name}__exec"
       _dist_target = "${target_name}__dist"
       _exec_output =
           "$target_out_dir/${invoker.target_name}/${invoker.target_name}"
 
       executable(_exec_target) {
         # Configs will always be defined since we set_defaults in BUILDCONFIG.gn.
         configs = []
         data_deps = []
-        forward_variables_from(invoker, "*", [ "extra_dist_files" ])
+        forward_variables_from(
+            invoker,
+            "*",
+            _wrapper_script_vars + _gen_isolate_vars + [ "extra_dist_files" ])
         testonly = true
 
         # Thanks to the set_defaults() for test(), configs are initialized with
         # the default shared_library configs rather than executable configs.
         configs -= [
           "//build/config:shared_library_config",
           "//build/config/android:hide_native_jni_exports",
         ]
         configs += [ "//build/config:executable_config" ]
 
@@ skipping 24 matching lines @@
         "use_default_launcher",
         "write_asset_list",
       ]
       shared_library(_library_target) {
         # Configs will always be defined since we set_defaults in BUILDCONFIG.gn.
         configs = []  # Prevent list overwriting warning.
         configs = invoker.configs
         testonly = true
 
         deps = []
-        forward_variables_from(
-            invoker,
-            "*",
-            _apk_specific_vars + _wrapper_script_vars + [ "visibility" ])
+        forward_variables_from(invoker,
+                               "*",
+                               _apk_specific_vars + _wrapper_script_vars +
+                                   _gen_isolate_vars + [ "visibility" ])
 
         if (!defined(invoker.use_default_launcher) ||
             invoker.use_default_launcher) {
           deps += [ "//testing/android/native_test:native_test_native_code" ]
         }
       }
       unittest_apk(_apk_target) {
         forward_variables_from(invoker, _apk_specific_vars + [ "deps" ])
         unittests_dep = ":$_library_target"
         apk_name = invoker.target_name
@@ skipping 13 matching lines @@
         data_deps = [
           ":$_test_runner_target",
         ]
       }
 
       # Incremental test targets work only for .apks.
       _incremental_test_runner_target =
           "${_output_name}_incremental__test_runner_script"
       test_runner_script(_incremental_test_runner_target) {
         forward_variables_from(invoker, _wrapper_script_vars)
+        if (_generate_device_isolate) {
+          isolate_file = _device_isolate_path
+          deps = [
+            ":$_gen_isolate_target_name",
+          ]
+        }
         apk_target = ":$_apk_target"
         test_name = "${_output_name}_incremental"
         test_type = "gtest"
         test_suite = _output_name
         incremental_install = true
       }
       group("${target_name}_incremental") {
         testonly = true
         datadeps = [
           ":$_incremental_test_runner_target",
         ]
         deps = [
           ":${_apk_target}_incremental",
         ]
       }
     }
 
     _test_runner_target = "${_output_name}__test_runner_script"
     test_runner_script(_test_runner_target) {
       forward_variables_from(invoker, _wrapper_script_vars)
+      if (_generate_device_isolate) {
+        isolate_file = _device_isolate_path
+        deps = [
+          ":$_gen_isolate_target_name",
+        ]
+      }
+
       if (_use_raw_android_executable) {
         executable_dist_dir = "$root_out_dir/$_dist_target"
       } else {
         apk_target = ":$_apk_target"
       }
       test_name = _output_name
       test_type = "gtest"
       test_suite = _output_name
     }
 
@@ skipping 81 matching lines @@
     # TODO(GYP): Delete this after we've converted everything to GN.
     # The _run targets exist only for compatibility with GYP.
     group("${target_name}_run") {
       testonly = true
       deps = [
         ":${invoker.target_name}",
       ]
     }
   }
 }