Add a dependency for FlatBuffers.

third_party/flatbuffers/BUILD.gn

+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+config("flatbuffers_config") {
+  include_dirs = [ "src/include" ]
+}
+
+static_library("flatbuffers") {

[brettw, 2016/04/21 20:00:03]

This should be a source_set.

[battre, 2016/04/25 14:31:47]

Done. I have also deleted flathash.cpp, which should not be there.

+  sources = [
+    "src/include/flatbuffers/flatbuffers.h",
+    "src/include/flatbuffers/hash.h",
+    "src/src/flathash.cpp",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+  public_configs = [ ":flatbuffers_config" ]
+}
+
+source_set("compiler_files") {
+  sources = [

[brettw, 2016/04/21 20:00:03]

Can you set
  visibility = [ ":*" ]
here so targets outside of here don't depend on this (just good hygiene).

[battre, 2016/04/25 14:31:47]

Done.

+    "src/include/idl.h",
+    "src/include/util.h",
+    "src/src/idl_gen_cpp.cpp",
+    "src/src/idl_gen_fbs.cpp",
+    "src/src/idl_gen_general.cpp",
+    "src/src/idl_gen_go.cpp",
+    "src/src/idl_gen_js.cpp",
+    "src/src/idl_gen_php.cpp",
+    "src/src/idl_gen_python.cpp",
+    "src/src/idl_gen_text.cpp",
+    "src/src/idl_parser.cpp",
+    "src/src/reflection.cpp",
+    "src/src/util.cpp",
+  ]
+  deps = [
+    ":flatbuffers",
+  ]
+}
+
+executable("flatc") {
+  sources = [
+    "src/src/flatc.cpp",
+  ]
+  deps = [
+    ":compiler_files",
+    ":flatbuffers",
+  ]
+}
+
+# The following is just for testing.
+
+import("//third_party/flatbuffers/flatc.gni")
+
+flatbuffers_library("flatbuffers_samplebuffer") {
+  testonly = true
+  sources = [
+    "src/tests/include_test1.fbs",
+    "src/tests/include_test2.fbs",
+    "src/tests/monster_test.fbs",
+    "src/tests/namespace_test/namespace_test1.fbs",
+    "src/tests/namespace_test/namespace_test2.fbs",
+  ]
+}
+
+executable("flatbuffers_unittest") {

[brettw, 2016/04/21 20:00:02]

This should use the test() template in //testing/test.gni (it will produce an
executable on desktop so shouldn't change what you did here).

[battre, 2016/04/25 14:31:47]

Done.

+  testonly = true
+  sources = [
+    # The following files are not included in :flatbuffers
+    # but are listed here because test.cpp tests more than what will
+    # get included into Chrome (reflection and generation).
+    "src/include/reflection.h",
+    "src/include/reflection_generated.h",
+
+    # This is the actual test.
+    "src/tests/test.cpp",
+  ]
+  deps = [
+    ":compiler_files",
+    ":flatbuffers",
+    ":flatbuffers_samplebuffer",
+  ]
+}