Implement NativeWidgetMac::ReorderNativeViews

ui/views/cocoa/bridged_native_widget.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_native_widget.h"
 
 #import <objc/runtime.h>
 #include <stddef.h>
 #include <stdint.h>
 
@@ skipping 65 matching lines @@
   [window_ invalidateShadow];
 }
 - (void)setCurrentProgress:(NSAnimationProgress)progress {
   [super setCurrentProgress:progress];
   [window_ invalidateShadow];
 }
 @end
 
 namespace {
 
+using RankMap = std::map<NSView*, int>;
+
 const CGFloat kMavericksMenuOpacity = 251.0 / 255.0;
 const CGFloat kYosemiteMenuOpacity = 194.0 / 255.0;
 const int kYosemiteMenuBlur = 80;
 
 // Margin at edge and corners of the window that trigger resizing. These match
 // actual Cocoa resize margins.
 const int kResizeAreaEdgeSize = 3;
 const int kResizeAreaCornerSize = 12;
 
 int kWindowPropertiesKey;
@@ skipping 160 matching lines @@
 // resize operations to coordinate with frames provided by the GPU process.
 scoped_refptr<base::SingleThreadTaskRunner> GetCompositorTaskRunner() {
   // If the WindowResizeHelper's pumpable task runner is set, it means the GPU
   // process is directing messages there, and the compositor can synchronize
   // with it. Otherwise, just use the UI thread.
   scoped_refptr<base::SingleThreadTaskRunner> task_runner =
       ui::WindowResizeHelperMac::Get()->task_runner();
   return task_runner ? task_runner : base::ThreadTaskRunnerHandle::Get();
 }
 
+void RankNSViews(views::View* view,
+                 const views::BridgedNativeWidget::AssociatedViews& hosts,
+                 RankMap* rank) {
+  auto it = hosts.find(view);
+  if (it != hosts.end())
+    rank->emplace(it->second, rank->size());
+  for (int i = 0; i < view->child_count(); ++i)
+    RankNSViews(view->child_at(i), hosts, rank);
+}
+
+NSComparisonResult SubviewSorter(id lhs, id rhs, void* rank_as_void) {

[tapted, 2016/03/17 23:51:27]

Make sure you do a build with xcode 7 too. I had to change this method signature
to

NSComparisonResult SubviewSorter(__kindof NSView* lhs, __kindof NSView* rhs,
void* rank_as_void) 

to avoid

../../ui/views/cocoa/bridged_native_widget.mm:941:54: error: incompatible
pointer types sending 'NSComparisonResult (*)(id, id, void *)' to parameter of
type 'NSComparisonResult (* _Nonnull)(__kindof NSView * _Nonnull, __kindof
NSView * _Nonnull, void * _Nullable)' (aka 'NSComparisonResult (*)(__kindof
NSView * _Nonnull, __kindof NSView * _Nonnull, void * _Nullable)')
[-Werror,-Wincompatible-pointer-types]


However, I think the bots are still xcode 6, and that probably doesn't have
__kindof, so we might need some other way to fix this, or have a #if xcode < 7
check that #defines it to something empty.


Sadly, if you break developer's compiles on xcode 7, that's probably enough to
have the patch quickly reverted, even if no bots break.

+  DCHECK_NE(lhs, rhs);
+
+  const RankMap* rank = static_cast<const RankMap*>(rank_as_void);
+  auto left_rank = rank->find(lhs);
+  auto right_rank = rank->find(rhs);
+  bool left_found = left_rank != rank->end();
+  bool right_found = right_rank != rank->end();
+
+  // Sort unassociated views above associated views.
+  if (left_found != right_found)
+    return left_found ? NSOrderedAscending : NSOrderedDescending;
+
+  if (left_found) {
+    return left_rank->second < right_rank->second ? NSOrderedAscending
+                                                  : NSOrderedDescending;
+  }
+
+  // If both are unassociated, consider that order is not important
+  return NSOrderedSame;
+}
+
 }  // namespace
 
 namespace views {
 
 // static
 gfx::Size BridgedNativeWidget::GetWindowSizeForClientSize(
     NSWindow* window,
     const gfx::Size& content_size) {
   NSRect content_rect =
       NSMakeRect(0, 0, content_size.width(), content_size.height());
@@ skipping 601 matching lines @@
     // to generate a window shadow from the composited CALayer. To get around
     // this, let the window background remain opaque and clip the window
     // boundary in drawRect method of BridgedContentView. See crbug.com/543671.
     if (base::mac::IsOSYosemiteOrLater())
       [window_ setBackgroundColor:[NSColor clearColor]];
   }
 
   UpdateLayerProperties();
 }
 
+void BridgedNativeWidget::SetAssociationForView(const views::View* view,
+                                                NSView* native_view) {
+  DCHECK_EQ(0u, associated_views_.count(view));
+  associated_views_[view] = native_view;
+  native_widget_mac_->GetWidget()->ReorderNativeViews();
+}
+
+void BridgedNativeWidget::ClearAssociationForView(const views::View* view) {
+  auto it = associated_views_.find(view);
+  DCHECK(it != associated_views_.end());
+  associated_views_.erase(it);
+}
+
+void BridgedNativeWidget::ReorderChildViews() {
+  RankMap rank;
+  Widget* widget = native_widget_mac_->GetWidget();
+  RankNSViews(widget->GetRootView(), associated_views_, &rank);
+  // Set compositor view below

[tapted, 2016/03/17 23:04:15]

Yep - this makes sense, but the comment should explain a bit more. E.g.

  // Unassociated NSViews should be ordered above associated ones. The exception
  // is the UI compositor's superview, which should always be on the very
  // bottom, so give it an explicit negative rank.

+  if (compositor_superview_)
+    rank[compositor_superview_.get()] = -1;

[tapted, 2016/03/17 23:04:15]

The .get() shouldn't be required -- scoped_nsobject auto-converts usually

+  [widget->GetNativeView() sortSubviewsUsingFunction:&SubviewSorter

[tapted, 2016/03/17 23:04:15]

widget->GetNativeView() --> bridged_view_ 

+                                             context:&rank];
+}
+
 ////////////////////////////////////////////////////////////////////////////////
 // BridgedNativeWidget, internal::InputMethodDelegate:
 
 ui::EventDispatchDetails BridgedNativeWidget::DispatchKeyEventPostIME(
     ui::KeyEvent* key) {
   DCHECK(focus_manager_);
   native_widget_mac_->GetWidget()->OnKeyEvent(key);
   if (!key->handled()) {
     if (!focus_manager_->OnKeyEvent(*key))
       key->StopPropagation();
@@ skipping 341 matching lines @@
   [bridged_view_ setMouseDownCanMoveWindow:draggable];
   // AppKit will not update its cache of mouseDownCanMoveWindow unless something
   // changes. Previously we tried adding an NSView and removing it, but for some
   // reason it required reposting the mouse-down event, and didn't always work.
   // Calling the below seems to be an effective solution.
   [window_ setMovableByWindowBackground:NO];
   [window_ setMovableByWindowBackground:YES];
 }
 
 }  // namespace views