Make the favicons look visually the same after refreshing

ui/gfx/image/image_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ui/gfx/image/image.h"
 
 #import <AppKit/AppKit.h>
 
 #include "base/logging.h"
 #include "base/memory/scoped_nsobject.h"
@@ skipping 30 matching lines @@
   NSData* ns_data = [ns_bitmap representationUsingType:NSPNGFileType
                                             properties:nil];
   const unsigned char* bytes =
       static_cast<const unsigned char*>([ns_data bytes]);
   scoped_refptr<base::RefCountedBytes> refcounted_bytes(
       new base::RefCountedBytes());
   refcounted_bytes->data().assign(bytes, bytes + [ns_data length]);
   return refcounted_bytes;
 }
 
-NSImage* NSImageFromPNG(const std::vector<gfx::ImagePNGRep>& image_png_reps) {
+NSImage* NSImageFromPNG(const std::vector<gfx::ImagePNGRep>& image_png_reps,
+                        CGColorSpaceRef color_space) {
   if (image_png_reps.empty()) {
     LOG(ERROR) << "Unable to decode PNG.";
     return GetErrorNSImage();
   }
 
   scoped_nsobject<NSImage> image;
   for (size_t i = 0; i < image_png_reps.size(); ++i) {
     scoped_refptr<base::RefCountedMemory> png = image_png_reps[i].raw_data;
     CHECK(png.get());
     scoped_nsobject<NSData> ns_data(
         [[NSData alloc] initWithBytes:png->front() length:png->size()]);
     scoped_nsobject<NSBitmapImageRep> ns_image_rep(
         [[NSBitmapImageRep alloc] initWithData:ns_data]);
     if (!ns_image_rep) {
       LOG(ERROR) << "Unable to decode PNG at "
                  << ui::GetScaleFactorScale(image_png_reps[i].scale_factor)
                  << ".";
       return GetErrorNSImage();
     }
 
+    // PNGCodec ignores colorspace related ancillary chunks (sRGB, iCCP). Ignore
+    // colorspace information when decoding directly from PNG to an NSImage so
+    // that the conversions: PNG -> SkBitmap -> NSImage and PNG -> NSImage
+    // produce visually similar results.
+    CGColorSpaceModel color_space_model = CGColorSpaceGetModel(
+        [[ns_image_rep colorSpace] CGColorSpace]);
+    CGColorSpaceModel decoded_color_space_model =
+        CGColorSpaceGetModel(color_space);
+    if (color_space_model == decoded_color_space_model) {
+      scoped_nsobject<NSColorSpace> ns_color_space(
+          [[NSColorSpace alloc] initWithCGColorSpace: color_space]);

[Avi (use Gerrit), 2013/06/12 01:35:29]

drive by: no space after the colon

+      NSBitmapImageRep* ns_retagged_image_rep =
+          [ns_image_rep
+              bitmapImageRepByRetaggingWithColorSpace: ns_color_space];

[Avi (use Gerrit), 2013/06/12 01:35:29]

drive by: no space after the colon

+      if (ns_retagged_image_rep && ns_retagged_image_rep != ns_image_rep) {
+        [ns_retagged_image_rep retain];

[pkotwicz, 2013/06/12 01:26:19]

I am confused why I need to retain |ns_retagged_image_rep|. (I get a crash if I
do not retain it)

[Avi (use Gerrit), 2013/06/12 01:35:29]

It comes from -bitmapImageRepByRetaggingWithColorSpace:, so it is autoreleased,
which means it has an effective retain count of 0. ns_image_rep is a
scoped_nsobject, which assumes that you are giving it a retained object, and
when it goes out of scope it will release it. So if you don't retain
ns_retagged_image_rep here, it gets released when ns_image_rep goes out of
scope, and then is released again when the autorelease pool goes away and you
die.

Style-wise, move the retain into the line below:

ns_image_rep.reset([ns_retagged_image_rep retain]);

+        ns_image_rep.reset(ns_retagged_image_rep);
+      }
+    }
+
     if (!image.get()) {
       float scale = ui::GetScaleFactorScale(image_png_reps[i].scale_factor);
       NSSize image_size = NSMakeSize([ns_image_rep pixelsWide] / scale,
                                      [ns_image_rep pixelsHigh] / scale);
       image.reset([[NSImage alloc] initWithSize:image_size]);
     }
     [image addRepresentation:ns_image_rep];
   }
 
   return image.release();
 }
 
 gfx::Size NSImageSize(NSImage* image) {
   NSSize size = [image size];
   int width = static_cast<int>(size.width);
   int height = static_cast<int>(size.height);
   return gfx::Size(width, height);
 }
 
 } // namespace internal
 } // namespace gfx