MacViews: Implement Tab Dragging

ui/base/test/ui_controls_mac.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ui/base/test/ui_controls.h"
 
 #import <Cocoa/Cocoa.h>
 #include <vector>
 
 #include "base/bind.h"
 #include "base/callback.h"
+#include "base/mac/scoped_nsautorelease_pool.h"
+#include "base/mac/scoped_nsobject.h"
+#include "base/mac/scoped_objc_class_swizzler.h"
 #include "base/message_loop/message_loop.h"
+#include "base/thread_task_runner_handle.h"
 #include "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #import "ui/events/test/cocoa_test_event_utils.h"
+#include "ui/gfx/mac/coordinate_conversion.h"
+#include "ui/gfx/screen.h"
 
 // Implementation details: We use [NSApplication sendEvent:] instead
 // of [NSApplication postEvent:atStart:] so that the event gets sent
 // immediately.  This lets us run the post-event task right
 // immediately as well.  Unfortunately I cannot subclass NSEvent (it's
 // probably a class cluster) to allow other easy answers.  For
 // example, if I could subclass NSEvent, I could run the Task in it's
 // dealloc routine (which necessarily happens after the event is
 // dispatched).  Unlike Linux, Mac does not have message loop
 // observer/notification.  Unlike windows, I cannot post non-events
@@ skipping 18 matching lines @@
 //    be used, so that we don't need to poll the event queue time to time.
 
 using cocoa_test_event_utils::SynthesizeKeyEvent;
 using cocoa_test_event_utils::TimeIntervalSinceSystemStartup;
 
 namespace {
 
 // Stores the current mouse location on the screen. So that we can use it
 // when firing keyboard and mouse click events.
 NSPoint g_mouse_location = { 0, 0 };
+bool g_mouse_button_down[3] = { false, false, false };

[tapted, 2016/03/01 08:11:58]

comment (mention that it's indexed by ui_controls::MouseButton)

[themblsha, 2016/03/09 17:40:22]

Done.

 
 bool g_ui_controls_enabled = false;
 
 // Creates the proper sequence of autoreleased key events for a key down + up.
 void SynthesizeKeyEventsSequence(NSWindow* window,
                                  ui::KeyboardCode keycode,
                                  bool control,
                                  bool shift,
                                  bool alt,
                                  bool command,
@@ skipping 102 matching lines @@
       return window;
   }
 
   // Note that -[NSApplication orderedWindows] won't include NSPanels. If a test
   // uses those, it will need to handle that itself.
   return nil;
 }
 
 }  // namespace
 
+namespace {
+int kEventDeletedTaskRunnerKey;

[tapted, 2016/03/01 08:11:58]

can be merged with the namespace above. needs a comment.

[themblsha, 2016/03/09 17:40:22]

Done.

+} // namespace
+
+@interface EventDeletedTaskRunner : NSObject {

[tapted, 2016/03/01 08:11:58]

What's the reason why EventQueueWatcher couldn't support this?

[themblsha, 2016/03/01 18:41:53]

I'm spawning these on a separate thread, as the main one is inside a nested
eventloop — and the queue on the separate thread is always empty as the events
are magically posted to the UI thread. But turns out there's an error in
implementation — NSErrors are copied and the copy is actually processed, so the
tasks are added to the queue before the event finishes processing.

This currently results in a race condition when g_mouse_location is updated
while the previous message is still being processed — that's why the window move
works.

And currently the simulated events don't move the window while in
CocoaWindowMoveLoop, still investigating how it works internally — maybe I'm
sending wrong messages or not enough messages or something else. Need to do
additional reverse-engineering on this.

Another option which I did at first involved sending CG-events which I've
created using CGEventCreateMouseEvent — but they have two drawbacks:
1. They move the real mouse
2. Don't know how to know when they've finished being processed

+ @private
+  scoped_refptr<base::SingleThreadTaskRunner> task_runner_;
+  base::Closure finish_closure_;
+}
+- (id)initWithClosure:(const base::Closure&)task;
+@end
+
+@implementation EventDeletedTaskRunner
+- (id)initWithClosure:(const base::Closure&)task {
+  if (self = [super init]) {
+    task_runner_ = base::ThreadTaskRunnerHandle::Get();
+    finish_closure_ = task;
+  }
+  return self;
+}
+
+- (void)dealloc {
+  task_runner_->PostTask(FROM_HERE, finish_closure_);
+  [super dealloc];
+}
+@end
+
+// Donates testing implementations of NSEvent methods.
+@interface FakeNSEventTestingDonor : NSObject
+@end
+
+@implementation FakeNSEventTestingDonor
++ (NSPoint)mouseLocation {
+  return g_mouse_location;
+}
+
++ (NSUInteger)pressedMouseButtons {
+  NSUInteger result = 0;
+  const int buttons[3] = {
+      ui_controls::LEFT, ui_controls::RIGHT, ui_controls::MIDDLE};
+  for (unsigned int i = 0; i < arraysize(buttons); ++i) {
+    if (g_mouse_button_down[buttons[i]])
+      result |= (1 << i);
+  }
+  return result;
+}
+@end
+
+namespace {
+class ScopedNSEventSwizzler {
+ public:
+  static void Install() {
+    static ScopedNSEventSwizzler* swizzler = nullptr;
+    if (!swizzler) {
+      swizzler = new ScopedNSEventSwizzler();
+    }
+  }
+
+ protected:
+  ScopedNSEventSwizzler()
+      : mouse_location_swizzler_(new base::mac::ScopedObjCClassSwizzler(
+            [NSEvent class],
+            [FakeNSEventTestingDonor class],
+            @selector(mouseLocation))),
+        pressed_mouse_buttons_swizzler_(new base::mac::ScopedObjCClassSwizzler(
+            [NSEvent class],
+            [FakeNSEventTestingDonor class],
+            @selector(pressedMouseButtons))) {
+  }
+
+ private:
+  scoped_ptr<base::mac::ScopedObjCClassSwizzler> mouse_location_swizzler_;
+  scoped_ptr<base::mac::ScopedObjCClassSwizzler>
+      pressed_mouse_buttons_swizzler_;
+};
+}  // namespace
+
 namespace ui_controls {
 
 void EnableUIControls() {
   g_ui_controls_enabled = true;
 }
 
 bool SendKeyPress(gfx::NativeWindow window,
                   ui::KeyboardCode key,
                   bool control,
                   bool shift,
@@ skipping 10 matching lines @@
 bool SendKeyPressNotifyWhenDone(gfx::NativeWindow window,
                                 ui::KeyboardCode key,
                                 bool control,
                                 bool shift,
                                 bool alt,
                                 bool command,
                                 const base::Closure& task) {
   CHECK(g_ui_controls_enabled);
   DCHECK(base::MessageLoopForUI::IsCurrent());
 
+  // we want to destroy the autoreleased event ASAP

[tapted, 2016/03/01 08:11:58]

Comments should all be complete sentences. Capitalize first letter, end in a
fullstop.

[themblsha, 2016/03/09 17:40:22]

Done.

+  base::mac::ScopedNSAutoreleasePool pool;
+
   std::vector<NSEvent*> events;
   SynthesizeKeyEventsSequence(
       window, key, control, shift, alt, command, &events);
 
+  if (!task.is_null()) {
+    base::scoped_nsobject<EventDeletedTaskRunner> task_runner =
+        [[EventDeletedTaskRunner alloc] initWithClosure:task];
+
+    // event will be deleted when the last event is deleted
+    for (std::vector<NSEvent*>::iterator iter = events.begin();

[tapted, 2016/03/01 08:11:58]

for (NSEvent* event : events)

+         iter != events.end(); ++iter)
+      objc_setAssociatedObject(*iter, &kEventDeletedTaskRunnerKey,
+                               task_runner.get(), OBJC_ASSOCIATION_RETAIN);
+  }
+
   // TODO(suzhe): Using [NSApplication postEvent:atStart:] here causes
   // BrowserKeyEventsTest.CommandKeyEvents to fail. See http://crbug.com/49270
   // But using [NSApplication sendEvent:] should be safe for keyboard events,
   // because until now, no code wants to retrieve the next event when handling
   // a keyboard event.
   for (std::vector<NSEvent*>::iterator iter = events.begin();
        iter != events.end(); ++iter)
     [[NSApplication sharedApplication] sendEvent:*iter];
 
-  if (!task.is_null()) {
-    base::MessageLoop::current()->PostTask(
-        FROM_HERE, base::Bind(&EventQueueWatcher, task));
-  }
-
   return true;
 }
 
 bool SendMouseMove(long x, long y) {
   CHECK(g_ui_controls_enabled);
   return SendMouseMoveNotifyWhenDone(x, y, base::Closure());
 }
 
 // Input position is in screen coordinates.  However, NSMouseMoved
 // events require them window-relative, so we adjust.  We *DO* flip
 // the coordinate space, so input events can be the same for all
 // platforms.  E.g. (0,0) is upper-left.
 bool SendMouseMoveNotifyWhenDone(long x, long y, const base::Closure& task) {
   CHECK(g_ui_controls_enabled);
-  CGFloat screenHeight =
-    [[[NSScreen screens] firstObject] frame].size.height;
-  g_mouse_location = NSMakePoint(x, screenHeight - y);  // flip!
+  g_mouse_location = gfx::ScreenPointToNSPoint(gfx::Point(x, y));  // flip!
+  ScopedNSEventSwizzler::Install();
 
   NSWindow* window = WindowAtCurrentMouseLocation();
 
   NSPoint pointInWindow = g_mouse_location;
   if (window)
     pointInWindow = [window convertScreenToBase:pointInWindow];
   NSTimeInterval timestamp = TimeIntervalSinceSystemStartup();
 
-  NSEvent* event =
-      [NSEvent mouseEventWithType:NSMouseMoved
-                         location:pointInWindow
-                    modifierFlags:0
-                        timestamp:timestamp
-                     windowNumber:[window windowNumber]
-                          context:nil
-                      eventNumber:0
-                       clickCount:0
-                         pressure:0.0];
-  [[NSApplication sharedApplication] postEvent:event atStart:NO];
+  NSEventType etype = NSMouseMoved;

[tapted, 2016/03/01 08:11:58]

etype -> event_type

[themblsha, 2016/03/09 17:40:22]

Done.

+  if (g_mouse_button_down[LEFT]) {
+    etype = NSLeftMouseDragged;
+  } else if (g_mouse_button_down[RIGHT]) {
+    etype = NSRightMouseDragged;
+  } else if (g_mouse_button_down[MIDDLE]) {
+    etype = NSOtherMouseDragged;
+  }
+
+  // we want to destroy the autoreleased event ASAP
+  base::mac::ScopedNSAutoreleasePool pool;
+
+  NSEvent* event = [NSEvent mouseEventWithType:etype
+                                      location:pointInWindow
+                                 modifierFlags:0
+                                     timestamp:timestamp
+                                  windowNumber:[window windowNumber]
+                                       context:nil
+                                   eventNumber:0
+                                    clickCount:0
+                                      pressure:0.0];
 
   if (!task.is_null()) {
-    base::MessageLoop::current()->PostTask(
-        FROM_HERE, base::Bind(&EventQueueWatcher, task));
+    base::scoped_nsobject<EventDeletedTaskRunner> task_runner =
+        [[EventDeletedTaskRunner alloc] initWithClosure:task];
+    objc_setAssociatedObject(event, &kEventDeletedTaskRunnerKey,
+                             task_runner.get(), OBJC_ASSOCIATION_RETAIN);
   }
 
+  [[NSApplication sharedApplication] postEvent:event atStart:NO];
+
   return true;
 }
 
 bool SendMouseEvents(MouseButton type, int state) {
   CHECK(g_ui_controls_enabled);
   return SendMouseEventsNotifyWhenDone(type, state, base::Closure());
 }
 
 bool SendMouseEventsNotifyWhenDone(MouseButton type, int state,
                                    const base::Closure& task) {
   CHECK(g_ui_controls_enabled);
   // On windows it appears state can be (UP|DOWN).  It is unclear if
   // that'll happen here but prepare for it just in case.
   if (state == (UP|DOWN)) {
     return (SendMouseEventsNotifyWhenDone(type, DOWN, base::Closure()) &&
             SendMouseEventsNotifyWhenDone(type, UP, task));
   }
   NSEventType etype = NSLeftMouseDown;
   if (type == LEFT) {
     if (state == UP) {
       etype = NSLeftMouseUp;
+      g_mouse_button_down[LEFT] = false;
     } else {
       etype = NSLeftMouseDown;
+      g_mouse_button_down[LEFT] = true;
     }
   } else if (type == MIDDLE) {
     if (state == UP) {
       etype = NSOtherMouseUp;
+      g_mouse_button_down[MIDDLE] = false;
     } else {
       etype = NSOtherMouseDown;
+      g_mouse_button_down[MIDDLE] = true;
     }
   } else if (type == RIGHT) {
     if (state == UP) {
       etype = NSRightMouseUp;
+      g_mouse_button_down[RIGHT] = false;
     } else {
       etype = NSRightMouseDown;
+      g_mouse_button_down[RIGHT] = true;

[tapted, 2016/03/01 08:11:58]

these can all be collapsed into

g_mouse_button_down[type] = state == DOWN;

after the if-else{}

[themblsha, 2016/03/09 17:40:22]

Done.

     }
   } else {
     return false;
   }
   NSWindow* window = WindowAtCurrentMouseLocation();
   NSPoint pointInWindow = g_mouse_location;
   if (window)
     pointInWindow = [window convertScreenToBase:pointInWindow];
 
+  ScopedNSEventSwizzler::Install();
+
+  // we want to destroy the autoreleased event ASAP
+  base::mac::ScopedNSAutoreleasePool pool;
+
   NSEvent* event =
       [NSEvent mouseEventWithType:etype
                          location:pointInWindow
                     modifierFlags:0
                         timestamp:TimeIntervalSinceSystemStartup()
                      windowNumber:[window windowNumber]
                           context:nil
                       eventNumber:0
                        clickCount:1
                          pressure:(state == DOWN ? 1.0 : 0.0 )];
-  [[NSApplication sharedApplication] postEvent:event atStart:NO];
 
   if (!task.is_null()) {
-    base::MessageLoop::current()->PostTask(
-        FROM_HERE, base::Bind(&EventQueueWatcher, task));
+    base::scoped_nsobject<EventDeletedTaskRunner> task_runner =
+        [[EventDeletedTaskRunner alloc] initWithClosure:task];
+    objc_setAssociatedObject(event, &kEventDeletedTaskRunnerKey,
+                             task_runner.get(), OBJC_ASSOCIATION_RETAIN);
   }
 
+  [[NSApplication sharedApplication] postEvent:event atStart:NO];
+
   return true;
 }
 
 bool SendMouseClick(MouseButton type) {
   CHECK(g_ui_controls_enabled);
   return SendMouseEventsNotifyWhenDone(type, UP|DOWN, base::Closure());
 }
 
 void RunClosureAfterAllPendingUIEvents(const base::Closure& closure) {
   base::MessageLoop::current()->PostTask(
       FROM_HERE, base::Bind(&EventQueueWatcher, closure));
 }
 
 bool IsFullKeyboardAccessEnabled() {
   return [NSApp isFullKeyboardAccessEnabled];
 }
 
 }  // namespace ui_controls