Move //remoting/remoting_host_win.gypi:* to GN

remoting/host/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//build/util/version.gni")
 import("//remoting/remoting_host.gni")
 import("//remoting/remoting_locales.gni")
 import("//remoting/remoting_options.gni")
@@ skipping 351 matching lines @@
       ]
     }
 
     midl("remoting_lib_idl") {
       sources = get_target_outputs(":generate_idl")
       deps = [
         ":generate_idl",
       ]
     }
 
+    # GYP version: remoting/remoting_host_win.gypi:remoting_lib_ps
+    static_library("remoting_lib_ps") {
+      defines = [
+        "ENTRY_PREFIX=Ps",
+        "REGISTER_PROXY_DLL",
+      ]
+
+      deps = [
+        ":remoting_lib_idl",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/host/chromoting_lib.dlldata.c",
+        "$root_gen_dir/remoting/host/chromoting_lib_p.c",
+      ]
+
+      if (is_clang) {
+        cflags = [
+          # MIDL generated code has a habit of omitting optional braces.
+          "-Wno-missing-braces",
+
+          # Source files generated by the MIDL compiler trigger warnings with
+          # -Wincompatible-pointer-types enabled.
+          "-Wno-incompatible-pointer-types",
+
+          # Generated code contains unused variables.
+          "-Wno-unused-variable",
+
+          # PROXYFILE_LIST_START is an extern with initializer.
+          "-Wno-extern-initializer",
+        ]
+      }
+    }
+
+    # GYP version: remoting/remoting_host_win.gypi:remoting_lib_rc
+    action("remoting_lib_rc") {
+      sources = [
+        "win/chromoting_lib_idl.templ",
+      ]
+
+      script = "gen_remoting_lib_rc.py"
+
+      outputs = [
+        "$target_gen_dir/chromoting_lib.rc",
+      ]
+
+      args = [ rebase_path(outputs[0], root_build_dir) ]
+    }
+
     # Makes the .mc file from the .mc.jinja file.
     remoting_localize("messages_localizing") {
       sources = [
         "win/host_messages.mc.jinja2",
       ]
       locales = remoting_locales
       locale_dir = webapp_locale_dir
       encoding = "utf-16"
 
       # This target is funny. It only produces one file and the output doesn't
       # match the input. We want to generate remoting_host_messages.mc from
       # host_messages.mg.jinja2. GN complains if it doesn't see a pattern in the
       # output, so the following pattern produces the name we want with a template
       # based on the input.
       #
       # TODO: This is for GYP compat. We should just make the names match instead.
       output = "$target_gen_dir/remoting_{{source_name_part}}"
     }
 
     # Makes the .h/.rc files from the .mc file.
     message_compiler("messages") {
       sources = get_target_outputs(":messages_localizing")
       deps = [
         ":messages_localizing",
       ]
     }
 
+    # GYP version: remoting/remoting_host_win.gypi:remoting_console
+    executable("remoting_console") {
+      configs += [ "//build/config/compiler:wexit_time_destructors" ]
+
+      defines = [ "BINARY=BINARY_HOST_ME2ME" ]
+
+      deps = [
+        ":remoting_core",
+        ":remoting_windows_resources",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/version.rc",
+        "win/entry_point.cc",
+      ]
+
+      ldflags = [
+        "/MANIFEST:EMBED",
+        "/MANIFESTINPUT:" +
+            rebase_path("win/dpi_aware.manifest", root_build_dir),
+        "/ENTRY:HostEntryPoint",
+        "/NODEFAULTLIB",
+      ]
+    }
+
+    # GYP version: //remoting/remoting_host_win.gypi:remoting_core
+    shared_library("remoting_core") {
+      configs += [
+        "//base/allocator:allocator_shim_define",
+        "//build/config/compiler:wexit_time_destructors",
+      ]
+
+      defines = [
+        "_ATL_APARTMENT_THREADED",
+        "_ATL_CSTRING_EXPLICIT_CONSTRUCTORS",
+        "_ATL_NO_AUTOMATIC_NAMESPACE",
+        "_ATL_NO_EXCEPTIONS",
+        "BINARY=BINARY_CORE",
+        "BINARY_CORE=1",
+        "BINARY_DESKTOP=2",
+        "BINARY_HOST_ME2ME=3",
+        "BINARY_NATIVE_MESSAGING_HOST=4",
+        "BINARY_REMOTE_ASSISTANCE_HOST=5",
+        "DAEMON_CONTROLLER_CLSID=\"$daemon_controller_clsid\"",
+        "RDP_DESKTOP_SESSION_CLSID=\"$rdp_desktop_session_clsid\"",
+        "HOST_IMPLEMENTATION",
+        "ISOLATION_AWARE_ENABLED=1",
+        "STRICT",
+        "VERSION=$chrome_version_full",
+      ]
+
+      if (is_win && remoting_multi_process != 0 && remoting_rdp_session != 0) {
+        defines += [ "REMOTING_RDP_SESSION" ]
+      }
+
+      if (remoting_multi_process != 0) {
+        defines += [ "REMOTING_MULTI_PROCESS" ]
+      }
+
+      deps = [
+        ":remoting_lib_idl",
+        ":remoting_lib_ps",
+        ":remoting_lib_rc",
+        ":remoting_me2me_host_static",
+        ":remoting_windows_resources",
+        "//base",
+        "//base:base_static",
+        "//base/third_party/dynamic_annotations",
+        "//ipc",
+        "//net",
+        "//remoting/base",
+        "//remoting/base:breakpad",
+        "//remoting/codec",
+        "//remoting/host",
+        "//remoting/host:messages",
+        "//remoting/host/it2me:common",
+        "//remoting/host/native_messaging",
+        "//remoting/host/setup",
+        "//remoting/protocol",
+        "//sandbox/win:sandbox",  # Should always use Windows version
+        "//third_party/webrtc/modules/desktop_capture",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/host/chromoting_lib.rc",
+        "desktop_process_main.cc",
+        "host_main.cc",
+        "host_main.h",
+        "it2me/it2me_native_messaging_host_main.cc",
+        "it2me/it2me_native_messaging_host_main.h",
+        "security_key/remote_security_key_main.cc",
+        "security_key/remote_security_key_main.h",
+        "setup/me2me_native_messaging_host_main.cc",
+        "setup/me2me_native_messaging_host_main.h",
+        "win/chromoting_module.cc",
+        "win/chromoting_module.h",
+        "win/core.cc",
+        "win/core_resource.h",
+        "win/host_service.cc",
+        "win/host_service.h",
+        "win/omaha.cc",
+        "win/omaha.h",
+        "win/rdp_desktop_session.cc",
+        "win/rdp_desktop_session.h",
+        "win/unprivileged_process_delegate.cc",
+        "win/unprivileged_process_delegate.h",
+        "win/wts_session_process_delegate.cc",
+        "win/wts_session_process_delegate.h",
+        "worker_process_ipc_delegate.h",
+      ]
+
+      ldflags = [
+        "/MANIFEST:EMBED",
+        "/MANIFESTINPUT:" +
+            rebase_path("win/common-controls.manifest", root_build_dir),
+        "comctl32.lib",
+        "rpcns4.lib",
+        "rpcrt4.lib",
+        "uuid.lib",
+        "wtsapi32.lib",
+        "/EXPORT:DllGetClassObject=PsDllGetClassObject,PRIVATE",
+        "/EXPORT:DllCanUnloadNow=PsDllCanUnloadNow,PRIVATE",
+        "/EXPORT:DllRegisterServer=PsDllRegisterServer,PRIVATE",
+        "/EXPORT:DllUnregisterServer=PsDllUnregisterServer,PRIVATE",
+      ]
+
+      if (is_clang) {
+        cflags += [ "-Wno-header-hygiene" ]
+      }
+    }
+
+    # GYP version: //remoting/remoting_host_win.gypi:remoting_desktop
+    executable("remoting_desktop") {
+      configs += [
+        "//build/config/compiler:wexit_time_destructors",
+        "//build/config/win:windowed",
+      ]
+
+      defines = [ "BINARY=BINARY_DESKTOP" ]
+
+      deps = [
+        ":remoting_core",
+        ":remoting_windows_resources",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/version.rc",
+        "win/entry_point.cc",
+      ]
+
+      ldflags = [
+        "/MANIFEST:EMBED",
+        "/MANIFESTINPUT:" +
+            rebase_path("win/dpi_aware.manifest", root_build_dir),
+        "/MANIFESTUAC",
+        "/ENTRY:HostEntryPoint",
+        "/NODEFAULTLIB",
+      ]
+
+      if (is_official_build) {
+        ldflags += [
+          "/MANIFESTUAC:level=2",
+          "/MANIFESTUAC:uiAccess=true",
+        ]
+      }
+    }
+
+    # GYP version: //remoting/remoting_host_win.gypi:remote_security_key
+    executable("remote_security_key") {
+      configs += [ "//build/config/compiler:wexit_time_destructors" ]
+
+      defines = [ "BINARY=BINARY_REMOTE_SECURITY_KEY" ]
+
+      deps = [
+        ":remoting_core",
+        ":remoting_windows_resources",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/version.rc",
+        "security_key/remote_security_key_entry_point.cc",
+      ]
+
+      ldflags = [ "/NODEFAULTLIB" ]
+    }
+
+    # GYP version:
+    # //remoting/remoting_host_win.gypi:remoting_me2me_native_messaging_host
+    executable("remoting_me2me_native_messaging_host") {
+      configs += [ "//build/config/compiler:wexit_time_destructors" ]
+
+      deps = [
+        ":remoting_core",
+        ":remoting_windows_resources",
+      ]
+
+      sources = [
+        "$root_gen_dir/remoting/version.rc",
+        "setup/me2me_native_messaging_host_entry_point.cc",
+      ]
+
+      ldflags = [ "/NODEFAULTLIB" ]
+    }
+
+    # GYP version: //remoting/remoting_host_win.gypi:remoting_windows_resources
+    remoting_localize("remoting_windows_resources") {
+      deps = [
+        "//remoting/resources",
+      ]
+
+      sources = [
+        "win/core.rc.jinja2",
+        "win/version.rc.jinja2",

[Sergey Ulanov, 2016/03/02 20:46:43]

Should remoting_lib.rc be in this list?

[Hzj_jie, 2016/03/03 09:06:35]

No, seems not, gn have only foreach_action, without extension parameter to
select files based on extension.

So current way is,
Change to chromoting_lib_idl.templ triggers both generate_idl and
remoting_lib_rc (newly added)

generate_idl -> remoting_lib_idl -> (remoting_lib_ps, remoting_core, host)

remoting_lib_rc -> remoting_core

So looks like we do not need remoting_lib_rc to trigger remoting_core to be
rebuilt. I will remove it and see if everything works.

+      ]
+
+      # TODO(zijiehe): Why version file strings are not public in GN?

[Sergey Ulanov, 2016/03/01 20:26:43]

I think GN does have variables for the version, see
https://code.google.com/p/chromium/codesearch#chromium/src/build/util/version...

It's already used in this file to pass VERSION define when compiling the host.
Or maybe I just don't understand this TODO.

[Hzj_jie, 2016/03/02 08:27:29]

Yes, thank you. But //build/util/LASTCHANGE is not exported.

+      variables = [
+        rebase_path("//chrome/VERSION"),
+        rebase_path("//remoting/VERSION"),
+        rebase_path("//build/util/LASTCHANGE"),
+      ]
+
+      output = "$root_gen_dir/remoting/{{source_name_part}}"
+
+      locale_dir = webapp_locale_dir
+
+      encoding = "utf-16"
+
+      locales = remoting_locales
+    }
+
     # TODO(GYP) More Windows remoting targets from remoting_host_win.gypi
   }
 
   if (enable_remoting_host) {
     executable("remoting_start_host") {
       sources = [
         "setup/host_starter.cc",
         "setup/host_starter.h",
         "setup/start_host.cc",
       ]
 
       deps = [
         "//build/config/sanitizers:deps",
         "//remoting/host/setup",
       ]
 
       if (enable_webrtc) {
         deps += [ "//third_party/libjingle:libjingle_webrtc" ]
       }
     }
 
     action_foreach("remoting_native_messaging_manifests") {
       if (is_mac) {
         assert(false, "not implemented on mac yet")
-      } else if (is_win) {
-        assert(false, "not implemented on win yet")
       } else {
         me2me_host_path =
             "/opt/google/chrome-remote-desktop/native-messaging-host"
         it2me_host_path =
             "/opt/google/chrome-remote-desktop/remote-assistance-host"
       }
 
       script = "../tools/build/remoting_localize.py"
 
       sources = [
@@ skipping 63 matching lines @@
         deps += [ "//build/config/linux/gtk2" ]
       }
       if ((is_linux && !is_chromeos) || is_mac) {
         libs = [ "pam" ]
       }
 
       if (is_mac && is_official_build) {
         sources += [ "internal/internal_mac-inl.h" ]
         defines += [ "USE_REMOTING_MACOSX_INTERNAL" ]
       }
+
+      if (is_win && remoting_multi_process != 0 && remoting_rdp_session != 0) {
+        defines += [ "REMOTING_RDP_SESSION" ]
+      }
+
+      if (remoting_multi_process != 0) {
+        defines += [ "REMOTING_MULTI_PROCESS" ]
+      }
     }
 
-    if (!is_win) {
+    if (is_win) {
+      # GYP version: //remoting/remoting_host_win.gypi:remoting_me2me_host
+      executable("remoting_me2me_host") {
+        configs += [
+          "//build/config/compiler:wexit_time_destructors",
+          "//build/config/win:windowed",
+        ]
+
+        defines = [ "BINARY=BINARY_HOST_ME2ME" ]
+
+        deps = [
+          ":remoting_core",
+          ":remoting_windows_resources",
+        ]
+
+        sources = [
+          "$root_gen_dir/remoting/version.rc",
+          "win/entry_point.cc",
+        ]
+
+        output_name = "remoting_host"
+
+        ldflags = [
+          "/MANIFEST:EMBED",
+          "/MANIFESTINPUT:" +
+              rebase_path("win/dpi_aware.manifest", root_build_dir),
+          "/ENTRY:HostEntryPoint",
+          "/NODEFAULTLIB",
+        ]
+      }
+    } else {
       executable("remoting_me2me_host") {
         sources = [
           "host_main.cc",
           "host_main.h",
         ]
 
+        if (((is_mac && is_chrome_branded) || is_win) && is_official_build) {

[Sergey Ulanov, 2016/03/01 20:26:43]

What's the reason it needs to be chrome-branded on mac, but not on windows?

[Hzj_jie, 2016/03/02 08:27:29]

It's the combination of,
https://cs.corp.google.com/clankium/src/remoting/remoting.gyp?rcl=0&l=63
and,
https://cs.corp.google.com/cobalt/build/common.gypi?rcl=0&l=1226
But, yes, it's out of date, I should remove is_win, since we are building
remoting_host.exe on windows with a totally different logic.

+          defines = [ "REMOTING_ENABLE_BREAKPAD" ]
+        }
+
         deps = [
           ":credits",
           ":remoting_me2me_host_static",
           "//build/config/sanitizers:deps",
         ]
       }
 
       executable("native_messaging_host") {
         sources = [
           "setup/me2me_native_messaging_host_entry_point.cc",
@@ skipping 12 matching lines @@
 
         configs += [ "//build/config/compiler:wexit_time_destructors" ]
 
         # The |major|, |build| and |patch| versions are inherited from Chrome.
         # Since Chrome's |minor| version is always '0', we replace it with a
         # Chromoting-specific patch version.
         defines = [ "VERSION=" + "$chrome_version_major" + "." +
                     "$remoting_version_patch" + "." + "$chrome_version_build" +
                     "." + "$chrome_version_patch" ]
 
-        if (is_mac || is_win) {
+        if (is_mac) {
           assert(false, "not implemented on mac or win yet")

[Sergey Ulanov, 2016/03/01 20:26:43]

nit: update the message

[Hzj_jie, 2016/03/02 08:27:29]

Done.

         }
       }
     }
 
     if (is_chrome_branded && enable_me2me_host && !is_chromeos) {
       # TODO(GYP): add support for archive_chromoting_tests variable?
 
       import("//build/config/zip.gni")
 
       build_deb_script = "installer/linux/build_deb.py"
@@ skipping 80 matching lines @@
           "//remoting/resources",
           "//third_party/icu:icudata",
         ]
       }
     } else {
       group("remoting_me2me_host_archive") {
       }
     }
   }
 }