[Mac/GN] Add new template for creating .plugin loadable modules.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
 
 # This is used as the base template for both iOS and Mac frameworks..
 #
 # Arguments
 #
@@ skipping 260 matching lines @@
     deps += [
       ":$_executable_bundle_data",
       ":$_info_plist_bundle_data",
     ]
 
     bundle_root_dir = "$root_out_dir/${_output_name}.app/Contents"
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }
+
+# Template to package a loadable_module into a .plugin bundle.
+#
+# This takes no extra arguments that differ from a loadable_module.
+template("mac_plugin_bundle") {
+  assert(defined(invoker.deps),
+         "Dependencies must be specified for $target_name")
+
+  _target_name = target_name
+  _loadable_module_target = _target_name + "_loadable_module"
+  _loadable_module_bundle_data = _loadable_module_target + "_bundle_data"
+
+  loadable_module(_loadable_module_target) {
+    visibility = [ ":$_loadable_module_bundle_data" ]
+    forward_variables_from(invoker,
+                           "*",
+                           [
+                             "assert_no_deps",
+                             "data_deps",
+                             "output_name",
+                             "visibility",
+                           ])
+  }
+
+  bundle_data(_loadable_module_bundle_data) {
+    visibility = [ ":$_target_name" ]
+    sources = [
+      "$root_out_dir/${_loadable_module_target}.so",
+    ]
+    outputs = [
+      "{{bundle_executable_dir}}/$_target_name",
+    ]
+    public_deps = [
+      ":$_loadable_module_target",
+    ]
+  }
+
+  create_bundle(_target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "data_deps",
+                             "deps",
+                             "public_deps",
+                             "testonly",
+                             "visibility",
+                           ])
+    if (!defined(deps)) {
+      deps = []
+    }
+    deps += [ ":$_loadable_module_bundle_data" ]
+
+    bundle_root_dir = "$root_out_dir/$_target_name.plugin/Contents"
+    bundle_executable_dir = "$bundle_root_dir/MacOS"
+  }
+}