C++->Java string constants auto-generator

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/toolchain/toolchain.gni")
 import("//third_party/android_platform/config.gni")
@@ skipping 349 matching lines @@
              rebase_path(depfile, root_build_dir),
              "--srcjar=$_rebased_srcjar_path",
            ] + _rebased_sources
     outputs = [
       depfile,
       _srcjar_path,
     ]
   }
 }
 
+# Declare a target for generating Java classes from C++ strings.
+#
+# This target generates Java files from C++ strings using a script.
+#
+# This target will create a single .srcjar. Adding this target to an
+# android_library target's srcjar_deps will make the generated java files be
+# included in that library's final outputs.
+#
+# Variables
+#   sources: list of files to be processed by the script. For each source
+#     file the script will generate a .java file including all the strings
+#     in the source file with the name indicated in the derectives.
+#
+# Example
+#   java_cpp_string("foo_generated_string") {
+#     sources = [
+#       "src/native_foo.cc",
+#     ]
+#   }
+template("java_cpp_string") {
+  action(target_name) {
+    # The sources aren't compiled so don't check their dependencies.
+    check_includes = false
+    set_sources_assignment_filter([])
+
+    assert(defined(invoker.sources))
+    forward_variables_from(invoker,
+                           [
+                             "sources",
+                             "testonly",
+                             "visibility",
+                           ])
+
+    script = "//build/android/gyp/java_cpp_string.py"
+    depfile = "$target_gen_dir/$target_name.d"
+
+    _srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
+    _rebased_srcjar_path = rebase_path(_srcjar_path, root_build_dir)
+    _rebased_sources = rebase_path(invoker.sources, root_build_dir)
+
+    args = [
+             "--depfile",
+             rebase_path(depfile, root_build_dir),
+             "--srcjar=$_rebased_srcjar_path",
+           ] + _rebased_sources
+    outputs = [
+      depfile,
+      _srcjar_path,
+    ]
+  }
+}
+
 # Declare a target for processing a Jinja template.
 #
 # Variables
 #   input: The template file to be processed.
 #   output: Where to save the result.
 #   variables: (Optional) A list of variables to make available to the template
 #     processing environment, e.g. ["name=foo", "color=red"].
 #
 # Example
 #   jinja_template("chrome_public_manifest") {
@@ skipping 1903 matching lines @@
   }
 
   android_library(target_name) {
     java_files = []
     srcjar_deps = [ ":${_template_name}__protoc_java" ]
     deps = [
       "//third_party/android_protobuf:protobuf_nano_javalib",
     ]
   }
 }