unbundle: add shim_headers.gni and unbundled GN file for zlib

build/linux/unbundle/zlib.gn

Index: build/linux/unbundle/zlib.gn
diff --git a/build/linux/unbundle/zlib.gn b/build/linux/unbundle/zlib.gn
new file mode 100644
index 0000000000000000000000000000000000000000..9d41917c5d31898acb9067780b1bad8ccfa43447
--- /dev/null
+++ b/build/linux/unbundle/zlib.gn
@@ -0,0 +1,61 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/shim_headers.gni")
+
+shim_headers("zlib_shim") {
+  root_path = "."
+  headers = [ "zlib.h" ]
+}
+
+static_library("zlib") {

[brettw, 2016/04/14 20:20:07]

This should be a source_set.

+  deps = [
+    ":zlib_shim",
+  ]
+  libs = [ "z" ]
+}
+
+shim_headers("minizip_shim") {
+  root_path = "contrib"
+  headers = [
+    "minizip/crypt.h",
+    "minizip/ioapi.h",
+    "minizip/iowin32.h",
+    "minizip/mztools.h",
+    "minizip/unzip.h",
+    "minizip/zip.h",
+  ]
+}
+
+static_library("minizip") {

[brettw, 2016/04/14 20:20:07]

This should be a source_set.

+  deps = [
+    ":minizip_shim",
+  ]
+  libs = [ "minizip" ]
+}
+
+static_library("zip") {
+  sources = [
+    "google/zip.cc",
+    "google/zip.h",
+    "google/zip_internal.cc",
+    "google/zip_internal.h",
+    "google/zip_reader.cc",
+    "google/zip_reader.h",
+  ]
+  deps = [
+    ":minizip",
+    "//base",
+  ]
+}
+
+static_library("compression_utils") {
+  sources = [
+    "google/compression_utils.cc",
+    "google/compression_utils.h",
+  ]
+  deps = [
+    ":zlib",
+  ]
+}