Allow WebRTC to require Mac 10.7 deployments in GN builds.

build/config/mac/mac_sdk.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 
+# See https://bugs.chromium.org/p/webrtc/issues/detail?id=5453.
+# We can drop the rtc_require_mac_10_7_deployment flag when Chromium
+# also requires a 10.7 deployment target.
+import("//build_overrides/webrtc.gni")

[brettw, 2016/02/16 22:46:46]

We're trying to make the build directory independent of any other directory.
You'll notice that the current //build directory has no references to
//build_overrides/*.

The //build directory is mirrored in
https://chromium.googlesource.com/chromium/src/build/
and can be DEPSed in by other projects (e.g. standalone V8, NaCl). However, the
//build_overrides directory is necessarily different for each such project. This
change will force each project to defined a file in their repository
"webrtc.gni" with this variable set, which I don't think we want.

This mac_deployment_target is already exposed as a build variable. Can you just
configure your bot to set it?

+
 declare_args() {
   # Minimum supported version of the Mac SDK.
   mac_sdk_min = "10.10"
 
   # Minimum supported version of OSX.
-  mac_deployment_target = "10.6"
+  if (rtc_require_mac_10_7_deployment) {
+    mac_deployment_target = "10.7"
+  } else {
+    mac_deployment_target = "10.6"
+  }
 
   # Path to a specific version of the Mac SDK, not including a backslash at
   # the end. If empty, the path to the lowest version greater than or equal to
   # mac_sdk_min is used.
   mac_sdk_path = ""
 }
 
 find_sdk_args = [ "--print_sdk_path" ]
 if (is_chrome_branded && is_official_build) {
   find_sdk_args += [
     "--verify",
     mac_sdk_min,
     "--sdk_path=" + mac_sdk_path,
   ]
 } else {
   find_sdk_args += [ mac_sdk_min ]
 }
 
 # The tool will print the SDK path on the first line, and the version on the
 # second line.
 find_sdk_lines =
     exec_script("//build/mac/find_sdk.py", find_sdk_args, "list lines")
 mac_sdk_version = find_sdk_lines[1]
 if (mac_sdk_path == "") {
   mac_sdk_path = find_sdk_lines[0]
 }