Fix for an issue with the Fullscreen Menu Bar on OSX

chrome/browser/ui/cocoa/presentation_mode_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/presentation_mode_controller.h"
 
 #include <algorithm>
 
 #include "base/command_line.h"
 #import "base/mac/mac_util.h"
@@ skipping 13 matching lines @@
 
 // The activation zone for the main menu is 4 pixels high; if we make it any
 // smaller, then the menu can be made to appear without the bar sliding down.
 const CGFloat kDropdownActivationZoneHeight = 4;
 const NSTimeInterval kDropdownAnimationDuration = 0.12;
 const NSTimeInterval kMouseExitCheckDelay = 0.1;
 // This show delay attempts to match the delay for the main menu.
 const NSTimeInterval kDropdownShowDelay = 0.3;
 const NSTimeInterval kDropdownHideDelay = 0.2;
 
+// The event kind value for a undocumented menubar show/hide Carbon event.
+const CGFloat kMenuBarRevealEventKind = 2004;
+
 // The amount by which the floating bar is offset downwards (to avoid the menu)
 // in presentation mode. (We can't use |-[NSMenu menuBarHeight]| since it
 // returns 0 when the menu bar is hidden.)
 const CGFloat kFloatingBarVerticalOffset = 22;
 
 OSStatus MenuBarRevealHandler(EventHandlerCallRef handler,
                               EventRef event,
                               void* context) {
   PresentationModeController* self =
       static_cast<PresentationModeController*>(context);
-  CGFloat revealFraction = 0;
-  GetEventParameter(event,
-                    FOUR_CHAR_CODE('rvlf'),
-                    typeCGFloat,
-                    NULL,
-                    sizeof(CGFloat),
-                    NULL,
-                    &revealFraction);
-  [self setMenuBarRevealProgress:revealFraction];
+
+  // If Chrome has multiple fullscreen windows in their own space, the Handler
+  // becomes flaky and might start receiving kMenuBarRevealEventKind events
+  // from another space. Since the menubar in the another space is in either a
+  // shown or hidden state, it will give us a reveal fraction of 0.0 or 1.0.
+  // As such, we should ignore the kMenuBarRevealEventKind event if it gives
+  // us a fraction of 0.0 or 1.0, and rely on kEventMenuBarShown and
+  // kEventMenuBarHidden to set these values.
+  if ([self isOnActiveSpace]) {
+    if (GetEventKind(event) == kMenuBarRevealEventKind) {
+      CGFloat revealFraction = 0;
+      GetEventParameter(event, FOUR_CHAR_CODE('rvlf'), typeCGFloat, NULL,
+                        sizeof(CGFloat), NULL, &revealFraction);
+      if (revealFraction > 0.0 && revealFraction < 1.0)
+        [self setMenuBarRevealProgress:revealFraction];
+    } else if (GetEventKind(event) == kEventMenuBarShown) {
+      [self setMenuBarRevealProgress:1.0];
+    } else {
+      [self setMenuBarRevealProgress:0.0];
+    }
+  }
+
   return CallNextEventHandler(handler, event);
 }
 
 }  // end namespace
 
 // Helper class to manage animations for the dropdown bar.  Calls
 // [PresentationModeController changeToolbarFraction] once per
 // animation step.
 @interface DropdownAnimation : NSAnimation {
  @private
@@ skipping 116 matching lines @@
 // the window gains or loses main status as well as in |-cleanup|.
 - (void)showActiveWindowUI;
 - (void)hideActiveWindowUI;
 
 // Whether the menu bar should be shown in immersive fullscreen for the screen
 // that contains the window.
 - (BOOL)shouldShowMenubarInImmersiveFullscreen;
 
 @end
 
-
 @implementation PresentationModeController
 
 @synthesize inPresentationMode = inPresentationMode_;
 @synthesize slidingStyle = slidingStyle_;
 @synthesize toolbarFraction = toolbarFraction_;
 
 - (id)initWithBrowserController:(BrowserWindowController*)controller
                           style:(fullscreen_mac::SlidingStyle)style {
   if ((self = [super init])) {
     browserController_ = controller;
     systemFullscreenMode_ = base::mac::kFullScreenModeNormal;
     slidingStyle_ = style;
   }
 
   // Let the world know what we're up to.
   [[NSNotificationCenter defaultCenter]
     postNotificationName:kWillEnterFullscreenNotification
                   object:nil];
 
-  // Install the Carbon event handler for the undocumented menu bar show/hide
-  // event.
-  EventTypeSpec eventSpec = {kEventClassMenu, 2004};
-  InstallApplicationEventHandler(NewEventHandlerUPP(&MenuBarRevealHandler),
-                                 1,
-                                 &eventSpec,
-                                 self,
-                                 &menuBarTrackingHandler_);
+  // Install the Carbon event handler for the menubar show, hide and
+  // undocumented reveal event.
+  EventTypeSpec eventSpecs[3];
+
+  eventSpecs[0].eventClass = kEventClassMenu;
+  eventSpecs[0].eventKind = kMenuBarRevealEventKind;
+
+  eventSpecs[1].eventClass = kEventClassMenu;
+  eventSpecs[1].eventKind = kEventMenuBarShown;
+
+  eventSpecs[2].eventClass = kEventClassMenu;
+  eventSpecs[2].eventKind = kEventMenuBarHidden;
+
+  InstallApplicationEventHandler(NewEventHandlerUPP(&MenuBarRevealHandler), 3,
+                                 eventSpecs, self, &menuBarTrackingHandler_);
+
   return self;
 }
 
 - (void)dealloc {
   RemoveEventHandler(menuBarTrackingHandler_);
   DCHECK(!inPresentationMode_);
   DCHECK(!trackingArea_);
   [super dealloc];
 }
 
@@ skipping 189 matching lines @@
 // the logic is correct and not fragile.
 - (CGFloat)menubarOffset {
   if ([browserController_ isInAppKitFullscreen])
     return -std::floor(menubarFraction_ * [self floatingBarVerticalOffset]);
 
   return [self shouldShowMenubarInImmersiveFullscreen]
              ? -[self floatingBarVerticalOffset]
              : 0;
 }
 
+- (BOOL)isOnActiveSpace {
+  return [browserController_ window].onActiveSpace;
+}
+
 // Used to activate the floating bar in presentation mode.
 - (void)mouseEntered:(NSEvent*)event {
   DCHECK(inPresentationMode_);
 
   // Having gotten a mouse entered, we no longer need to do exit checks.
   [self cancelMouseExitCheck];
 
   NSTrackingArea* trackingArea = [event trackingArea];
   if (trackingArea == trackingArea_) {
     // The tracking area shouldn't be active during animation.
@@ skipping 310 matching lines @@
   [self updateMenuBarAndDockVisibility];
 
   // TODO(rohitrao): Remove the Exit Fullscreen button.  http://crbug.com/35956
 }
 
 - (BOOL)shouldShowMenubarInImmersiveFullscreen {
   return [self doesScreenHaveMenuBar] && toolbarFraction_ > 0.99;
 }
 
 @end