Remove net & url small, iOS ICU alternatives, unit tests.

net/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/buildflag_header.gni")
 import("//build/config/chromecast_build.gni")
 import("//build/config/compiler/compiler.gni")
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build_overrides/v8.gni")
 import("//testing/libfuzzer/fuzzer_test.gni")
 import("//testing/test.gni")
 import("//third_party/icu/config.gni")
 import("//third_party/protobuf/proto_library.gni")
 import("//tools/grit/grit_rule.gni")
+import("//url/features.gni")
 
 if (is_android) {
   import("//build/config/android/config.gni")
   import("//build/config/android/rules.gni")
 } else if (is_mac) {
   import("//build/config/mac/mac_sdk.gni")
 }
 
 # The list of net files is kept in net.gypi. Read it.
 gypi_values = exec_script("//build/gypi_to_gn.py",
@@ skipping 31 matching lines @@
     defines += [ "POSIX_AVOID_MMAP" ]
   }
   if (disable_file_support) {
     defines += [ "DISABLE_FILE_SUPPORT" ]
   }
   if (disable_ftp_support) {
     defines += [ "DISABLE_FTP_SUPPORT=1" ]
   }
 }
 
-# net_internal_config is shared with net and net_small.
 config("net_internal_config") {
   defines = [
     # TODO(GYP) Note that the GYP file supports linux_link_kerberos (defaults to
     # 0) which implies that we run pkg_config on kerberos and link to that
     # rather than setting this define which will dynamically open it. That
     # doesn't seem to be set in the regular builds, so we're skipping this
     # capability here.
     "DLOPEN_KERBEROS",
     "NET_IMPLEMENTATION",
   ]
 
   if (use_kerberos) {
     defines += [ "USE_KERBEROS" ]
     if (is_android) {
       include_dirs = [ "/usr/include/kerberosV" ]
     }
   }
 
   if (enable_built_in_dns) {
     defines += [ "ENABLE_BUILT_IN_DNS" ]
   }
 }
 
-# net_shared_* are settings shared between net and net_small
-net_shared_sources = gypi_values.net_nacl_common_sources
+net_sources = gypi_values.net_nacl_common_sources
 
-net_shared_unfiltered_sources = []
+net_unfiltered_sources = []
 
-net_shared_configs = [
+net_configs = [
   ":net_internal_config",
   "//build/config:precompiled_headers",
 
   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
   "//build/config/compiler:no_size_t_to_int_warning",
 ]
 
-net_shared_public_deps = [
+net_public_deps = [
   ":net_quic_proto",
   "//crypto",
   "//crypto:platform",
 ]
 
-net_shared_deps = [
+net_deps = [
   ":net_resources",
   "//base",
   "//net/base/registry_controlled_domains",
   "//third_party/protobuf:protobuf_lite",
 ]
 
 if (!is_nacl) {
-  net_shared_sources += gypi_values.net_non_nacl_sources
+  net_sources += gypi_values.net_non_nacl_sources
 
-  net_shared_deps += [
+  net_deps += [
     "//base/third_party/dynamic_annotations",
     "//components/prefs",
     "//sdch",
     "//third_party/zlib",
   ]
 
   if (!use_kerberos) {
-    net_shared_sources -= [
+    net_sources -= [
       "http/http_auth_handler_negotiate.cc",
       "http/http_auth_handler_negotiate.h",
     ]
   }
 
   if (is_posix) {
     if (posix_avoid_mmap) {
-      net_shared_sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
+      net_sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
     } else {
-      net_shared_sources -=
-          [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
+      net_sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
     }
   }
 
   if (!enable_built_in_dns) {
-    net_shared_sources -= [
+    net_sources -= [
       "dns/address_sorter_posix.cc",
       "dns/address_sorter_posix.h",
       "dns/dns_client.cc",
     ]
   }
 
   if (use_openssl) {
-    net_shared_sources -= [
+    net_sources -= [
       "base/nss_memio.c",
       "base/nss_memio.h",
       "cert/ct_log_verifier_nss.cc",
       "cert/ct_objects_extractor_nss.cc",
       "cert/jwk_serializer_nss.cc",
       "cert/scoped_nss_types.h",
       "cert/x509_util_nss.cc",
       "quic/crypto/aead_base_decrypter_nss.cc",
       "quic/crypto/aead_base_encrypter_nss.cc",
       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
       "quic/crypto/chacha20_poly1305_rfc7539_decrypter_nss.cc",
       "quic/crypto/chacha20_poly1305_rfc7539_encrypter_nss.cc",
       "quic/crypto/channel_id_nss.cc",
       "quic/crypto/p256_key_exchange_nss.cc",
       "quic/crypto/proof_source_chromium_nss.cc",
       "socket/nss_ssl_util.cc",
       "socket/nss_ssl_util.h",
       "socket/ssl_client_socket_nss.cc",
       "socket/ssl_client_socket_nss.h",
       "socket/ssl_server_socket_nss.cc",
       "socket/ssl_server_socket_nss.h",
       "ssl/token_binding_nss.cc",
     ]
     if (is_ios) {
-      net_shared_sources -= [
+      net_sources -= [
         "cert/x509_util_ios.cc",
         "cert/x509_util_ios.h",
       ]
     }
   } else {
-    net_shared_sources -= [
+    net_sources -= [
       "cert/ct_log_verifier_openssl.cc",
       "cert/ct_objects_extractor_openssl.cc",
       "cert/jwk_serializer_openssl.cc",
       "cert/x509_util_openssl.cc",
       "cert/x509_util_openssl.h",
       "quic/crypto/aead_base_decrypter_openssl.cc",
       "quic/crypto/aead_base_encrypter_openssl.cc",
       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
@@ skipping 20 matching lines @@
       "ssl/ssl_platform_key_task_runner.h",
       "ssl/test_ssl_private_key.cc",
       "ssl/test_ssl_private_key.h",
       "ssl/threaded_ssl_private_key.cc",
       "ssl/threaded_ssl_private_key.h",
       "ssl/token_binding_openssl.cc",
     ]
   }
 
   if (!use_openssl_certs) {
-    net_shared_sources -= [
+    net_sources -= [
       "base/crypto_module_openssl.cc",
       "base/keygen_handler_openssl.cc",
       "base/openssl_private_key_store.h",
       "base/openssl_private_key_store_memory.cc",
       "cert/cert_database_openssl.cc",
       "cert/cert_verify_proc_openssl.cc",
       "cert/cert_verify_proc_openssl.h",
       "cert/test_root_certs_openssl.cc",
       "cert/x509_certificate_openssl.cc",
       "ssl/openssl_client_key_store.cc",
       "ssl/openssl_client_key_store.h",
     ]
     if (is_android) {
-      net_shared_sources -= [ "base/openssl_private_key_store_android.cc" ]
+      net_sources -= [ "base/openssl_private_key_store_android.cc" ]
     }
   } else {
     if (is_android) {
       # Android doesn't use these even when using OpenSSL.
-      net_shared_sources -= [
+      net_sources -= [
         "base/openssl_private_key_store_memory.cc",
         "cert/cert_database_openssl.cc",
         "cert/cert_verify_proc_openssl.cc",
         "cert/test_root_certs_openssl.cc",
       ]
     }
   }
 
   if (!use_kerberos || is_android) {
-    net_shared_sources -= [
+    net_sources -= [
       "http/http_auth_gssapi_posix.cc",
       "http/http_auth_gssapi_posix.h",
     ]
   }
 
   if (use_glib && use_gconf && !is_chromeos) {
-    net_shared_configs += [ "//build/config/linux:gconf" ]
-    net_shared_deps += [ "//build/linux:gio" ]
+    net_configs += [ "//build/config/linux:gconf" ]
+    net_deps += [ "//build/linux:gio" ]
   }
 
   if (is_linux) {
-    net_shared_configs += [ "//build/config/linux:libresolv" ]
+    net_configs += [ "//build/config/linux:libresolv" ]
   }
 
   if (!use_nss_certs) {
-    net_shared_sources -= [
+    net_sources -= [
       "base/crypto_module_nss.cc",
       "base/keygen_handler_nss.cc",
       "cert/cert_database_nss.cc",
       "cert/nss_cert_database.cc",
       "cert/nss_cert_database.h",
       "cert/x509_certificate_nss.cc",
       "ssl/client_cert_store_nss.cc",
       "ssl/client_cert_store_nss.h",
       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
       "third_party/mozilla_security_manager/nsKeygenHandler.h",
       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
     ]
     if (is_chromeos) {
       # These were already removed on non-ChromeOS.
-      net_shared_sources -= [
+      net_sources -= [
         "cert/nss_cert_database_chromeos.cc",
         "cert/nss_cert_database_chromeos.h",
         "cert/nss_profile_filter_chromeos.cc",
         "cert/nss_profile_filter_chromeos.h",
       ]
     }
-    net_shared_sources -= [
+    net_sources -= [
       "ssl/client_key_store.cc",
       "ssl/client_key_store.h",
       "ssl/ssl_platform_key_nss.cc",
     ]
   } else if (use_openssl) {
     # client_cert_store_nss.c requires NSS_CmpCertChainWCANames from NSS's
     # libssl, but our bundled copy is not built in OpenSSL ports. Pull that file
     # in directly.
-    net_shared_sources += [ "third_party/nss/ssl/cmpcert.c" ]
+    net_sources += [ "third_party/nss/ssl/cmpcert.c" ]
   }
 
   if (!use_nss_verifier) {
     # These files are part of the partial implementation of NSS for
     # cert verification, so keep them in that case.
-    net_shared_sources -= [
+    net_sources -= [
       "cert/cert_verify_proc_nss.cc",
       "cert/cert_verify_proc_nss.h",
       "cert/test_root_certs_nss.cc",
       "cert/x509_util_nss_certs.cc",
       "cert_net/nss_ocsp.cc",
       "cert_net/nss_ocsp.h",
     ]
   }
 
   if (is_ios && use_nss_verifier) {
-    net_shared_sources -= [
+    net_sources -= [
       "cert/cert_verify_proc_ios.cc",
       "cert/cert_verify_proc_ios.h",
       "cert/x509_certificate_openssl_ios.cc",
     ]
   }
 
   if (is_chromecast && use_nss_certs) {
-    net_shared_sources += [ "ssl/ssl_platform_key_chromecast.cc" ]
-    net_shared_sources -= [ "ssl/ssl_platform_key_nss.cc" ]
+    net_sources += [ "ssl/ssl_platform_key_chromecast.cc" ]
+    net_sources -= [ "ssl/ssl_platform_key_nss.cc" ]
   }
 
   if (!enable_mdns) {
-    net_shared_sources -= [
+    net_sources -= [
       "dns/mdns_cache.cc",
       "dns/mdns_cache.h",
       "dns/mdns_client.cc",
       "dns/mdns_client.h",
       "dns/mdns_client_impl.cc",
       "dns/mdns_client_impl.h",
       "dns/record_parsed.cc",
       "dns/record_parsed.h",
       "dns/record_rdata.cc",
       "dns/record_rdata.h",
     ]
   }
 
   if (is_win) {
-    net_shared_sources -= [ "http/http_auth_handler_ntlm_portable.cc" ]
+    net_sources -= [ "http/http_auth_handler_ntlm_portable.cc" ]
   } else {  # !is_win
-    net_shared_sources -= [
+    net_sources -= [
       "base/winsock_init.cc",
       "base/winsock_init.h",
       "base/winsock_util.cc",
       "base/winsock_util.h",
       "proxy/proxy_resolver_winhttp.cc",
       "proxy/proxy_resolver_winhttp.h",
     ]
   }
 
   if (is_ios) {
     # Add back some sources that were otherwise filtered out. iOS needs some Mac
     # files.
-    net_shared_unfiltered_sources += [
+    net_unfiltered_sources += [
       "base/mac/url_conversions.h",
       "base/mac/url_conversions.mm",
       "base/network_change_notifier_mac.cc",
       "base/network_config_watcher_mac.cc",
       "base/network_interfaces_mac.cc",
       "base/network_interfaces_mac.h",
       "base/platform_mime_util_mac.mm",
       "proxy/proxy_resolver_mac.cc",
       "proxy/proxy_server_mac.cc",
     ]
 
-    net_shared_sources -= [ "disk_cache/blockfile/file_posix.cc" ]
-    net_shared_deps += [
+    net_sources -= [ "disk_cache/blockfile/file_posix.cc" ]
+    net_deps += [
       "//third_party/nss:nspr",
       "//third_party/nss",
       "//net/third_party/nss/ssl:libssl",
     ]
   }
 
   if (is_ios && !use_nss_verifier) {
-    net_shared_sources += [ "cert/test_root_certs_mac.cc" ]
+    net_sources += [ "cert/test_root_certs_mac.cc" ]
   }
 
   if (is_ios || is_mac) {
-    net_shared_sources += gypi_values.net_base_mac_ios_sources
+    net_sources += gypi_values.net_base_mac_ios_sources
   }
 
   if (is_android) {
-    net_shared_deps += [ ":net_jni_headers" ]
+    net_deps += [ ":net_jni_headers" ]
 
     # Add some Linux sources that were excluded by the filter, but which
     # are needed.
-    net_shared_unfiltered_sources += [
+    net_unfiltered_sources += [
       "base/address_tracker_linux.cc",
       "base/address_tracker_linux.h",
       "base/network_interfaces_linux.cc",
       "base/network_interfaces_linux.h",
       "base/platform_mime_util_linux.cc",
     ]
   }
 } else {
-  net_shared_public_deps += [ "//native_client_sdk/src/libraries/nacl_io" ]
+  net_public_deps += [ "//native_client_sdk/src/libraries/nacl_io" ]
 }
 
 component("net") {
-  sources = net_shared_sources
+  sources = net_sources
 
   # Add back some sources that were otherwise filtered out.
   set_sources_assignment_filter([])
-  sources += net_shared_unfiltered_sources
+  sources += net_unfiltered_sources
   set_sources_assignment_filter(sources_assignment_filter)
 
   cflags = []
-  configs += net_shared_configs
+  configs += net_configs
   public_configs = [ ":net_config" ]
 
-  public_deps = net_shared_public_deps + [ "//url" ]
-  deps = net_shared_deps
+  public_deps = net_public_deps + [ "//url" ]
+  deps = net_deps
 
   if (is_mac) {
     libs = [
       "Foundation.framework",
       "Security.framework",
       "SystemConfiguration.framework",
       "resolv",
     ]
   }
 
@@ skipping 13 matching lines @@
     }
 
     if (!disable_ftp_support) {
       sources += gypi_values.net_ftp_support_sources
     }
 
     if (enable_websockets) {
       sources += gypi_values.net_websockets_sources
     }
 
-    # ICU support.
-    deps += [
-      "//base:i18n",
-      "//third_party/icu",
-    ]
-    sources += [
-      "base/filename_util_icu.cc",
-      "base/net_string_util_icu.cc",
-    ]
-
-    # Brotli support.
-    deps += [ "//third_party/brotli" ]
-    sources += [ "filter/brotli_filter.cc" ]
+    # ICU & Brotli support.
+    if (is_android && use_platform_icu_alternatives) {
+      # Use ICU alternative on Android & Disable Brotli support.
+      sources += [
+        "base/net_string_util_icu_alternatives_android.cc",
+        "base/net_string_util_icu_alternatives_android.h",
+        "filter/brotli_filter_disabled.cc",
+      ]
+      defines = [
+        "DISABLE_FILE_SUPPORT",
+        "DISABLE_FTP_SUPPORT",

[xunjieli, 2016/04/01 14:16:43]

These two defines should not be here?

[kapishnikov, 2016/04/01 18:55:01]

Nice catch. These two defines come from "net_config":
  public_configs = [ ":net_config" ]

Fixed.

+        "USE_PLATFORM_ICU_ALTERNATIVES=1",
+      ]
+      deps += [ ":net_jni_headers" ]
+    } else if (is_ios && use_platform_icu_alternatives) {
+      # Use ICU alternative on Android & Disable Brotli support.
+      sources += [
+        "base/net_string_util_icu_alternatives_ios.mm",
+        "filter/brotli_filter_disabled.cc",
+      ]
+      defines = [
+        "DISABLE_FILE_SUPPORT",
+        "DISABLE_FTP_SUPPORT",

[xunjieli, 2016/04/01 14:16:43]

These two defines should not be here?

[kapishnikov, 2016/04/01 18:55:01]

Removed.

+        "USE_PLATFORM_ICU_ALTERNATIVES=1",
+      ]
+    } else {  # use third-party ICU implementation by default.
+      deps += [
+        "//base:i18n",
+        "//third_party/brotli",
+        "//third_party/icu",
+      ]
+      sources += [
+        "base/filename_util_icu.cc",
+        "base/net_string_util_icu.cc",
+        "filter/brotli_filter.cc",
+      ]
+    }
   }
 }
 
-if (is_android) {
-  # Same as net, but with brotli encoding, ICU, file, ftp, and websocket
-  # support stripped.
-  component("net_small") {
-    sources = net_shared_sources
-
-    # Add back some sources that were otherwise filtered out.
-    set_sources_assignment_filter([])
-    sources += net_shared_unfiltered_sources
-    set_sources_assignment_filter(sources_assignment_filter)
-
-    cflags = []
-    defines = []
-    configs += net_shared_configs
-    public_configs = [ ":net_config" ]
-
-    public_deps = net_shared_public_deps +
-                  [ "//url:url_lib_use_icu_alternatives_on_android" ]
-    deps = net_shared_deps + [ ":net_jni_headers" ]
-
-    defines += [
-      "DISABLE_FILE_SUPPORT",
-      "DISABLE_FTP_SUPPORT",
-      "USE_ICU_ALTERNATIVES_ON_ANDROID=1",
-    ]
-
-    # Use ICU alternative on Android.
-    sources += [
-      "base/net_string_util_icu_alternatives_android.cc",
-      "base/net_string_util_icu_alternatives_android.h",
-    ]
-
-    # Disable Brotli support.
-    sources += [ "filter/brotli_filter_disabled.cc" ]
-  }
-}
-
 grit("net_resources") {
   source = "base/net_resources.grd"
   use_qualified_include = true
   outputs = [
     "grit/net_resources.h",
     "net_resources.pak",
   ]
 }
 
 proto_library("net_quic_proto") {
-  visibility = [
-    ":net",
-    ":net_small",
-  ]
+  visibility = [ ":net" ]
 
   sources = [
     "quic/proto/cached_network_parameters.proto",
     "quic/proto/source_address_token.proto",
   ]
   cc_generator_options = "dllexport_decl=NET_EXPORT_PRIVATE:"
   cc_include = "net/base/net_export.h"
 
   defines = [ "NET_IMPLEMENTATION" ]
 
@@ skipping 837 matching lines @@
 source_set("stale_while_revalidate_experiment_domains") {
   sources = [
     "base/stale_while_revalidate_experiment_domains.cc",
     "base/stale_while_revalidate_experiment_domains.h",
   ]
   deps = [
     ":net",
     ":stale_while_revalidate_experiment_domains_dafsa",
     "//base",
   ]
-  configs += net_shared_configs
+  configs += net_configs
 }
 
 if (!is_ios) {
   executable("quic_client") {
     sources = [
       "tools/quic/quic_simple_client_bin.cc",
     ]
     deps = [
       ":net",
       ":simple_quic_tools",
@@ skipping 30 matching lines @@
   ]
   outputs = [
     "{{bundle_resources_dir}}/" +
         "{{source_root_relative_dir}}/{{source_file_part}}",
   ]
 }
 
 test("net_unittests") {
   sources = gypi_values.net_test_sources
 
-  if (is_ios) {
+  if (is_ios && enable_websockets) {
     sources -= [
       "websockets/websocket_stream_cookie_test.cc",
       "websockets/websocket_stream_create_test_base.cc",
       "websockets/websocket_stream_create_test_base.h",
     ]
   }
 
   configs += [
     "//build/config:precompiled_headers",
 
@@ skipping 140 matching lines @@
       "websockets/websocket_deflater_test.cc",
       "websockets/websocket_end_to_end_test.cc",
       "websockets/websocket_errors_test.cc",
       "websockets/websocket_extension_parser_test.cc",
       "websockets/websocket_extension_test.cc",
       "websockets/websocket_frame_parser_test.cc",
       "websockets/websocket_frame_test.cc",
       "websockets/websocket_handshake_challenge_test.cc",
       "websockets/websocket_handshake_stream_create_helper_test.cc",
       "websockets/websocket_inflater_test.cc",
+      "websockets/websocket_stream_cookie_test.cc",
+      "websockets/websocket_stream_create_test_base.cc",
       "websockets/websocket_stream_test.cc",
       "websockets/websocket_test_util.cc",
       "websockets/websocket_test_util.h",
     ]
     deps -= [ ":http_server" ]
   }
 
   if (disable_file_support) {
     sources -= [
       "base/directory_lister_unittest.cc",
@@ skipping 91 matching lines @@
       # iOS.
       # OS is not "linux" or "freebsd" or "openbsd".
       "socket/unix_domain_client_socket_posix_unittest.cc",
       "socket/unix_domain_server_socket_posix_unittest.cc",
 
       # See bug http://crbug.com/344533.
       "disk_cache/blockfile/index_table_v3_unittest.cc",
     ]
   }
 
+  # Unit tests that are not supported by the current ICU alternatives on Android.
+  if (is_android && use_platform_icu_alternatives) {
+    sources -= [
+      "base/filename_util_unittest.cc",
+      "base/url_util_unittest.cc",
+      "cert/x509_certificate_unittest.cc",
+      "filter/brotli_filter_unittest.cc",
+      "proxy/proxy_resolver_v8_unittest.cc",
+      "url_request/url_request_job_unittest.cc",
+    ]
+  }
+
+  # Unit tests that are not supported by the current ICU alternatives on iOS.
+  if (is_ios && use_platform_icu_alternatives) {
+    sources -= [
+      "base/filename_util_unittest.cc",
+      "base/url_util_unittest.cc",
+      "cert/x509_certificate_unittest.cc",
+      "http/http_auth_handler_basic_unittest.cc",
+      "http/http_auth_handler_digest_unittest.cc",
+      "http/http_auth_handler_factory_unittest.cc",
+      "http/http_auth_unittest.cc",
+      "http/http_content_disposition_unittest.cc",
+      "http/http_network_transaction_unittest.cc",
+      "http/http_proxy_client_socket_pool_unittest.cc",
+      "socket/ssl_client_socket_pool_unittest.cc",
+      "spdy/spdy_network_transaction_unittest.cc",
+      "spdy/spdy_proxy_client_socket_unittest.cc",
+      "url_request/url_request_job_unittest.cc",
+      "url_request/url_request_unittest.cc",
+    ]
+  }
+
   if (is_android) {
     deps += [
       ":net_test_jni_headers",
       "//base:base_java_unittest_support",
       "//net/android:net_java",
       "//net/android:net_java_test_support",
       "//net/android:net_javatests",
       "//net/android:net_unittests_apk_resources",
 
       # TODO(mmenke):  This depends on test_support_base, which depends on
@@ skipping 252 matching lines @@
 fuzzer_test("net_quic_crypto_framer_parse_message_fuzzer") {
   sources = [
     "quic/quic_crypto_framer_parse_message_fuzzer.cc",
   ]
   deps = [
     ":net_fuzzer_test_support",
     "//base",
     "//net",
   ]
 }