[iOS/GN] Convert //ios/third_party/earl_grey to build with GN.

build/config/ios/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ios/ios_sdk.gni")
 import("//build/config/mac/rules.gni")
 
 # TODO(crbug.com/297668): refactor this template to extract common behaviour
 # between OS X and iOS bundle generation, then create a generic "app" template
 # that forward to "executable" on all platform except iOS/OS X.
@@ skipping 236 matching lines @@
 #         into the framework subdirectory.
 #
 #     public_headers:
 #         (optional) list of paths to header file that needs to be copied
 #         into the framework bundle Headers subdirectory. If omitted or
 #         empty then the Headers subdirectory is not created.
 #
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("ios_framework_bundle") {
+  _target_name = target_name
+  _framework_target = _target_name
+
   if (defined(invoker.public_headers) && invoker.public_headers != []) {
-    _target_name = target_name
     _output_name = target_name
     if (defined(invoker.output_name)) {
       _output_name = invoker.output_name
     }
 
     _public_headers = invoker.public_headers
     _framework_name = _output_name + ".framework"
     _framework_root = "$root_out_dir/$_framework_name"
+    _framework_target = target_name + "_internal"
 
     _header_map_filename = "$target_gen_dir/$_output_name.headers.hmap"
     _framework_headers_target = _target_name + "_framework_headers"
 
     _compile_headers_map_target = _target_name + "_compile_headers_map"
     action(_compile_headers_map_target) {
       visibility = [ ":$_framework_headers_target" ]
       script = "$root_out_dir/gyp-mac-tool"
       outputs = [
         _header_map_filename,
@@ skipping 35 matching lines @@
         "$_framework_root/Headers/{{source_file_part}}",
       ]
     }
 
     _headers_map_config = _target_name + "_headers_map"
     config(_headers_map_config) {
       visibility = [ ":$_target_name" ]
       include_dirs = [ _header_map_filename ]
     }
 
+    _framework_public_config = _target_name + "_public_config"
+    config(_framework_public_config) {
+      # TODO(sdefresne): should we have a framework_dirs similar to lib_dirs
+      # and include_dirs to avoid duplicate values on the command-line.
+      common_flags = [ "-F" + rebase_path("$root_out_dir/.", root_out_dir) ]
+      cflags_objc = common_flags
+      cflags_objcc = common_flags
+      ldflags = common_flags
+      lib_dirs = [ root_out_dir ]
+      libs = [ _framework_name ]
+    }
+
     group(_framework_headers_target) {
       deps = [
         ":$_compile_headers_map_target",
         ":$_copy_public_headers_target",
         ":$_create_module_map_target",
       ]
     }
   }
 
-  framework_bundle(target_name) {
-    forward_variables_from(invoker, "*", [ "public_headers" ])
+  framework_bundle(_framework_target) {
+    forward_variables_from(invoker,
+                           "*",
+                           [
+                             "public_headers",
+                             "visibility",
+                           ])
 
     if (defined(_public_headers)) {
+      visibility = [ ":$_target_name" ]
       configs += [ ":$_headers_map_config" ]
+
       if (!defined(deps)) {
         deps = []
       }
       deps += [ ":$_framework_headers_target" ]
+    } else {
+      forward_variables_from(invoker, [ "visibility" ])
+    }
+  }
+
+  if (defined(_public_headers)) {
+    group(_target_name) {
+      forward_variables_from(invoker,
+                             [
+                               "testonly",
+                               "visibility",
+                               "public_configs",
+                             ])
+
+      deps = [
+        ":$_framework_target",
+      ]
+      if (!defined(public_configs)) {
+        public_configs = []
+      }
+      public_configs += [ ":$_framework_public_config" ]
     }
   }
 }