Android Add _incremental targets for instrumentation tests

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/toolchain/toolchain.gni")
 import("//third_party/android_platform/config.gni")
@@ skipping 1183 matching lines @@
 #   create_dist_ijar: Whether to define the "${target_name}_dist_ijar" target
 #     (used by instrumentation_test_apk).
 #   data_deps: List of dependencies needed at runtime. These will be built but
 #     won't change the generated .apk in any way (in fact they may be built
 #     after the .apk is).
 #   deps: List of dependencies. All Android java resources and libraries in the
 #     "transitive closure" of these dependencies will be included in the apk.
 #     Note: this "transitive closure" actually only includes such targets if
 #     they are depended on through android_library or android_resources targets
 #     (and so not through builtin targets like 'action', 'group', etc).
+#   install_script_name: Name of wrapper script (default=target_name).
 #   java_files: List of .java files to include in the apk.
 #   srcjar_deps: List of srcjar dependencies. The .java files in the srcjars
 #      will be added to java_files and be included in this apk.
 #   apk_name: Name for final apk.
 #   final_apk_path: Path to final built apk. Default is
 #     $root_out_dir/apks/$apk_name.apk. Setting this will override apk_name.
 #   loadable_modules: List of paths to native libraries to include. Different
 #     from |native_libs| in that:
 #       * dependencies of this .so are not automatically included
 #       * ".cr.so" is never added
@@ skipping 69 matching lines @@
     _final_apk_path = invoker.final_apk_path
   } else if (defined(invoker.apk_name)) {
     _final_apk_path = "$root_build_dir/apks/" + invoker.apk_name + ".apk"
   }
   _final_apk_path_no_ext_list =
       process_file_template([ _final_apk_path ],
                             "{{source_dir}}/{{source_name_part}}")
   _final_apk_path_no_ext = _final_apk_path_no_ext_list[0]
   assert(_final_apk_path_no_ext != "")  # Mark as used.
 
+  _install_script_name = "install_$_template_name"
+  if (defined(invoker.install_script_name)) {
+    _install_script_name = invoker.install_script_name
+  }
+  _incremental_install_script_path =
+      "${root_out_dir}/bin/${_install_script_name}_incremental"
+
   _native_libs = []
 
   _version_code = android_default_version_code
   if (defined(invoker.version_code)) {
     _version_code = invoker.version_code
   }
 
   _version_name = android_default_version_name
   if (defined(invoker.version_name)) {
     _version_name = invoker.version_name
@@ skipping 80 matching lines @@
 
   _emma_never_instrument = defined(invoker.testonly) && invoker.testonly
 
   build_config_target = "${_template_name}__build_config"
   write_build_config(build_config_target) {
     forward_variables_from(invoker, [ "apk_under_test" ])
     type = "android_apk"
     jar_path = _jar_path
     dex_path = final_dex_path
     apk_path = _final_apk_path
+    incremental_apk_path = "${_final_apk_path_no_ext}_incremental.apk"
+    incremental_install_script_path = _incremental_install_script_path
     resources_zip = resources_zip_path
     build_config = _build_config
     android_manifest = _android_manifest
 
     deps = _native_libs_deps + _android_manifest_deps
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
 
     if (defined(invoker.alternative_locale_resource_dep)) {
@@ skipping 412 matching lines @@
   }
 
   _create_incremental_script_rule_name = "${_template_name}__incremental_script"
   action(_create_incremental_script_rule_name) {
     script = "//build/android/incremental_install/create_install_script.py"
     depfile = "$target_gen_dir/$target_name.d"
     deps = [
       _native_libs_file_arg_dep,
     ]
 
-    _generated_script_path =
-        "${root_out_dir}/bin/install_${_template_name}_incremental"
     outputs = [
       depfile,
-      _generated_script_path,
+      _incremental_install_script_path,
     ]
 
     _rebased_apk_path_no_ext =
         rebase_path(_final_apk_path_no_ext, root_build_dir)
-    _rebased_generated_script_path =
-        rebase_path(_generated_script_path, root_build_dir)
+    _rebased_incremental_install_script_path =
+        rebase_path(_incremental_install_script_path, root_build_dir)
     _rebased_depfile = rebase_path(depfile, root_build_dir)
     _dex_arg_key = "${_rebased_build_config}:final_dex:dependency_dex_files"
     args = [
       "--apk-path=${_rebased_apk_path_no_ext}_incremental.apk",
-      "--script-output-path=$_rebased_generated_script_path",
+      "--script-output-path=$_rebased_incremental_install_script_path",
       "--dex-file=$_rebased_lib_dex_path",
       "--dex-file-list=@FileArg($_dex_arg_key)",
       "--depfile=$_rebased_depfile",
     ]
     if (_proguard_enabled) {
       args += [ "--show-proguard-warning" ]
     }
     if (defined(_native_libs_file_arg)) {
       args += [ "--native-libs=$_native_libs_file_arg" ]
     }
@@ skipping 75 matching lines @@
 #       "android/org/chromium/foo/FooExampleTest.java",
 #     ]
 #     deps = [
 #       ":foo_test_support_java"
 #     ]
 #   }
 template("instrumentation_test_apk") {
   testonly = true
   _apk_target_name = "${target_name}__apk"
   _test_runner_target_name = "${target_name}__test_runner_script"
+  _install_script_name = "install_$target_name"
 
   test_runner_script(_test_runner_target_name) {
     forward_variables_from(invoker,
                            [
                              "additional_apks",
+                             "apk_under_test",
                              "isolate_file",
                            ])
     test_name = invoker.target_name
     test_type = "instrumentation"
     apk_target = ":$_apk_target_name"
   }
 
+  test_runner_script("${_test_runner_target_name}_incremental") {
+    forward_variables_from(invoker,
+                           [
+                             "additional_apks",
+                             "apk_under_test",
+                             "isolate_file",
+                           ])
+    test_name = "${invoker.target_name}_incremental"
+    test_type = "instrumentation"
+    apk_target = ":$_apk_target_name"
+    incremental_install = true
+  }
+
   android_apk(_apk_target_name) {
     deps = []
     data_deps = []
     forward_variables_from(invoker, "*")
+    install_script_name = _install_script_name
     deps += [ "//testing/android/broker:broker_java" ]
     data_deps += [
       "//testing/android/driver:driver_apk",
       "//tools/android/forwarder2",
       "//tools/android/md5sum",
     ]
     if (defined(invoker.additional_apks)) {
       data_deps += invoker.additional_apks
     }
 
     create_dist_ijar = true
     run_findbugs =
         defined(invoker.run_findbugs) && invoker.run_findbugs &&
         (defined(invoker.java_files) || defined(invoker.DEPRECATED_java_in_dir))
   }
 
   group(target_name) {
     public_deps = [
       ":$_apk_target_name",
       ":$_test_runner_target_name",
 
       # Required by test runner to enumerate test list.
       ":${_apk_target_name}_dist_ijar",
     ]
   }
+  group("${target_name}_incremental") {
+    public_deps = [
+      ":${_apk_target_name}_dist_ijar",
+      ":${_apk_target_name}_incremental",
+      ":${_test_runner_target_name}_incremental",
+      "${invoker.apk_under_test}_incremental",
+    ]
+  }
 }
 
 # Declare an Android gtest apk
 #
 # This target creates an Android apk for running gtest-based unittests.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. These will be passed to
 #     the underlying android_apk invocation and should include the java and
 #     resource dependencies of the apk.
@@ skipping 297 matching lines @@
   }
 
   android_library(target_name) {
     java_files = []
     srcjar_deps = [ ":${_template_name}__protoc_java" ]
     deps = [
       "//third_party/android_protobuf:protobuf_nano_javalib",
     ]
   }
 }