Fix blacklist_test_dll_3 linking every time in GN Windows.

chrome_elf/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/win/manifest.gni")
 import("//chrome/version.gni")
 import("//testing/test.gni")
 
 process_version("chrome_elf_resources") {
   template_file = chrome_version_rc_template
   sources = [
     "chrome_elf.ver",
   ]
   output = "$target_gen_dir/chrome_elf_version.rc"
 }
 
 # This manifest matches what GYP produces. It may not even be necessary.
 windows_manifest("chrome_elf_manifest") {
   sources = [
     as_invoker_manifest,
   ]
   type = "dll"
 }
 
 shared_library("chrome_elf") {
   sources = [
+    "chrome_elf.def",
     "chrome_elf_main.cc",
     "chrome_elf_main.h",
   ]
   deps = [
     ":blacklist",
     ":breakpad",
     ":chrome_elf_manifest",
     ":chrome_elf_resources",
     ":common",
     "//build/config/sanitizers:deps",
   ]
   configs += [ "//build/config/win:windowed" ]
   configs -= [ "//build/config/win:console" ]
-  ldflags = [
-    "/NODEFAULTLIB:user32.lib",
-    "/DEF:" + rebase_path("chrome_elf.def"),
-  ]
+  ldflags = [ "/NODEFAULTLIB:user32.lib" ]
   if (current_cpu == "x86") {
     # Don"t set an x64 base address (to avoid breaking HE-ASLR).
     ldflags += [ "/BASE:0x01c20000" ]
   }
 }
 
 source_set("constants") {
   sources = [
     "chrome_elf_constants.cc",
     "chrome_elf_constants.h",
@@ skipping 100 matching lines @@
     ":blacklist_test_dll_1",
     ":blacklist_test_dll_2",
     ":blacklist_test_dll_3",
     ":chrome_elf",
   ]
 }
 
 shared_library("blacklist_test_main_dll") {
   sources = [
     "blacklist/test/blacklist_test_main_dll.cc",
+    "blacklist/test/blacklist_test_main_dll.def",
   ]
   deps = [
     ":blacklist",
     ":common",
     "//base",
     "//build/config/sanitizers:deps",
   ]
-  ldflags =
-      [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_main_dll.def",
-                              root_build_dir) ]
 }
 
-shared_library("blacklist_test_dll_1") {
+loadable_module("blacklist_test_dll_1") {
   sources = [
     "blacklist/test/blacklist_test_dll_1.cc",
+    "blacklist/test/blacklist_test_dll_1.def",
   ]
-  ldflags = [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_dll_1.def",
-                                    root_build_dir) ]
   deps = [
     "//build/config/sanitizers:deps",
   ]
 }
 
-shared_library("blacklist_test_dll_2") {
+loadable_module("blacklist_test_dll_2") {
   sources = [
     "blacklist/test/blacklist_test_dll_2.cc",
+    "blacklist/test/blacklist_test_dll_2.def",
   ]
-  ldflags = [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_dll_2.def",
-                                    root_build_dir) ]
   deps = [
     "//build/config/sanitizers:deps",
   ]
 }
 
-shared_library("blacklist_test_dll_3") {
+# As-is, this does not generate a .lib file because there are no exports and no
+# .def file. The current definition of loadable_module does not declare a .lib
+# file as an output, so this is OK. If it did (or if this used shared_library
+# which does), Ninja would get confused and always rebuild this target because
+# it sees a declared output file but that file doesn't exist on disk.
+loadable_module("blacklist_test_dll_3") {
   sources = [
     "blacklist/test/blacklist_test_dll_3.cc",
   ]
   deps = [
     "//build/config/sanitizers:deps",
   ]
 }