Allocator shim skeleton + Linux impl behind a build flag

base/allocator/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/buildflag_header.gni")
 import("//build/config/allocator.gni")
 import("//build/config/compiler/compiler.gni")
 
 if (is_win) {
   import("//build/config/win/visual_studio_version.gni")
 }
 
 declare_args() {
   # Provide a way to force disable debugallocation in Debug builds,
   # e.g. for profiling (it's more rare to profile Debug builds,
@@ skipping 272 matching lines @@
     # Make sure the allocation library is optimized as much as possible when
     # we"re in release mode.
     if (!is_debug) {
       configs -= [ "//build/config/compiler:default_optimization" ]
       configs += [ "//build/config/compiler:optimize_max" ]
     }
 
     deps += [ "//base/third_party/dynamic_annotations" ]
   }
 }  # use_allocator == "tcmalloc"
+
+buildflag_header("features") {
+  header = "features.h"
+  flags = [ "USE_EXPERIMENTAL_ALLOCATOR_SHIM=$use_experimental_allocator_shim" ]
+}
+
+if (use_experimental_allocator_shim) {
+  source_set("unified_allocator_shim") {
+    # TODO(primiano): support other platforms, currently this works only on
+    # Linux/CrOS only. http://crbug.com/550886 .

[Nico, 2016/03/08 03:08:42]

remove one of the two "only"

[Primiano Tucci (use gerrit), 2016/03/08 20:54:05]

But it was so symmetric :)
Done.

+    configs += [ "//base:base_implementation" ]  # for BASE_EXPORT

[Nico, 2016/03/08 03:08:41]

give this

    visibility = [ ":base" ]

too, to make it harder to misuse this. (else, e.g. //ui/gfx might accidentally
add an explicit dep on this target and then it'll export base symbols. gyp
doesn't have a protection against this type of mistake)

[Primiano Tucci (use gerrit), 2016/03/08 20:54:04]

TIL visibility in GN. Done.

+    sources = [
+      "allocator_shim.cc",
+      "allocator_shim.h",
+      "allocator_shim_internals.h",
+      "allocator_shim_override_cpp_symbols.h",
+      "allocator_shim_override_libc_symbols.h",
+    ]
+    if (is_linux && use_allocator == "tcmalloc") {
+      sources += [
+        "allocator_shim_default_dispatch_to_tcmalloc.cc",
+        "allocator_shim_override_glibc_weak_symbols.h",
+      ]
+      deps = [
+        ":tcmalloc",
+      ]
+    } else if (is_linux && use_allocator == "none") {
+      sources += [ "allocator_shim_default_dispatch_to_glibc.cc" ]
+    }
+  }
+}