[iOS/OS X] Allow base::scoped_nsobject<> to be used when ARC is enabled.

base/mac/scoped_nsobject_unittest_arc.mm

+// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include <vector>
+
+#import <CoreFoundation/CoreFoundation.h>
+
+#include "base/mac/scoped_nsobject.h"
+#include "testing/gtest/include/gtest/gtest.h"
+
+namespace {
+
+// #if 0
+template <typename NST>
+CFIndex GetRetainCount(const base::scoped_nsobject<NST>& nst) {
+  @autoreleasepool {
+    return CFGetRetainCount((__bridge CFTypeRef)nst.get()) - 1;
+  }
+}
+
+TEST(ScopedNSObjectTestARC, ScopedNSObject) {
+  base::scoped_nsobject<NSObject> p1([[NSObject alloc] init],
+                                     base::scoped_policy::RETAIN);
+  @autoreleasepool {
+    EXPECT_TRUE(p1.get());
+    EXPECT_TRUE(p1.get());
+  }
+  EXPECT_EQ(1u, GetRetainCount(p1));
+  base::scoped_nsobject<NSObject> p2(p1);
+  @autoreleasepool {
+    EXPECT_EQ(p1.get(), p2.get());
+  }
+  EXPECT_EQ(2u, GetRetainCount(p1));
+  p2.reset();
+  EXPECT_EQ(nil, p2.get());
+  EXPECT_EQ(1u, GetRetainCount(p1));
+  {
+    base::scoped_nsobject<NSObject> p3 = p1;
+    @autoreleasepool {
+      EXPECT_EQ(p1.get(), p3.get());
+    }
+    EXPECT_EQ(2u, GetRetainCount(p1));
+    p3 = p1;
+    @autoreleasepool {
+      EXPECT_EQ(p1.get(), p3.get());
+    }
+    EXPECT_EQ(2u, GetRetainCount(p1));
+  }
+  EXPECT_EQ(1u, GetRetainCount(p1));
+  base::scoped_nsobject<NSObject> p4;
+  @autoreleasepool {
+    p4 = base::scoped_nsobject<NSObject>(p1.get(), base::scoped_policy::RETAIN);
+  }
+  EXPECT_EQ(2u, GetRetainCount(p1));
+  @autoreleasepool {
+    EXPECT_TRUE(p1 == p1.get());
+    EXPECT_TRUE(p1 == p1);
+    EXPECT_FALSE(p1 != p1);
+    EXPECT_FALSE(p1 != p1.get());
+  }
+  base::scoped_nsobject<NSObject> p5([[NSObject alloc] init],
+                                     base::scoped_policy::RETAIN);
+  @autoreleasepool {
+    EXPECT_TRUE(p1 != p5);
+    EXPECT_TRUE(p1 != p5.get());
+    EXPECT_FALSE(p1 == p5);
+    EXPECT_FALSE(p1 == p5.get());
+  }
+
+  base::scoped_nsobject<NSObject> p6 = p1;
+  EXPECT_EQ(3u, GetRetainCount(p6));
+  @autoreleasepool {
+    p6.autorelease();
+    EXPECT_EQ(nil, p6.get());
+    EXPECT_EQ(4u, GetRetainCount(p1));
+  }
+  EXPECT_EQ(2u, GetRetainCount(p1));
+}
+
+TEST(ScopedNSObjectTestARC, ScopedNSObjectInContainer) {
+  base::scoped_nsobject<id> p([[NSObject alloc] init],
+                              base::scoped_policy::RETAIN);
+  @autoreleasepool {
+    EXPECT_TRUE(p.get());
+  }
+  EXPECT_EQ(1u, GetRetainCount(p));
+  @autoreleasepool {
+    std::vector<base::scoped_nsobject<id>> objects;
+    objects.push_back(p);
+    EXPECT_EQ(2u, GetRetainCount(p));
+    @autoreleasepool {
+      EXPECT_EQ(p.get(), objects[0].get());
+    }
+    objects.push_back(base::scoped_nsobject<id>([[NSObject alloc] init],
+                                                base::scoped_policy::RETAIN));
+    @autoreleasepool {
+      EXPECT_TRUE(objects[1].get());
+    }
+    EXPECT_EQ(1u, GetRetainCount(objects[1]));
+  }
+  EXPECT_EQ(1u, GetRetainCount(p));
+}
+
+TEST(ScopedNSObjectTestARC, ScopedNSObjectFreeFunctions) {
+  base::scoped_nsobject<id> p1([[NSObject alloc] init],
+                               base::scoped_policy::RETAIN);
+  id o1 = p1.get();
+  EXPECT_TRUE(o1 == p1);
+  EXPECT_FALSE(o1 != p1);
+  base::scoped_nsobject<id> p2([[NSObject alloc] init],
+                               base::scoped_policy::RETAIN);
+  EXPECT_TRUE(o1 != p2);
+  EXPECT_FALSE(o1 == p2);
+  id o2 = p2.get();
+  swap(p1, p2);
+  EXPECT_EQ(o2, p1.get());
+  EXPECT_EQ(o1, p2.get());
+}
+
+// #endif
+
+}  // namespace