Mac/iOS/GN: Generate Info.plist files for Mac apps and frameworks with gn.

build/config/mac/rules.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
 import("//build/config/mac/mac_sdk.gni")
+import("//build/util/version.gni")
 
-# This is used as the base template for both iOS and Mac frameworks..
+# The base template used to generate Info.plist files for iOS and Mac apps and
+# frameworks.
 #
 # Arguments
 #
+#     plist_templates:
+#         string array, paths to plist files which will be used for the bundle.
+#
+#     executable_name:
+#         string, name of the generated target used for the product
+#         and executable name as specified in the output Info.plist.
+#
+#     extra_substitutions:
+#         (optional) string array, 'key=value' pairs for extra fields which are
+#         specified in a source Info.plist template.
+template("info_plist") {
+  assert(defined(invoker.plist_templates),
+         "A list of template plist files must be specified for $target_name")
+  assert(defined(invoker.executable_name),
+         "The output_name file must be specified for $target_name")

[Robert Sesek, 2016/04/22 04:34:40]

"output_name file" -> "executable_name"

[Patti Lor, 2016/04/26 03:25:15]

Done.

+  executable_name = invoker.executable_name
+
+  action(target_name) {
+    script = "//build/config/mac/gen_plist.py"
+    sources = invoker.plist_templates
+    outputs = [
+      "$target_gen_dir/$target_name.plist",
+    ]
+    extra_args = []
+    if (defined(invoker.extra_substitutions)) {
+      foreach(substitution, invoker.extra_substitutions) {
+        extra_args += [ "-s=$substitution" ]
+      }
+    }
+    response_file_contents =
+        extra_args + [
+          "-s=BUILD_MACHINE_OS_BUILD=$machine_os_build",
+          "-s=EXECUTABLE_NAME=$executable_name",
+          "-s=GCC_VERSION=com.apple.compilers.llvm.clang.1_0",
+          "-s=PRODUCT_NAME=$executable_name",
+          "-s=VERSION=$chrome_version_full",

[Robert Sesek, 2016/04/22 04:34:40]

Remove VERSION and VERSION_BUILD from the template, since those should be set
only by the chrome target (when it uses this).

[Patti Lor, 2016/04/26 03:25:15]

Done.

+          "-s=VERSION_BUILD=$chrome_version_build",
+          "-s=XCODE_BUILD=$xcode_build",
+          "-s=XCODE_VERSION=$xcode_version",
+          "-o=" + rebase_path(outputs[0], root_build_dir),
+        ] + rebase_path(sources, root_build_dir)
+    args = [ "@{{response_file_name}}" ]
+  }
+}
+
+# Generates Info.plist files for Mac apps and frameworks.
+#
+# Arguments
+#
+#     info_plist:
+#         string, the path to an plist file that will be included in the final
+#         Info.plist generated.
+#
+#     executable_name:
+#         string, name of the generated target used for the product
+#         and executable name as specified in the output Info.plist.
+#
+#     extra_substitutions:
+#         (optional) string array, 'key=value' pairs for extra fields which are
+#         specified in a source Info.plist template.
+template("mac_info_plist") {
+  info_plist(target_name) {
+    extra_substitutions = []
+    if (defined(invoker.extra_substitutions)) {
+      extra_substitutions = invoker.extra_substitutions
+    }
+    extra_substitutions += [
+      "MAC_SDK_BUILD=$mac_sdk_build",
+      "MAC_SDK_NAME=$mac_sdk_name$mac_sdk_version",
+    ]
+    plist_templates = [
+      "//build/config/mac/BuildInfo.plist",
+      invoker.info_plist,
+    ]
+    forward_variables_from(invoker, [ "executable_name" ])
+  }
+}
+
+# This is used as the base template for both iOS and Mac frameworks.
+#
+# Arguments
+#
 #     output_name:
 #         (optional) string, name of the generated framework without the
 #         .framework suffix. If omitted, defaults to target_name.
 #
 #     framework_version:
 #         (optional) string, version of the framework. Typically this is a
 #         single letter, like "A". If omitted, the Versions/ subdirectory
 #         structure will not be created, and build output will go directly
 #         into the framework subdirectory.
 #
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("framework_bundle") {
   _target_name = target_name
   _output_name = target_name
   if (defined(invoker.output_name)) {
     _output_name = invoker.output_name
   }
 
-  # If the framework is unversionned, the final _target_name will be the
+  # If the framework is unversioned, the final _target_name will be the
   # create_bundle(_framework_target), otherwise an action with the name
   # _target_name will depends on the the create_bundle() in order to prepare
   # the versioned directory structure.
   _framework_target = _target_name
   _framework_name = _output_name + ".framework"
   _framework_root_dir = "$root_out_dir/$_framework_name"
   if (defined(invoker.framework_version) && invoker.framework_version != "") {
     _framework_version = invoker.framework_version
     _framework_root_dir += "/Versions/$_framework_version"
     _framework_target = _target_name + "_create_bundle"
@@ skipping 204 matching lines @@
 # See "gn help shared_library" for more information on arguments supported
 # by shared library target.
 template("mac_framework_bundle") {
   assert(defined(invoker.deps),
          "Dependencies must be specified for $target_name")
   assert(defined(invoker.info_plist),
          "The Info.plist file must be specified for $target_name")
 
   _info_plist_target = target_name + "_info_plist"
 
-  # TODO(rsesek): Process Info.plist variables.
+  mac_info_plist(_info_plist_target) {
+    executable_name = target_name
+    if (defined(invoker.output_name)) {
+      executable_name = invoker.output_name
+    }
+    forward_variables_from(invoker, [ "info_plist" ])
+  }
 
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
-    sources = [
-      invoker.info_plist,
-    ]
+    sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
+    public_deps = [
+      ":$_info_plist_target",
+    ]
   }
 
   framework_bundle(target_name) {
     forward_variables_from(invoker, "*", [ "info_plist" ])
 
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_info_plist_bundle_data" ]
   }
@@ skipping 46 matching lines @@
     outputs = [
       "{{bundle_executable_dir}}/$_output_name",
     ]
     public_deps = [
       ":$_executable_target",
     ]
   }
 
   _info_plist_target = target_name + "_info_plist"
 
-  # TODO(rsesek): Process Info.plist variables.
+  mac_info_plist(_info_plist_target) {
+    executable_name = _output_name
+    forward_variables_from(invoker, [ "info_plist" ])
+  }
 
   _info_plist_bundle_data = _info_plist_target + "_bundle_data"
 
   bundle_data(_info_plist_bundle_data) {
     forward_variables_from(invoker, [ "testonly" ])
     visibility = [ ":$_target_name" ]
-    sources = [
-      invoker.info_plist,
-    ]
+    sources = get_target_outputs(":$_info_plist_target")
     outputs = [
       "{{bundle_root_dir}}/Info.plist",
     ]
+    public_deps = [
+      ":$_info_plist_target",
+    ]
   }
 
   create_bundle(_target_name) {
     forward_variables_from(invoker,
                            [
                              "data_deps",
                              "deps",
                              "public_deps",
                              "testonly",
                            ])
@@ skipping 66 matching lines @@
                            ])
     if (!defined(deps)) {
       deps = []
     }
     deps += [ ":$_loadable_module_bundle_data" ]
 
     bundle_root_dir = "$root_out_dir/$_output_name.plugin/Contents"
     bundle_executable_dir = "$bundle_root_dir/MacOS"
   }
 }