Mac: Avoid deprecated use of ::Gestalt() in base/sys_info_mac

base/sys_info_mac.mm

-// Copyright (c) 2012 The Chromium Authors. All rights reserved.
+// Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/sys_info.h"
 
 #include <ApplicationServices/ApplicationServices.h>
 #include <CoreServices/CoreServices.h>
+#import <Foundation/Foundation.h>
 #include <mach/mach_host.h>
 #include <mach/mach_init.h>
 #include <stddef.h>
 #include <stdint.h>
 #include <sys/sysctl.h>
 #include <sys/types.h>
 
 #include "base/logging.h"
+#include "base/mac/mac_util.h"
 #include "base/mac/scoped_mach_port.h"
+#import "base/mac/sdk_forward_declarations.h"
 #include "base/macros.h"
 #include "base/strings/stringprintf.h"
 
 namespace base {
 
 // static
 std::string SysInfo::OperatingSystemName() {
   return "Mac OS X";
 }
 
 // static
 std::string SysInfo::OperatingSystemVersion() {
   int32_t major, minor, bugfix;
   OperatingSystemVersionNumbers(&major, &minor, &bugfix);
   return base::StringPrintf("%d.%d.%d", major, minor, bugfix);
 }
 
 // static
 void SysInfo::OperatingSystemVersionNumbers(int32_t* major_version,
                                             int32_t* minor_version,
                                             int32_t* bugfix_version) {
-  Gestalt(gestaltSystemVersionMajor,
-      reinterpret_cast<SInt32*>(major_version));
-  Gestalt(gestaltSystemVersionMinor,
-      reinterpret_cast<SInt32*>(minor_version));
-  Gestalt(gestaltSystemVersionBugFix,
-      reinterpret_cast<SInt32*>(bugfix_version));
+  NSProcessInfo* processInfo = [NSProcessInfo processInfo];
+  if ([processInfo respondsToSelector:@selector(operatingSystemVersion)]) {

[Nico, 2016/03/31 13:59:16]

Didn't someone say yesterday that this silently works on 10.9 too? Is the else
ever executed?

+    NSOperatingSystemVersion version = [processInfo operatingSystemVersion];
+    *major_version = version.majorVersion;
+    *minor_version = version.minorVersion;
+    *bugfix_version = version.patchVersion;
+  } else {
+    DCHECK(base::mac::IsOSMavericks());
+#pragma clang diagnostic push

[Nico, 2016/03/31 14:07:41]

Cool, can you add a comment here explaining why it's ok to call the old thing
here, that this will only run on 10.9 prior to 10.9.2, can be removed when we
stop supporting that, etc? I want every -Wdeprecated-declarations suppression to
have a very good reason for why it's there as a comment. (This here has a good
reason, it just needs a comment explaining it :-) )

[tapted, 2016/03/31 18:07:40]

Done. Added:

    // -[NSProcessInfo operatingSystemVersion] is documented available in 10.10.
    // It's also available via a private API since 10.9.2. For the remaining
    // cases in 10.9, rely on ::Gestalt(..). This can be removed once 10.9 is no
    // longer supported. Gestalt was deprecated in 10.8, so suppress the
    // deprecation warning.

+#pragma clang diagnostic ignored "-Wdeprecated-declarations"
+    Gestalt(gestaltSystemVersionMajor,
+            reinterpret_cast<SInt32*>(major_version));
+    Gestalt(gestaltSystemVersionMinor,
+            reinterpret_cast<SInt32*>(minor_version));
+    Gestalt(gestaltSystemVersionBugFix,
+            reinterpret_cast<SInt32*>(bugfix_version));
+#pragma clang diagnostic pop
+  }
 }
 
 // static
 int64_t SysInfo::AmountOfPhysicalMemory() {
   struct host_basic_info hostinfo;
   mach_msg_type_number_t count = HOST_BASIC_INFO_COUNT;
   base::mac::ScopedMachSendRight host(mach_host_self());
   int result = host_info(host.get(),
                          HOST_BASIC_INFO,
                          reinterpret_cast<host_info_t>(&hostinfo),
@@ skipping 35 matching lines @@
 
 std::string SysInfo::HardwareModelName() {
   char model[256];
   size_t len = sizeof(model);
   if (sysctlbyname("hw.model", model, &len, NULL, 0) == 0)
     return std::string(model, 0, len);
   return std::string();
 }
 
 }  // namespace base