[iOS/Mac/GN] The framework_bundle template should not force dependencies to link it.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
 import("//build/config/mac/mac_sdk.gni")
 
-# This is used as the base template for both iOS and Mac frameworks..
+# This is used as the base template for both iOS and Mac frameworks.
+#
+# By default, the bundle target this template generates does not link the

[brettw, 2016/04/21 20:27:55]

This seems like it would work in the other place. I think it would be good to
give an explicit example.

[Robert Sesek, 2016/04/22 15:27:06]

Done.

+# resulting framework into anything that depends on it. If a dependency wants
+# a link-time (as well as build-time) dependency on the framework bundle,
+# depend against "$target_name+link". If only the build-time dependency is
+# required (e.g., for copying into another bundle), then use "$target_name".
 #
 # Arguments
 #
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
 #         (optional) string, version of the framework. Typically this is a
 #         single letter, like "A". If omitted, the Versions/ subdirectory
@@ skipping 54 matching lines @@
     public_deps = [
       ":$_shared_library_target",
     ]
   }
 
   _framework_public_config = _target_name + "_public_config"
   config(_framework_public_config) {
     # TODO(sdefresne): should we have a framework_dirs similar to lib_dirs
     # and include_dirs to avoid duplicate values on the command-line.
     visibility = [ ":$_framework_target" ]
-    common_flags = [ "-F" + rebase_path("$root_out_dir/.", root_out_dir) ]
-    cflags_objc = common_flags

[sdefresne, 2016/04/22 07:59:48]

I think we need -F in cflags_objc/cflags_objcc when we use a framework with
embedded headers (which happens on iOS with OCHamcrest and EarlGrey).

[Robert Sesek, 2016/04/22 15:27:06]

I moved that to the ios/rules.gni config since Mac doesn't ever use embedded
headers.

-    cflags_objcc = common_flags
-    ldflags = common_flags
+    ldflags = [ "-F" + rebase_path("$root_out_dir/.", root_out_dir) ]
     lib_dirs = [ root_out_dir ]
     libs = [ _framework_name ]
   }
 
   create_bundle(_framework_target) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
 
     if (defined(_framework_version)) {
       visibility = [ ":$_target_name" ]
     } else {
-      forward_variables_from(invoker, [ "visibility" ])
+      if (defined(invoker.visibility)) {
+        visibility = invoker.visibility
+        visibility += [ ":$_target_name+link" ]
+      }
     }
 
     if (!defined(public_deps)) {
       public_deps = []
     }
     public_deps += [ ":$_shared_library_bundle_data" ]
 
-    public_configs = [ ":$_framework_public_config" ]
-
     bundle_root_dir = _framework_root_dir
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir"
   }
 
   if (defined(_framework_version)) {
     action(_target_name) {
-      forward_variables_from(invoker,
-                             [
-                               "visibility",
-                               "testonly",
-                             ])
+      forward_variables_from(invoker, [ "testonly" ])
+
+      if (defined(invoker.visibility)) {
+        visibility = invoker.visibility
+        visibility += [ ":$_target_name+link" ]
+      }
+
       script = "$root_out_dir/gyp-mac-tool"
       outputs = [
         "$root_out_dir/$_framework_name/Versions/Current",
       ]
       args = [
         "package-framework",
         "$_framework_name",
         "$_framework_version",
       ]
       public_deps = [
         ":$_framework_target",
       ]
     }
   }
+
+  group(_target_name + "+link") {
+    forward_variables_from(invoker,
+                           [
+                             "visibility",
+                             "testonly",
+                           ])
+    public_deps = [
+      ":$_target_name",
+    ]
+    public_configs = [ ":$_framework_public_config" ]
+  }
 }
 
 # Template to combile .xib or .storyboard files.
 #
 #
 # Arguments
 #
 #     sources:
 #         list of string, sources to compile
 #
@@ skipping 266 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_target_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }