Add testing/iossim/BUILD.gn to build iossim as host for iOS build.

testing/iossim/BUILD.gn

+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/mac/mac_sdk.gni")
+import("//third_party/class-dump/class-dump.gni")
+
+executable("iossim") {
+  sources = [
+    "iossim.mm",
+  ]
+  libs = [ "Foundation.framework" ]
+  deps = [
+    ":generate_dvt_core_simulator",
+    ":generate_dvt_foundation_header",
+    ":generate_dvt_iphone_sim_header",
+  ]
+  include_dirs = [ "$root_gen_dir/iossim" ]
+  configs += [ "//build/config/mac:macosx_version_min_10_9" ]
+}
+
+class_dump("generate_dvt_core_simulator") {
+  framework_name = "CoreSimulator"
+  framework_path = "$mac_sdk_path/../../../../../Library/PrivateFrameworks"
+  class_dump_filter = "Sim"
+}
+
+class_dump("generate_dvt_foundation_header") {
+  framework_name = "DVTFoundation"
+  framework_path = "$mac_sdk_path/../../../../../../SharedFrameworks"
+  class_dump_filter = "DVTStackBacktrace|DVTInvalidation|DVTMixIn"
+}
+
+class_dump("generate_dvt_iphone_sim_header") {
+  topological_sort = true
+  framework_name = "DVTiPhoneSimulatorRemoteClient"
+  framework_path = "$mac_sdk_path/../../../../../../SharedFrameworks"
+  class_dump_filter = "iPhoneSimulator"
+}