Swap main menu with app-specific menu when app window focused.

chrome/browser/app_controller_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/app_controller_mac.h"
 
+#include "apps/shell_window.h"
 #include "base/auto_reset.h"
 #include "base/bind.h"
 #include "base/command_line.h"
 #include "base/files/file_path.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/mac_util.h"
 #include "base/message_loop.h"
 #include "base/prefs/pref_service.h"
 #include "base/strings/string_number_conversions.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "chrome/app/chrome_command_ids.h"
 #include "chrome/browser/background/background_application_list_model.h"
 #include "chrome/browser/background/background_mode_manager.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/browser_shutdown.h"
 #include "chrome/browser/command_updater.h"
 #include "chrome/browser/download/download_service.h"
 #include "chrome/browser/download/download_service_factory.h"
 #include "chrome/browser/extensions/extension_service.h"
 #include "chrome/browser/extensions/extension_system.h"
+#include "chrome/browser/extensions/shell_window_registry.h"
 #include "chrome/browser/first_run/first_run.h"
 #include "chrome/browser/lifetime/application_lifetime.h"
 #include "chrome/browser/printing/print_dialog_cloud.h"
 #include "chrome/browser/profiles/profile_info_cache_observer.h"
 #include "chrome/browser/profiles/profile_manager.h"
 #include "chrome/browser/service/service_process_control.h"
 #include "chrome/browser/sessions/session_restore.h"
 #include "chrome/browser/sessions/session_service.h"
 #include "chrome/browser/sessions/session_service_factory.h"
 #include "chrome/browser/sessions/tab_restore_service.h"
@@ skipping 23 matching lines @@
 #import "chrome/browser/ui/cocoa/tabs/tab_window_controller.h"
 #include "chrome/browser/ui/cocoa/task_manager_mac.h"
 #include "chrome/browser/ui/extensions/application_launch.h"
 #include "chrome/browser/ui/host_desktop.h"
 #include "chrome/browser/ui/startup/startup_browser_creator.h"
 #include "chrome/browser/ui/startup/startup_browser_creator_impl.h"
 #include "chrome/common/chrome_notification_types.h"
 #include "chrome/common/chrome_paths_internal.h"
 #include "chrome/common/chrome_switches.h"
 #include "chrome/common/cloud_print/cloud_print_class_mac.h"
+#include "chrome/common/extensions/extension.h"
 #include "chrome/common/extensions/extension_constants.h"
 #include "chrome/common/mac/app_mode_common.h"
 #include "chrome/common/pref_names.h"
 #include "chrome/common/service_messages.h"
 #include "chrome/common/url_constants.h"
 #include "content/public/browser/browser_thread.h"
 #include "content/public/browser/download_manager.h"
 #include "content/public/browser/notification_service.h"
 #include "content/public/browser/notification_types.h"
 #include "content/public/browser/plugin_service.h"
@@ skipping 104 matching lines @@
 - (void)getUrl:(NSAppleEventDescriptor*)event
      withReply:(NSAppleEventDescriptor*)reply;
 - (void)submitCloudPrintJob:(NSAppleEventDescriptor*)event;
 - (void)windowLayeringDidChange:(NSNotification*)inNotification;
 - (void)windowChangedToProfile:(Profile*)profile;
 - (void)checkForAnyKeyWindows;
 - (BOOL)userWillWaitForInProgressDownloads:(int)downloadCount;
 - (BOOL)shouldQuitWithInProgressDownloads;
 - (void)executeApplication:(id)sender;
 - (void)profileWasRemoved:(const base::FilePath&)profilePath;
+- (void)updateMenuBar:(NSNotification*)notification;
 @end
 
 class AppControllerProfileObserver : public ProfileInfoCacheObserver {
  public:
   AppControllerProfileObserver(
       ProfileManager* profile_manager, AppController* app_controller)
       : profile_manager_(profile_manager),
         app_controller_(app_controller) {
     DCHECK(profile_manager_);
     DCHECK(app_controller_);
@@ skipping 71 matching lines @@
              name:NSWindowDidBecomeKeyNotification
            object:nil];
   [notificationCenter
       addObserver:self
          selector:@selector(windowLayeringDidChange:)
              name:NSWindowDidResignKeyNotification
            object:nil];
   [notificationCenter
       addObserver:self
          selector:@selector(windowLayeringDidChange:)
              name:NSWindowDidBecomeMainNotification

[tapted, 2013/07/04 02:43:33]

hm... I think this observer might be getting clobbered? We might need a more
generic function, which calls both updateMenuBar and windowLayeringDidChange

[jackhou1, 2013/07/05 03:52:37]

Nup, both get called.

[tapted, 2013/07/05 04:50:54]

Ah, interesting. And from the documentation it does look like
NSNotificaitonCentre supports this reliably, so I'm content.. might be other
opinions though.

            object:nil];
   [notificationCenter
       addObserver:self
          selector:@selector(windowLayeringDidChange:)
              name:NSWindowDidResignMainNotification
            object:nil];
 
   if (base::mac::IsOSLionOrLater()) {
     [notificationCenter
         addObserver:self
@@ skipping 15 matching lines @@
 }
 
 - (void)unregisterEventHandlers {
   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
   [em removeEventHandlerForEventClass:kInternetEventClass
                            andEventID:kAEGetURL];
   [em removeEventHandlerForEventClass:cloud_print::kAECloudPrintClass
                            andEventID:cloud_print::kAECloudPrintClass];
   [em removeEventHandlerForEventClass:'WWW!'
                            andEventID:'OURL'];
   [[NSNotificationCenter defaultCenter] removeObserver:self];

[tapted, 2013/07/04 02:43:33]

(this will probably do the removeObserver bit for us)

 }
 
 // (NSApplicationDelegate protocol) This is the Apple-approved place to override
 // the default handlers.
 - (void)applicationWillFinishLaunching:(NSNotification*)notification {
   // Nothing here right now.
 }
 
 - (BOOL)tryToTerminateApplication:(NSApplication*)app {
   // Check for in-process downloads, and prompt the user if they really want
@@ skipping 778 matching lines @@
   menuState_->UpdateCommandEnabled(IDC_FOCUS_SEARCH, true);
   menuState_->UpdateCommandEnabled(IDC_SHOW_BOOKMARK_MANAGER, true);
   menuState_->UpdateCommandEnabled(IDC_SHOW_HISTORY, true);
   menuState_->UpdateCommandEnabled(IDC_SHOW_DOWNLOADS, true);
   menuState_->UpdateCommandEnabled(IDC_MANAGE_EXTENSIONS, true);
   menuState_->UpdateCommandEnabled(IDC_HELP_PAGE_VIA_MENU, true);
   menuState_->UpdateCommandEnabled(IDC_IMPORT_SETTINGS, true);
   menuState_->UpdateCommandEnabled(IDC_FEEDBACK, true);
   menuState_->UpdateCommandEnabled(IDC_SHOW_SYNC_SETUP, true);
   menuState_->UpdateCommandEnabled(IDC_TASK_MANAGER, true);
+
+  [[NSNotificationCenter defaultCenter]
+      addObserver:self

[tapted, 2013/07/04 02:43:33]

Is there an appropriate place to removeObserver as well?

+         selector:@selector(updateMenuBar:)
+             name:NSWindowDidBecomeMainNotification object:nil];

[tapted, 2013/07/04 02:43:33]

nit: object:nil on a new line

[jackhou1, 2013/07/05 03:52:37]

Done.

 }
 
 // Conditionally adds the Profile menu to the main menu bar.
 - (void)initProfileMenu {
   NSMenu* mainMenu = [NSApp mainMenu];
   NSMenuItem* profileMenu = [mainMenu itemWithTag:IDC_PROFILE_MAIN_MENU];
 
   if (!ProfileManager::IsMultipleProfilesEnabled()) {
     [mainMenu removeItem:profileMenu];
     return;
@@ skipping 239 matching lines @@
   [self performSelector:@selector(delayedScreenParametersUpdate)
              withObject:nil
              afterDelay:0];
 }
 
 - (void)delayedScreenParametersUpdate {
   FOR_EACH_OBSERVER(ui::WorkAreaWatcherObserver, workAreaChangeObservers_,
       WorkAreaChanged());
 }
 
+// If the window is an app window, show the menu bar for that app, otherwise
+// restore the Chrome menu bar.
+- (void)updateMenuBar:(NSNotification*)notification {
+  NSMenu* mainMenu = [NSApp mainMenu];
+  apps::ShellWindow* shell_window =
+      extensions::ShellWindowRegistry::GetShellWindowForNativeWindowAnyProfile(
+          [notification object]);
+
+  if (!shell_window) {
+    // Restore the Chrome menu bar.

[tapted, 2013/07/04 02:43:33]

nit: menu -> main menu? And move down to before the for loop.

[jackhou1, 2013/07/05 03:52:37]

Done.

+    if (!appMenuItem_)
+      return;
+
+    [mainMenu removeItem:appMenuItem_];
+    appMenuItem_.reset();
+
+    for (NSMenuItem* item in [mainMenu itemArray])
+      [item setHidden:NO];
+
+    return;
+  }
+
+  // Hide everything and add a menu item for the app.
+  for (NSMenuItem* item in [mainMenu itemArray])

[tapted, 2013/07/04 02:43:33]

This looks like it will hide appMenuItem_ when an app window is refocussed?
Needs to come later - maybe right before [mainMenu addItem]

[jackhou1, 2013/07/05 03:52:37]

Done.

+    [item setHidden:YES];
+
+  NSString* title = base::SysUTF8ToNSString(shell_window->extension()->name());

[tapted, 2013/07/04 02:43:33]

note: menu_controller.mm does some sanitization of things it puts into menus.. I
don't think you need it, but I haven't thought about it too much

[jackhou1, 2013/07/05 03:52:37]

I think it's mostly for non-text stuff like check boxes etc.

+
+  if (appMenuItem_) {
+    if ([[appMenuItem_ title] isEqualToString:title])

[tapted, 2013/07/04 02:43:33]

since we've got the whole extension, maybe it's better to store the extension_id
at this level, and compare that.

[jackhou1, 2013/07/05 03:52:37]

Done.

+      return;
+
+    [mainMenu removeItem:appMenuItem_];
+    appMenuItem_.reset();

[tapted, 2013/07/04 02:43:33]

nit: this .reset is redundant

[jackhou1, 2013/07/05 03:52:37]

Done.

+  }
+
+  appMenuItem_.reset(
+      [[NSMenuItem alloc] initWithTitle:title
+                                 action:nil
+                          keyEquivalent:@""]);
+  base::scoped_nsobject<NSMenu> appMenu([[NSMenu alloc] initWithTitle:title]);
+  [appMenuItem_ setSubmenu:appMenu];
+  [mainMenu addItem:appMenuItem_];
+}
+
 @end  // @implementation AppController
 
 //---------------------------------------------------------------------------
 
 namespace app_controller_mac {
 
 bool IsOpeningNewWindow() {
   return g_is_opening_new_window;
 }
 
 }  // namespace app_controller_mac