Cronet for iOS with C API for GRPC support.

components/cronet/ios/Cronet.mm

+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "components/cronet/ios/Cronet.h"

[xunjieli, 2016/04/08 17:46:15]

newbie question: Why is this file is named as Cronet with a capitalized C?

[mef, 2016/04/08 20:40:43]

In my integration prototype I've noticed that all objC modules use CamelCase
instead of lower_case naming.

+
+#include <vector>

[xunjieli, 2016/04/08 17:46:15]

not needed?

[mef, 2016/04/08 20:40:43]

Done.

+
+#include "base/logging.h"
+#include "base/memory/scoped_vector.h"
+#include "base/strings/sys_string_conversions.h"
+#include "components/cronet/ios/cronet_environment.h"
+#include "components/cronet/url_request_context_config.h"
+
+static cronet::CronetEnvironment* gChromeNet = NULL;

[xunjieli, 2016/04/08 17:46:15]

Can we add a comment here to say why we have a global CronetEnvironment and
whether we plan to support multiple CronetEnvironment in the future?

Can we use base::LazyInstance<cronet::CronetEnvironment>::Leaky ?

[mef, 2016/04/08 20:40:43]

Added comment.
Maybe, what would be the advantage?

[xunjieli, 2016/04/11 13:42:05]

See:
http://dev.chromium.org/developers/coding-style/important-abstractions-and-da...

The advantage of using LazyInstance::Leaky is that it is completely thread-safe,
so we will have exactly one gChromeNet even if initialize is called by two
different threads). There are other benefits like not slowing startup and
cleaning up during shutdown.

[mef, 2016/04/13 11:24:49]

Done.

+
+static BOOL gHttp2Enabled = YES;
+static BOOL gQuicEnabled = NO;
+static ScopedVector<cronet::URLRequestContextConfig::QuicHint> gQuicHints;
+static NSString* gUserAgent = nil;
+static NSString* gSslKeyLogFileName = nil;
+
+namespace {
+void CheckNotStarted() {
+  CHECK(gChromeNet == NULL) << "Cronet is already started.";
+}
+
+}  // namespace
+
+@implementation Cronet
+
++ (void)setHttp2Enabled:(BOOL)http2Enabled {
+  CheckNotStarted();
+  gHttp2Enabled = http2Enabled;
+}
+
++ (void)setQuicEnabled:(BOOL)quicEnabled {
+  CheckNotStarted();
+  gQuicEnabled = quicEnabled;
+}
+
++ (void)addQuicHint:(NSString*)host port:(int)port altPort:(int)altPort {
+  CheckNotStarted();
+  gQuicHints.push_back(new cronet::URLRequestContextConfig::QuicHint(
+      base::SysNSStringToUTF8(host), port, altPort));
+}
+
++ (void)setPartialUserAgent:(NSString*)userAgent {
+  CheckNotStarted();
+  gUserAgent = userAgent;
+}
+
++ (void)setSslKeyLogFileName:(NSString*)sslKeyLogFileName {
+  CheckNotStarted();
+  gSslKeyLogFileName = sslKeyLogFileName;
+}
+
++ (void)installInternal {
+  cronet::CronetEnvironment::Initialize();
+  std::string partial_user_agent = base::SysNSStringToUTF8(gUserAgent);
+  gChromeNet = new cronet::CronetEnvironment(partial_user_agent);
+
+  gChromeNet->set_http2_enabled(gHttp2Enabled);
+  gChromeNet->set_quic_enabled(gQuicEnabled);
+  gChromeNet->set_ssl_key_log_file_name(
+      base::SysNSStringToUTF8(gSslKeyLogFileName));
+  for (auto quicHint : gQuicHints) {
+    gChromeNet->AddQuicHint(quicHint->host, quicHint->port,
+                            quicHint->alternate_port);
+  }
+  gChromeNet->Install();
+}
+
++ (void)start {
+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    [self installInternal];
+  });
+}
+
++ (void)startNetLogToFile:(NSString*)fileName logBytes:(BOOL)logBytes {
+  if (gChromeNet && [fileName length]) {
+    gChromeNet->StartNetLog([fileName UTF8String], logBytes);
+  }
+}
+
++ (void)stopNetLog {
+  if (gChromeNet) {
+    gChromeNet->StopNetLog();
+  }
+}
+
++ (NSString*)getUserAgent {
+  if (!gChromeNet) {
+    return nil;
+  }
+
+  std::string user_agent = gChromeNet->user_agent();
+  return [NSString stringWithCString:user_agent.c_str()
+                            encoding:[NSString defaultCStringEncoding]];
+}
+
++ (cronet_engine*)getGlobalEngine {
+  DCHECK(gChromeNet);
+  if (gChromeNet) {
+    static cronet_engine engine;
+    engine.obj = gChromeNet;
+    return &engine;
+  }
+  return nil;
+}
+
+@end