Implement NativeWidgetMac::ReorderNativeViews

ui/views/widget/widget_mac_utils.mm

+// Copyright 2016 The Chromium Authors. All rights reserved.

[tapted, 2016/03/17 08:18:59]

Can this entire file just be moved into the anonymous namespace in
brridged_native_widget? (except the typedef - that can go on BridgedNativeWidget
-- and ReorderChildNSViews might as well just go on BridgedNativeWidget as a
member function)

(otherwise, it should go in ui/views/cocoa/ and.. probably be called
reorder_child_nsviews.mm or something -- foo_utils.h files have a tendency to
become a grab-bag of unrelated stuff that don't belong together)

+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "ui/views/widget/widget_mac_utils.h"
+
+#include "base/mac/foundation_util.h"
+#include "ui/views/widget/widget.h"
+
+namespace views {
+namespace {
+
+using RankMap = std::map<NSView*, int>;
+
+void RankNSViews(View* view, const AssociatedViews& hosts, RankMap* rank) {
+  auto it = hosts.find(view);
+  if (it != hosts.end())
+    rank->emplace(it->second, rank->size());
+  for (int i = 0; i < view->child_count(); ++i)
+    RankNSViews(view->child_at(i), hosts, rank);
+}
+
+NSComparisonResult SubviewSorter(id lhs, id rhs, void* rank_as_void) {
+  DCHECK_NE(lhs, rhs);
+
+  const RankMap* rank = static_cast<const RankMap*>(rank_as_void);
+  auto left_rank = rank->find(lhs);
+  auto right_rank = rank->find(rhs);
+  bool left_found = left_rank != rank->end();
+  bool right_found = right_rank != rank->end();
+
+  // Sort unassociated views below associated views.
+  if (left_found != right_found)
+    return left_found ? NSOrderedDescending : NSOrderedAscending;
+
+  if (left_found)
+    return *left_rank < *right_rank ? NSOrderedAscending : NSOrderedDescending;
+
+  // If both are unassociated, consider that order is not important
+  return NSOrderedSame;
+}
+
+}  // namespace
+
+void ReorderChildNSViews(Widget* widget,
+                         const AssociatedViews& associated_views) {
+  RankMap rank;
+  RankNSViews(widget->GetRootView(), associated_views, &rank);
+  [widget->GetNativeView() sortSubviewsUsingFunction:&SubviewSorter
+                                             context:&rank];
+}
+
+}  // namespace views