Mac/iOS/GN: Generate Info.plist files for Mac apps and frameworks with gn.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
+import("//build/config/mac/mac_sdk.gni")
+import("//build/util/version.gni")
 
-# This is used as the base template for both iOS and Mac frameworks..
+# Used to generate an Info.plist file for iOS and Mac apps and frameworks.

[Robert Sesek, 2016/04/19 14:49:04]

Also document the Arguments as the other templates do below.

[Patti Lor, 2016/04/21 08:02:09]

Done.

+template("info_plist") {
+  _generate_info_plist = target_name + "_action"
+
+  action(_generate_info_plist) {
+    script = "//build/config/mac/gen_plist.py"
+    sources = [
+      "//build/config/mac/BuildInfo.plist",
+      invoker.info_plist,
+    ]
+    outputs = [
+      "$target_gen_dir/Info.plist",
+    ]
+    extra_args = []
+    if (defined(invoker.extra_substitutions)) {
+      foreach(substitution, invoker.extra_substitutions) {
+        extra_args += [ "-s=$substitution" ]
+      }
+    }
+    response_file_contents =
+        extra_args + [
+          "-s=MAC_SDK_BUILD=$mac_sdk_build",
+          "-s=MAC_SDK_NAME=$mac_sdk_name$mac_sdk_version",
+          "-s=BUILD_MACHINE_OS_BUILD=$machine_os_build",
+          "-s=GCC_VERSION=com.apple.compilers.llvm.clang.1_0",
+          "-s=XCODE_BUILD=$xcode_build",
+          "-s=XCODE_VERSION=$xcode_version",
+          "-s=VERSION=$chrome_version_full",
+          "-s=VERSION_BUILD=$chrome_version_build",
+          "-o=" + rebase_path(outputs[0], root_build_dir),
+        ] + rebase_path(sources, root_build_dir)
+    args = [ "@{{response_file_name}}" ]
+  }
+
+  source_set(target_name) {
+    sources = get_target_outputs(":$_generate_info_plist")
+    public_deps = [
+      ":$_generate_info_plist",
+    ]
+  }
+}
+
+# This is used as the base template for both iOS and Mac frameworks.
 #
 # Arguments
 #
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
 #         (optional) string, version of the framework. Typically this is a
 #         single letter, like "A". If omitted, the Versions/ subdirectory
 #         structure will not be created, and build output will go directly
 #         into the framework subdirectory.
 #
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("framework_bundle") {
   _target_name = target_name
   _output_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
-  # If the framework is unversionned, the final _target_name will be the
+  # If the framework is unversioned, the final _target_name will be the
   # create_bundle(_framework_target), otherwise an action with the name
   # _target_name will depends on the the create_bundle() in order to prepare
   # the versioned directory structure.
   _framework_target = _target_name
   _framework_name = _output_name + ".framework"
   _framework_root_dir = "$root_out_dir/$_framework_name"
   if (defined(invoker.framework_version) && invoker.framework_version != "") {
     _framework_version = invoker.framework_version
     _framework_root_dir += "/Versions/$_framework_version"
     _framework_target = _target_name + "_create_bundle"
@@ skipping 101 matching lines @@
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("mac_framework_bundle") {
   assert(defined(invoker.deps),
          "Dependencies must be specified for $target_name")
   assert(defined(invoker.info_plist),
          "The Info.plist file must be specified for $target_name")
 
   _info_plist_target = target_name + "_info_plist"
 
   # TODO(rsesek): Process Info.plist variables.

[Robert Sesek, 2016/04/19 14:49:04]

Remove, since you're doing it :).

[Patti Lor, 2016/04/21 08:02:09]

Done.

+  info_plist(_info_plist_target) {
+    forward_variables_from(invoker, [ "info_plist" ])
+  }
 
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
     sources = [
+      "$target_gen_dir/Info.plist",
       invoker.info_plist,
     ]
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
+    public_deps = [
+      ":$_info_plist_target",
+    ]
   }
 
   framework_bundle(target_name) {
     forward_variables_from(invoker, "*", [ "info_plist" ])
 
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_info_plist_bundle_data" ]
   }
@@ skipping 46 matching lines @@
     outputs = [
       "{{bundle_executable_dir}}/$_output_name",
     ]
     public_deps = [
       ":$_executable_target",
     ]
   }
 
   _info_plist_target = target_name + "_info_plist"
 
   # TODO(rsesek): Process Info.plist variables.

[Robert Sesek, 2016/04/19 14:49:04]

Remove.

[Patti Lor, 2016/04/21 08:02:09]

Done.

+  info_plist(_info_plist_target) {
+    forward_variables_from(invoker, [ "info_plist" ])
+    if (!defined(extra_substitutions)) {

[Robert Sesek, 2016/04/19 14:49:04]

Since you're not forward_varaibles_from()-ing extra_substitutions, this will
never be hit. I don't think there's a need yet for targets to define their own
substitutions, so you can remove this if block.

[Patti Lor, 2016/04/21 08:02:09]

Done.

+      extra_substitutions = []
+    }
+    extra_substitutions += [
+      "PRODUCT_NAME=$_output_name",

[Robert Sesek, 2016/04/19 14:49:04]

These subs are needed in the mac_framework_bundle version as well.

[Patti Lor, 2016/04/21 08:02:09]

Done.

+      "EXECUTABLE_NAME=$_output_name",
+    ]
+  }
 
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
     visibility = [ ":$_target_name" ]
     sources = [
+      "$target_gen_dir/Info.plist",
       invoker.info_plist,
     ]
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
+    public_deps = [
+      ":$_info_plist_target",
+    ]
   }
 
   create_bundle(_target_name) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [
       ":$_executable_bundle_data",
       ":$_info_plist_bundle_data",
     ]
 
     bundle_root_dir = "$root_out_dir/${_output_name}.app/Contents"
     bundle_resources_dir = "$bundle_root_dir/Resources"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }