Web shell test to go back and forward.

ios/web/shell/test/web_view_matchers.mm

Index: ios/web/shell/test/web_view_matchers.mm
diff --git a/ios/web/shell/test/web_view_matchers.mm b/ios/web/shell/test/web_view_matchers.mm
new file mode 100644
index 0000000000000000000000000000000000000000..a3fb1d1208a51caa1eb4781cb5938957fa7ed370
--- /dev/null
+++ b/ios/web/shell/test/web_view_matchers.mm
@@ -0,0 +1,82 @@
+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/web/shell/test/web_view_matchers.h"
+
+#import <WebKit/WebKit.h>
+
+#include "base/mac/bind_objc_block.h"
+#include "base/strings/sys_string_conversions.h"
+#include "base/strings/utf_string_conversions.h"
+#include "base/test/ios/wait_util.h"
+#include "base/values.h"
+#include "ios/web/public/web_state/web_state.h"
+#include "ios/web/shell/test/navigation_test_util.h"
+#include "ios/web/shell/test/web_shell_test_util.h"
+
+namespace {
+
+// Constant for UI wait loop in seconds.
+const NSTimeInterval kSpinDelaySeconds = 0.01;
+
+// Constant for timeout in seconds while waiting for web element.
+const NSTimeInterval kWaitForWebElementTimeout = 4.0;
+
+// Script that returns document.body as a string.
+char kGetDocumentBodyJavaScript[] =
+    "document.body ? document.body.textContent : null";
+}
+
+@implementation GREYMatchers (WebViewAdditions)
+
++ (id<GREYMatcher>)matcherForWebViewContainingText:(NSString*)text {
+  MatchesBlock matches = ^BOOL(UIView* view) {
+    if (![view isKindOfClass:[WKWebView class]]) {
+      return NO;
+    }
+
+    ViewController* viewController =
+        web::web_shell_test_util::GetCurrentViewController();
+    web::WebState* webState = [viewController webState];
+
+    __block BOOL didSucceed = NO;
+    NSDate* deadline =
+        [NSDate dateWithTimeIntervalSinceNow:kWaitForWebElementTimeout];
+    while (([[NSDate date] compare:deadline] != NSOrderedDescending) &&
+           !didSucceed) {
+      webState->ExecuteJavaScript(
+          base::UTF8ToUTF16(kGetDocumentBodyJavaScript),
+          base::BindBlock(^(const base::Value* value) {
+            std::string response;
+            if (value && value->IsType(base::Value::TYPE_STRING) &&
+                value->GetAsString(&response)) {
+              didSucceed = response.find(base::SysNSStringToUTF8(text)) !=
+                           std::string::npos;
+            }
+          }));
+      base::test::ios::SpinRunLoopWithMaxDelay(
+          base::TimeDelta::FromSecondsD(kSpinDelaySeconds));
+    }
+    return didSucceed;
+  };
+
+  DescribeToBlock describe = ^(id<GREYDescription> description) {
+    [description
+        appendText:[NSString stringWithFormat:@"web view containing %@", text]];
+  };
+
+  return [[[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                               descriptionBlock:describe]
+      autorelease];
+}
+
+@end
+
+#if !(GREY_DISABLE_SHORTHAND)
+
+id<GREYMatcher> shell_webViewContainingText(NSString* text) {
+  return [GREYMatchers matcherForWebViewContainingText:text];
+}
+
+#endif