[Mac/iOS/GN] Re-purpose the ios_compile_xib.py file to also handle Mac XIBs.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
+import("//build/config/mac/mac_sdk.gni")
 
 # This is used as the base template for both iOS and Mac frameworks..
 #
 # Arguments
 #
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
@@ skipping 114 matching lines @@
         "$_framework_name",
         "$_framework_version",
       ]
       public_deps = [
         ":$_framework_target",
       ]
     }
   }
 }
 
+# Template to combile .xib or .storyboard files.
+#
+#
+# Arguments
+#
+#     sources:
+#         list of string, sources to compile
+#
+#     ibtool_flags:
+#         (optional) list of string, additional flags to pass to the ibtool
+template("compile_xibs") {
+  action_foreach(target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "visibility",
+                           ])
+    assert(defined(invoker.sources),
+           "Sources must be specified for $target_name")
+
+    ibtool_flags = []
+    if (defined(invoker.ibtool_flags)) {
+      ibtool_flags = invoker.ibtool_flags
+    }
+
+    script = "//build/config/mac/compile_xib.py"
+    sources = invoker.sources
+    outputs = [
+      "$target_gen_dir/{{source_name_part}}.nib",
+    ]
+    args = [
+             "--input",
+             "{{source}}",

[sdefresne, 2016/04/19 07:09:10]

Nice, I didn't knew about this, I was always using rebase_path(sources,
root_out_dir).

+             "--output",
+             rebase_path("$target_gen_dir/{{source_name_part}}.nib"),
+           ] + ibtool_flags
+  }
+}
+
+# Template to compile and package Mac XIB files as bundle data.
+#
+# Arguments
+#
+#     sources:
+#         list of string, sources to comiple
+#
+#     output_path:
+#         (optional) string, the path to use for the outputs list in the
+#         bundle_data step. If unspecified, defaults to bundle_resources_dir.
+template("mac_xib_bundle_data") {
+  _target_name = target_name
+  _compile_target_name = _target_name + "_compile_ibtool"
+
+  compile_xibs(_compile_target_name) {
+    forward_variables_from(invoker, [ "testonly" ])
+    visibility = [ ":$_target_name" ]
+    sources = invoker.sources
+    ibtool_flags = [
+      "--minimum-deployment-target",
+      mac_deployment_target,
+      "--target-device",
+      "mac",
+    ]
+  }
+
+  bundle_data(_target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "testonly",
+                             "visibility",
+                           ])
+
+    public_deps = [
+      ":$_compile_target_name",
+    ]
+    sources = get_target_outputs(":$_compile_target_name")
+
+    _output_path = "{{bundle_resources_dir}}"
+    if (defined(invoker.output_path)) {
+      _output_path = invoker.output_path
+    }
+
+    outputs = [
+      "$_output_path/{{source_file_part}}",
+    ]
+  }
+}
+
 # Template to package a shared library into a Mac framework bundle.
 #
 # Arguments
 #
 #     info_plist:
 #         string, path to the Info.plist file that will be used for the bundle.
 #
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
@@ skipping 176 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_target_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }