Mac: make save/open dialogs operate as tab-modal sheets....

chrome/browser/cocoa/bookmark_bar_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "app/l10n_util_mac.h"
 #include "app/resource_bundle.h"
 #include "base/mac_util.h"
 #include "base/nsimage_cache_mac.h"
 #include "base/sys_string_conversions.h"
+#include "chrome/app/chrome_dll_resource.h"  // IDC_*
 #include "chrome/browser/bookmarks/bookmark_editor.h"
 #include "chrome/browser/bookmarks/bookmark_model.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_list.h"
 #import "chrome/browser/cocoa/bookmark_bar_bridge.h"
 #import "chrome/browser/cocoa/bookmark_bar_controller.h"
 #import "chrome/browser/cocoa/bookmark_bar_view.h"
 #import "chrome/browser/cocoa/bookmark_button_cell.h"
 #import "chrome/browser/cocoa/bookmark_editor_controller.h"
 #import "chrome/browser/cocoa/bookmark_name_folder_controller.h"
@@ skipping 22 matching lines @@
 @end
 
 @interface BookmarkBarController(Private)
 - (void)applyContentAreaOffset:(BOOL)apply immediately:(BOOL)immediately;
 - (void)showBookmarkBar:(BOOL)enable immediately:(BOOL)immediately;
 - (void)addNode:(const BookmarkNode*)child toMenu:(NSMenu*)menu;
 - (void)addFolderNode:(const BookmarkNode*)node toMenu:(NSMenu*)menu;
 - (void)tagEmptyMenu:(NSMenu*)menu;
 - (void)clearMenuTagMap;
 - (int)preferredHeight;
+- (void)greyOutBookmarkBar:(BOOL)doGreyOut;
 @end
 
 namespace {
 
 // Our height, when opened in "always visible" mode.
 const int kBookmarkBarHeight = 28;
 
 // Our height, when visible in "new tab page" mode.
 const int kNTPBookmarkBarHeight = 40;
 
 // Magic numbers from Cole
 const CGFloat kDefaultBookmarkWidth = 150.0;
 const CGFloat kBookmarkVerticalPadding = 2.0;
 const CGFloat kBookmarkHorizontalPadding = 1.0;
 
 }  // namespace
 
 @implementation BookmarkBarController
 
 - (id)initWithBrowser:(Browser*)browser
          initialWidth:(float)initialWidth
      compressDelegate:(id<ToolbarCompressable>)compressDelegate
        resizeDelegate:(id<ViewResizer>)resizeDelegate
-          urlDelegate:(id<BookmarkURLOpener>)urlDelegate {
+          urlDelegate:(id<BookmarkURLOpener>)urlDelegate
+             commands:(CommandUpdater*)commands {
   if ((self = [super initWithNibName:@"BookmarkBar"
                               bundle:mac_util::MainAppBundle()])) {
     browser_ = browser;
     initialWidth_ = initialWidth;
     bookmarkModel_ = browser_->profile()->GetBookmarkModel();
     buttons_.reset([[NSMutableArray alloc] init]);
     compressDelegate_ = compressDelegate;
     resizeDelegate_ = resizeDelegate;
     urlDelegate_ = urlDelegate;
     tabObserver_.reset(
         new TabStripModelObserverBridge(browser_->tabstrip_model(), self));
 
     ResourceBundle& rb = ResourceBundle::GetSharedInstance();
     folderImage_.reset([rb.GetNSImageNamed(IDR_BOOKMARK_BAR_FOLDER) retain]);
+
+    // We grey out if |IDC_BOOKMARK_MENU_CONTENTS| is disabled. Note that the
+    // unit tests don't provide a |CommandUpdater|.
+    if (commands) {
+      commandObserver_.reset(new CommandObserverBridge(self, commands));
+      commandObserver_->ObserveCommand(IDC_BOOKMARK_MENU_CONTENTS);
+    }
   }
   return self;
 }
 
 - (void)dealloc {
   bridge_.reset(NULL);
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [super dealloc];
 }
 
@@ skipping 159 matching lines @@
 }
 
 - (void)tabChangedWithContents:(TabContents*)contents
                        atIndex:(NSInteger)index
                    loadingOnly:(BOOL)loading {
   // We need tabChangedWithContents: for when the user clicks a bookmark from
   // the bookmark bar on the new tab page.
   [self updateVisibility];
 }
 
+// Possibly (un)grey out the bookmark bar (i.e., enable/disable its buttons).
+// Needed for tab-modal sheets.
+- (void)greyOutBookmarkBar:(BOOL)doGreyOut {
+  if (barIsGreyedOut_ == doGreyOut)
+    return;
+
+  barIsGreyedOut_ = doGreyOut;
+  for (NSButton* each_button in buttons_.get())
+    [each_button setEnabled:!doGreyOut];
+  [offTheSideButton_ setEnabled:!doGreyOut];
+}
+
+// Called for state changes in commands (we're only interested in
+// |IDC_BOOKMARK_MENU_CONTENTS|); part (all) of the |CommandObserverProtocol|.
+- (void)enabledStateChangedForCommand:(NSInteger)command enabled:(BOOL)enabled {
+  if (command == IDC_BOOKMARK_MENU_CONTENTS) {
+    [self greyOutBookmarkBar:!enabled];
+  } else {
+    NOTREACHED() << "Got state change for command we didn't ask to observe.";
+  }
+}
+
 // Recursively add the given bookmark node and all its children to
 // menu, one menu item per node.
 - (void)addNode:(const BookmarkNode*)child toMenu:(NSMenu*)menu {
   NSString* title = [BookmarkMenuCocoaController menuTitleForNode:child];
   NSMenuItem* item = [[[NSMenuItem alloc] initWithTitle:title
                                                  action:nil
                                           keyEquivalent:@""] autorelease];
   [menu addItem:item];
   if (child->is_folder()) {
     NSMenu* submenu = [[[NSMenu alloc] initWithTitle:title] autorelease];
@@ skipping 444 matching lines @@
 
 - (void)setUrlDelegate:(id<BookmarkURLOpener>)urlDelegate {
   urlDelegate_ = urlDelegate;
 }
 
 - (NSArray*)buttons {
   return buttons_.get();
 }
 
 @end