MacViews: Remove constrained window dependencies for certificate viewer.

chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.mm

Index: chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.mm
diff --git a/chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.mm b/chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.mm
new file mode 100644
index 0000000000000000000000000000000000000000..d6dd3ffaf0d7eab02501d412957391324d9fa432
--- /dev/null
+++ b/chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.mm
@@ -0,0 +1,134 @@
+// Copyright 2016 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/certificate_viewer_mac_cocoa.h"
+
+#include "base/logging.h"
+#import "base/mac/foundation_util.h"
+#include "chrome/browser/certificate_viewer.h"
+#import "chrome/browser/ui/cocoa/constrained_window/constrained_window_mac.h"
+#import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet.h"

[tapted, 2016/05/31 07:44:47]

nit: remove (not needed since the corresponding header includes it)

[Patti Lor, 2016/06/06 06:52:46]

Done.

+#import "chrome/browser/ui/cocoa/constrained_window/constrained_window_sheet_controller.h"
+
+class SSLCertificateViewerCocoaBridge : public ConstrainedWindowMacDelegate {

[tapted, 2016/05/31 07:44:47]

wrap this in an anonymous

namespace {

[Patti Lor, 2016/06/06 06:52:46]

Done.

+ public:
+  explicit SSLCertificateViewerCocoaBridge(
+      SSLCertificateViewerCocoa* controller)
+      : controller_(controller) {}
+
+  virtual ~SSLCertificateViewerCocoaBridge() {}

[tapted, 2016/05/31 07:44:47]

nit: can this be removed? the compiler-provided default should be fine

[Patti Lor, 2016/06/06 06:52:46]

Done.

+
+  // ConstrainedWindowMacDelegate implementation:

[tapted, 2016/05/31 07:44:47]

nit: // ConstrainedWindowMacDelegate:

(the ... implementation: style is just for ObjC these days)

[Patti Lor, 2016/06/06 06:52:46]

Done.

+  void OnConstrainedWindowClosed(ConstrainedWindowMac* window) override {
+    // |onConstrainedWindowClosed| will delete the sheet which might still be
+    // in use higher up the call stack. Wait for the next cycle of the event
+    // loop to call this function.
+    [controller_ performSelector:@selector(onConstrainedWindowClosed)
+                      withObject:nil
+                      afterDelay:0];
+  }
+
+ private:
+  SSLCertificateViewerCocoa* controller_;  // Weak. Owns this.
+
+  DISALLOW_COPY_AND_ASSIGN(SSLCertificateViewerCocoaBridge);
+};
+

[tapted, 2016/05/31 07:44:47]

}  // namespace

[Patti Lor, 2016/06/06 06:52:46]

Done.

+@implementation SSLCertificateViewerCocoa {
+  std::unique_ptr<SSLCertificateViewerCocoaBridge> observer_;
+  std::unique_ptr<ConstrainedWindowMac> constrainedWindow_;
+  base::scoped_nsobject<NSWindow> overlayWindow_;
+  // A copy of the sheet's frame. Used to restore on show.
+  NSRect oldSheetFrame_;
+  BOOL closePending_;
+  // A copy of the sheet's |autoresizesSubviews| flag to restore on show.
+  BOOL oldResizesSubviews_;
+}
+
+- (void)sheetDidEnd:(NSWindow*)parent

[tapted, 2016/05/31 07:44:47]

nit: this should come before // ConstrainedWindowSheet protocol implementation.
and preceded by

// SSLCertificateViewerMac overrides:

[Patti Lor, 2016/06/06 06:52:46]

Done.

+         returnCode:(NSInteger)returnCode
+            context:(void*)context {
+  if (!closePending_)
+    constrainedWindow_->CloseWebContentsModalDialog();
+}
+
+- (void)displayForWebContents:(content::WebContents*)webContents {

[tapted, 2016/05/31 07:44:48]

So.. since displayForWebContents and onConstrainedWindowClosed are newly
introduced "private" interfaces, we should declare those in a private category.
This should come before the anonymous namespace that holds
SSLCertificateViewerCocoaBridge, and it looks like

@interface SSLCertificateViewerCocoa ()
- (void)displayForWebContents:(content::WebContents*)webContents;
- (void)onConstrainedWindowClosed;
@end

[Patti Lor, 2016/06/06 06:52:45]

Done.

+  [super displayForWebContents:webContents];
+
+  observer_.reset(new SSLCertificateViewerCocoaBridge(self));
+  constrainedWindow_ =
+      CreateAndShowWebModalDialogMac(observer_.get(), webContents, self);
+}
+
+- (NSWindow*)overlayWindow {

[tapted, 2016/05/31 07:44:47]

nit: this should be defined first, since it's in the public interface, followed
by the private category (displayForWebContents,onConstrainedwindowClosed), then
overrides, then protocol impl.

[Patti Lor, 2016/06/06 06:52:46]

Done.

+  return overlayWindow_;
+}
+
+- (void)onConstrainedWindowClosed {
+  constrainedWindow_.reset();
+  [self release];
+}
+
+// ConstrainedWindowSheet protocol implementation.
+
+- (void)showSheetForWindow:(NSWindow*)window {
+  overlayWindow_.reset([window retain]);
+  [self showCertificateSheet:window];
+}
+
+- (void)closeSheetWithAnimation:(BOOL)withAnimation {
+  closePending_ = YES;
+  overlayWindow_.reset();
+  [self closeCertificateSheet:withAnimation];
+}
+
+- (void)hideSheet {
+  NSWindow* sheetWindow = [overlayWindow_ attachedSheet];
+  [sheetWindow setAlphaValue:0.0];
+  [sheetWindow setIgnoresMouseEvents:YES];
+
+  oldResizesSubviews_ = [[sheetWindow contentView] autoresizesSubviews];
+  [[sheetWindow contentView] setAutoresizesSubviews:NO];
+}
+
+- (void)unhideSheet {
+  NSWindow* sheetWindow = [overlayWindow_ attachedSheet];
+  [sheetWindow setIgnoresMouseEvents:NO];
+
+  [[sheetWindow contentView] setAutoresizesSubviews:oldResizesSubviews_];
+  [[overlayWindow_ attachedSheet] setAlphaValue:1.0];
+}
+
+- (void)pulseSheet {
+  // NOOP
+}
+
+- (void)makeSheetKeyAndOrderFront {
+  [[overlayWindow_ attachedSheet] makeKeyAndOrderFront:nil];
+}
+
+- (void)updateSheetPosition {
+  // NOOP
+}
+
+- (void)resizeWithNewSize:(NSSize)preferredSize {
+  // NOOP
+}
+
+- (NSWindow*)sheetWindow {
+  return [self certificatePanel];
+}
+
+@end
+
+void ShowCertificateViewer(content::WebContents* web_contents,
+                           gfx::NativeWindow parent,
+                           net::X509Certificate* cert) {
+  // SSLCertificateViewerCocoa will manage its own lifetime and will release
+  // itself when the dialog is closed.
+  // See -[SSLCertificateViewerCocoa onConstrainedWindowClosed].
+  SSLCertificateViewerCocoa* viewer =
+      [[SSLCertificateViewerCocoa alloc] initWithCertificate:cert];
+  [viewer displayForWebContents:web_contents];
+}