Mac: autocomplete popup size and shape mirrors star/go buttons.

chrome/browser/autocomplete/autocomplete_popup_view_mac.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/autocomplete/autocomplete_popup_view_mac.h"
 
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/autocomplete/autocomplete_edit.h"
 #include "chrome/browser/autocomplete/autocomplete_edit_view_mac.h"
 #include "chrome/browser/autocomplete/autocomplete_popup_model.h"
 #include "chrome/browser/cocoa/nsimage_cache.h"
 
 namespace {
 
+// How to round off the popup's corners.  Goal is to match star and go
+// buttons.
+const CGFloat kPopupRoundingRadius = 4.0;
+
+// How far to offset the image column from the left.
+const CGFloat kImageXOffset = 8.0;
+
+// How far to offset the text column from the left.
+const CGFloat kTextXOffset = 33.0;
+
 // Background colors for different states of the popup elements.
 NSColor* BackgroundColor() {
   return [NSColor controlBackgroundColor];
 }
 NSColor* SelectedBackgroundColor() {
   return [NSColor selectedControlColor];
 }
 NSColor* HoveredBackgroundColor() {
   return [NSColor controlColor];
 }
@@ skipping 200 matching lines @@
   return [popup_ isVisible] ? true : false;
 }
 
 void AutocompletePopupViewMac::CreatePopupIfNeeded() {
   if (!popup_) {
     popup_.reset([[NSWindow alloc] initWithContentRect:NSZeroRect
                                              styleMask:NSBorderlessWindowMask
                                                backing:NSBackingStoreBuffered
                                                  defer:YES]);
     [popup_ setMovableByWindowBackground:NO];
-    [popup_ setOpaque:YES];
-    [popup_ setHasShadow:YES];
+    // The window will have rounded borders.
+    [popup_ setAlphaValue:1.0];
+    [popup_ setOpaque:NO];
     [popup_ setLevel:NSNormalWindowLevel];
 
     AutocompleteMatrix* matrix =
         [[[AutocompleteMatrix alloc] initWithFrame:NSZeroRect] autorelease];
     [matrix setTarget:matrix_target_];
     [matrix setAction:@selector(select:)];
     [popup_ setContentView:matrix];
   }
 }
 
@@ skipping 25 matching lines @@
     [cell setImage:MatchIcon(match)];
     [cell setAttributedTitle:MatchText(match, [field_ font])];
   }
 
   // Layout the popup and size it to land underneath the field.
   // TODO(shess) Consider refactoring to remove this depenency,
   // because the popup doesn't need any of the field-like aspects of
   // field_.  The edit view could expose helper methods for attaching
   // the window to the field.
 
-  // Locate |field_| on the screen.
+  // Locate |field_| on the screen, and pad the left and right sides
+  // by the height to make it wide enough to include the star and go
+  // buttons.
+  // TODO(shess): This assumes that those buttons will be square.
+  // Better to plumb through so that this code can get the rect from
+  // the toolbar controller?
   NSRect r = [field_ convertRect:[field_ bounds] toView:nil];
+  r.origin.x -= r.size.height;
+  r.size.width += 2 * r.size.height;
   r.origin = [[field_ window] convertBaseToScreen:r.origin];
   DCHECK_GT(r.size.width, 0.0);
 
   // Set the cell size to fit a line of text in the cell's font.  All
   // cells should use the same font and each should layout in one
   // line, so they should all be about the same height.
   const NSSize cellSize = [[matrix cellAtRow:0 column:0] cellSize];
   DCHECK_GT(cellSize.height, 0.0);
   [matrix setCellSize:NSMakeSize(r.size.width, cellSize.height)];
 
@@ skipping 56 matching lines @@
 
 - (NSColor*)backgroundColor {
   if ([self state] == NSOnState) {
     return SelectedBackgroundColor();
   } else if ([self isHighlighted]) {
     return HoveredBackgroundColor();
   }
   return BackgroundColor();
 }
 
+// The default NSButtonCell drawing leaves the image flush left and
+// the title next to the image.  This spaces things out to line up
+// with the star button and autocomplete field.
+// TODO(shess): Determine if the star button can change size (other
+// than scaling coordinates), in which case this needs to be more
+// dynamic.
+- (void)drawInteriorWithFrame:(NSRect)cellFrame inView:(NSView *)controlView {
+  [[self backgroundColor] set];
+  NSRectFill(cellFrame);
+
+  // Put the image centered vertically but in a fixed column.
+  // TODO(shess) Currently, the images are all 16x16 png files, so
+  // left-justified works out fine.  If that changes, it may be
+  // appropriate to align them on their centers instead of their
+  // left-hand sides.
+  NSImage* image = [self image];
+  if (image) {
+    NSRect imageRect = cellFrame;
+    imageRect.size = [image size];
+    imageRect.origin.y +=
+        floor((NSHeight(cellFrame) - NSHeight(imageRect)) / 2);
+    imageRect.origin.x += kImageXOffset;
+    [self drawImage:image withFrame:imageRect inView:controlView];
+  }
+
+  // Adjust the title position to be lined up under the field's text.
+  NSAttributedString* title = [self attributedTitle];
+  if (title) {
+    NSRect titleRect = cellFrame;
+    titleRect.size.width -= kTextXOffset;
+    titleRect.origin.x += kTextXOffset;
+    [self drawTitle:title withFrame:titleRect inView:controlView];
+  }
+}
+
 @end
 
 @implementation AutocompleteMatrix
 
 // Remove all tracking areas and initialize the one we want.  Removing
 // all might be overkill, but it's unclear why there would be others
 // for the popup window.
 - (void)resetTrackingArea {
   for (NSTrackingArea* trackingArea in [self trackingAreas]) {
     [self removeTrackingArea:trackingArea];
@@ skipping 61 matching lines @@
 - (void)mouseEntered:(NSEvent*)theEvent {
   [self highlightRowUnder:theEvent];
 }
 - (void)mouseMoved:(NSEvent*)theEvent {
   [self highlightRowUnder:theEvent];
 }
 - (void)mouseExited:(NSEvent*)theEvent {
   [self highlightRowAt:-1];
 }
 
+// This handles drawing the decorations of the rounded popup window,
+// calling on NSMatrix to draw the actual contents.
+- (void)drawRect:(NSRect)rect {
+  // Background clear so we can round the corners.
+  [[NSColor clearColor] set];
+  NSRectFill([self frame]);
+
+  // The toolbar items we're mirroring for shape are inset slightly
+  // for width.  I don't know why, which is why I didn't make this a
+  // constant, yet.  The factor of 0.5 on both dimensions is to put
+  // the stroke down the middle of the pixels.
+  const NSRect border(NSInsetRect([self bounds], 1.5, 0.5));
+  NSBezierPath* path =
+      [NSBezierPath bezierPathWithRoundedRect:border
+                                      xRadius:kPopupRoundingRadius
+                                      yRadius:kPopupRoundingRadius];
+
+  // Draw the matrix clipped to our border.
+  [NSGraphicsContext saveGraphicsState];
+  [path addClip];
+  [super drawRect:rect];
+  [NSGraphicsContext restoreGraphicsState];
+
+  // Put a border over that.
+  // TODO(shess): Theme the color?
+  [[NSColor lightGrayColor] setStroke];
+  [path setLineWidth:1.0];
+  [path stroke];
+}
+
 @end
 
 @implementation AutocompleteMatrixTarget
 
 - initWithPopupView:(AutocompletePopupViewMac*)view {
   self = [super init];
   if (self) {
     popup_view_ = view;
   }
   return self;
 }
 
 - (void)select:sender {
   DCHECK(popup_view_);
   popup_view_->AcceptInput();
 }
 
 @end