MacViews: Implement NSResponder deletion action messages.

ui/views/cocoa/bridged_native_widget_unittest.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_native_widget.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include <memory>
 
@@ skipping 189 matching lines @@
   void InstallTextField(const std::string& text,
                         ui::TextInputType text_input_type);
 
   // Install a textfield with input type ui::TEXT_INPUT_TYPE_TEXT in the view
   // hierarchy and make it the text input client.
   void InstallTextField(const std::string& text);
 
   // Returns the current text as std::string.
   std::string GetText();
 
+  // Set the selection range for the installed textfield.
+  void SetSelectionRange(const gfx::Range& range);
+
   // testing::Test:
   void SetUp() override;
   void TearDown() override;
 
  protected:
+  // Test delete to beginning of line or paragraph based on |sel|.
+  void TestDeleteBeginning(SEL sel);
+
+  // Test delete to end of line or paragraph based on |sel|.
+  void TestDeleteEnd(SEL sel);
+
   std::unique_ptr<views::View> view_;
   BridgedContentView* ns_view_;  // Weak. Owned by bridge().
   base::MessageLoopForUI message_loop_;
 
  private:
   DISALLOW_COPY_AND_ASSIGN(BridgedNativeWidgetTest);
 };
 
 BridgedNativeWidgetTest::BridgedNativeWidgetTest() {
 }
@@ skipping 23 matching lines @@
   InstallTextField(text, ui::TEXT_INPUT_TYPE_TEXT);
 }
 
 std::string BridgedNativeWidgetTest::GetText() {
   NSRange range = NSMakeRange(0, NSUIntegerMax);
   NSAttributedString* text =
       [ns_view_ attributedSubstringForProposedRange:range actualRange:NULL];
   return SysNSStringToUTF8([text string]);
 }
 
+void BridgedNativeWidgetTest::SetSelectionRange(const gfx::Range& range) {
+  ui::TextInputClient* client = [ns_view_ textInputClient];
+  client->SetSelectionRange(range);
+}
+
 void BridgedNativeWidgetTest::SetUp() {
   BridgedNativeWidgetTestBase::SetUp();
 
   view_.reset(new views::internal::RootView(widget_.get()));
   base::scoped_nsobject<NSWindow> window([test_window() retain]);
 
   // BridgedNativeWidget expects to be initialized with a hidden (deferred)
   // window.
   [window orderOut:nil];
   EXPECT_FALSE([window delegate]);
   bridge()->Init(window, init_params_);
 
   // The delegate should exist before setting the root view.
   EXPECT_TRUE([window delegate]);
   bridge()->SetRootView(view_.get());
   ns_view_ = bridge()->ns_view();
 
   // Pretend it has been shown via NativeWidgetMac::Show().
   [window orderFront:nil];
   [test_window() makePretendKeyWindowAndSetFirstResponder:bridge()->ns_view()];
 }
 
 void BridgedNativeWidgetTest::TearDown() {
   if (bridge())
     bridge()->SetRootView(nullptr);
   view_.reset();
   BridgedNativeWidgetTestBase::TearDown();
 }
 
+void BridgedNativeWidgetTest::TestDeleteBeginning(SEL sel) {
+  InstallTextField("foo bar baz");
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Move the caret to the beginning of the line.
+  SetSelectionRange(gfx::Range(0));
+  // Verify no deletion takes place.
+  [ns_view_ doCommandBySelector:sel];
+  EXPECT_EQ("foo bar baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
+
+  // Move the caret as- "foo| bar baz".
+  SetSelectionRange(gfx::Range(3, 3));
+  [ns_view_ doCommandBySelector:sel];
+  // Verify state is "| bar baz".
+  EXPECT_EQ(" bar baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
+
+  // Make a selection as- " bar |baz|".
+  SetSelectionRange(gfx::Range(5, 8));
+  [ns_view_ doCommandBySelector:sel];
+  // Verify only the selection is deleted so that the state is " bar |".
+  EXPECT_EQ(" bar ", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(5, 0), [ns_view_ selectedRange]);
+}
+
+void BridgedNativeWidgetTest::TestDeleteEnd(SEL sel) {
+  InstallTextField("foo bar baz");
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Caret is at the end of the line. Verify no deletion takes place.
+  [ns_view_ doCommandBySelector:sel];
+  EXPECT_EQ("foo bar baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Move the caret as- "foo bar| baz".
+  SetSelectionRange(gfx::Range(7, 7));
+  [ns_view_ doCommandBySelector:sel];
+  // Verify state is "foo bar|".
+  EXPECT_EQ("foo bar", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(7, 0), [ns_view_ selectedRange]);
+
+  // Make a selection as- "|foo |bar".
+  SetSelectionRange(gfx::Range(0, 4));
+  [ns_view_ doCommandBySelector:sel];
+  // Verify only the selection is deleted so that the state is "|bar".
+  EXPECT_EQ("bar", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
+}
+
 // The TEST_VIEW macro expects the view it's testing to have a superview. In
 // these tests, the NSView bridge is a contentView, at the root. These mimic
 // what TEST_VIEW usually does.
 TEST_F(BridgedNativeWidgetTest, BridgedNativeWidgetTest_TestViewAddRemove) {
   base::scoped_nsobject<BridgedContentView> view([bridge()->ns_view() retain]);
   EXPECT_NSEQ([test_window() contentView], view);
   EXPECT_NSEQ(test_window(), [view window]);
 
   // The superview of a contentView is an NSNextStepFrame.
   EXPECT_TRUE([view superview]);
@@ skipping 281 matching lines @@
   EXPECT_EQ("a", GetText());
   EXPECT_EQ_RANGE(NSMakeRange(1, 0), [ns_view_ selectedRange]);
 
   // Should succeed after moving left first.
   [ns_view_ doCommandBySelector:@selector(moveLeft:)];
   [ns_view_ doCommandBySelector:@selector(deleteForward:)];
   EXPECT_EQ("", GetText());
   EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
 }
 
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteWordForward) {

[tapted, 2016/04/26 05:46:55]

I think we should try to make these cross-platform -- moving them in to
textfield_unittests.cc, and figure out where the gaps are (i.e. on what
platforms).

GTK has a rich set of keybindings, which Chrome probably ignores a lot of. See
e.g. GtkMovementStep at
https://developer.gnome.org/gtk3/stable/gtk3-Standard-Enumerations.html#GtkMo...
-- (i.e. Chrome on Linux should have a lot of these behaviours as well). It's
also nice where possible to show that adding all this MacViews stuff is
improving things for all platforms. i.e. not just tacking on a lot of
mac-specific functionality, but bringing a mac-like level of UI "excellence" to
all platforms.

[karandeepb, 2016/04/29 01:52:48]

Added a cross-platform test here-https://codereview.chromium.org/1923793002.
However I think we should also add tests to BridgedNativeWidgetTest.

Thanks for the link to the GTK keybindings. Will keep it in mind, when I add new
commands.

[tapted, 2016/04/29 04:15:39]

That's not really testing the beginning/end of line stuff. But since it's
actually hard to find precisely how delete beginning/end stuff should be mapped
to keys on other platforms, this approach seems reasonable, since it's only got
a clear keymapping on Mac. (on Linux I think delete-to-end might be Ctrl+U but
that's also "view source")

+  InstallTextField("foo bar baz");
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Caret is at the end of the line. Verify no deletion takes place.
+  [ns_view_ doCommandBySelector:@selector(deleteWordForward:)];
+  EXPECT_EQ("foo bar baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Move the caret as- "foo b|ar baz".
+  SetSelectionRange(gfx::Range(5, 5));
+  [ns_view_ doCommandBySelector:@selector(deleteWordForward:)];
+  // Verify state is "foo b| baz"
+  EXPECT_EQ("foo b baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(5, 0), [ns_view_ selectedRange]);
+
+  // Make a selection as- "|fo|o b baz".
+  SetSelectionRange(gfx::Range(0, 2));
+  [ns_view_ doCommandBySelector:@selector(deleteWordForward:)];
+  // Verify only the selection is deleted and state is "|o b baz".
+  EXPECT_EQ("o b baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
+}
+
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteWordBackward) {
+  InstallTextField("foo bar baz");
+  EXPECT_EQ_RANGE(NSMakeRange(11, 0), [ns_view_ selectedRange]);
+
+  // Move the caret to the beginning of the line.
+  SetSelectionRange(gfx::Range(0));
+  // Verify no deletion takes place.
+  [ns_view_ doCommandBySelector:@selector(deleteWordBackward:)];
+  EXPECT_EQ("foo bar baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(0, 0), [ns_view_ selectedRange]);
+
+  // Move the caret as- "foo ba|r baz".
+  SetSelectionRange(gfx::Range(6, 6));
+  [ns_view_ doCommandBySelector:@selector(deleteWordBackward:)];
+  // Verify state is "foo |r baz".
+  EXPECT_EQ("foo r baz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(4, 0), [ns_view_ selectedRange]);
+
+  // Make a selection as- "f|oo r b|az".
+  SetSelectionRange(gfx::Range(1, 7));
+  [ns_view_ doCommandBySelector:@selector(deleteWordBackward:)];
+  // Verify only the selection is deleted and state is "f|az"
+  EXPECT_EQ("faz", GetText());
+  EXPECT_EQ_RANGE(NSMakeRange(1, 0), [ns_view_ selectedRange]);
+}
+
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteToBeginningOfLine) {
+  TestDeleteBeginning(@selector(deleteToBeginningOfLine:));
+}
+
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteToEndOfLine) {
+  TestDeleteEnd(@selector(deleteToEndOfLine:));
+}
+
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteToBeginningOfParagraph) {
+  TestDeleteBeginning(@selector(deleteToBeginningOfParagraph:));
+}
+
+TEST_F(BridgedNativeWidgetTest, TextInput_DeleteToEndOfParagraph) {
+  TestDeleteEnd(@selector(deleteToEndOfParagraph:));
+}
+
 // Test firstRectForCharacterRange:actualRange for cases where query range is
 // empty or outside composition range.
 TEST_F(BridgedNativeWidgetTest, TextInput_FirstRectForCharacterRange_Caret) {
   InstallTextField("");
   ui::TextInputClient* client = [ns_view_ textInputClient];
 
   // No composition. Ensure bounds and range corresponding to the current caret
   // position are returned.
   // Initially selection range will be [0, 0].
   NSRange caret_range = NSMakeRange(0, 0);
@@ skipping 145 matching lines @@
   [center postNotificationName:NSWindowDidExitFullScreenNotification
                         object:window];
   EXPECT_EQ(1, [window ignoredToggleFullScreenCount]);  // No change.
   EXPECT_FALSE(bridge()->target_fullscreen_state());
 
   widget_->CloseNow();
 }
 
 }  // namespace test
 }  // namespace views