[GN][Chromecast] Add "-Wl,-rpath=\$ORIGIN" to executable and shlib defaults.

build/config/chromecast/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chromecast_build.gni")
 
 assert(is_chromecast)
 
 config("static_config") {
   ldflags = [
     # We want to statically link libstdc++/libgcc.
     "-static-libstdc++",
     "-static-libgcc",
 
     # Don't allow visible symbols from libraries that contain
     # assembly code with symbols that aren't hidden properly.
     # http://b/26390825
     "-Wl,--exclude-libs=libffmpeg.a",
   ]
 }
 
+config("ldconfig") {
+  visibility = [ ":*" ]
+
+  # Chromecast executables depend on several shared libraries in $ORIGIN. Add
+  # $ORIGIN to the rpath of these executables. This is not inherited by default
+  # when depending on these targets for security reasons (see comments in
+  # //build/config/gcc/BUILD.gn)
+  configs = [ "//build/config/gcc:rpath_for_built_shared_libraries" ]
+}
+
 config("executable_config") {
+  configs = [ ":ldconfig" ]
+
   if (current_cpu == "arm") {
     ldflags = [
       # Export stdlibc++ and libgcc symbols to force shlibs to refer to these
       # symbols from the executable.
       "-Wl,--export-dynamic",
 
       "-lm",  # stdlibc++ requires math.h
 
       # In case we redefined stdlibc++ symbols (e.g. tc_malloc)
       "-Wl,--allow-multiple-definition",
 
       "-Wl,--whole-archive",
       "-l:libstdc++.a",
       "-l:libgcc.a",
       "-Wl,--no-whole-archive",
     ]
 
     # Despite including libstdc++/libgcc archives, we still need to specify
     # static linking for them in order to prevent the executable from having a
     # dynamic dependency on them.
-    configs = [ ":static_config" ]
+    configs += [ ":static_config" ]
   }
 }
 
 config("shared_library_config") {
+  configs = [ ":ldconfig" ]
   if (current_cpu == "arm") {
-    configs = [ ":static_config" ]
+    configs += [ ":static_config" ]
   }
 }