MacViews: Add native drop shadow to dialogs on OSX < 10.10.

ui/views/cocoa/bridged_content_view.mm

Index: ui/views/cocoa/bridged_content_view.mm
diff --git a/ui/views/cocoa/bridged_content_view.mm b/ui/views/cocoa/bridged_content_view.mm
index 56e53abe4eaf4e947ae921953083f16ada4f8924..deb211faa5e3675d76b1315b5961e800bff87350 100644
--- a/ui/views/cocoa/bridged_content_view.mm
+++ b/ui/views/cocoa/bridged_content_view.mm
@@ -5,6 +5,7 @@
 #import "ui/views/cocoa/bridged_content_view.h"
 
 #include "base/logging.h"
+#import "base/mac/mac_util.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "skia/ext/skia_utils_mac.h"
@@ -16,6 +17,9 @@
 #import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #include "ui/gfx/canvas_paint_mac.h"
 #include "ui/gfx/geometry/rect.h"
+#include "ui/gfx/path.h"
+#import "ui/gfx/path_mac.h"
+#include "ui/gfx/scoped_ns_graphics_context_save_gstate_mac.h"
 #include "ui/strings/grit/ui_strings.h"
 #include "ui/views/controls/menu/menu_config.h"
 #include "ui/views/controls/menu/menu_controller.h"
@@ -26,6 +30,17 @@ using views::MenuController;
 
 namespace {
 
+// Returns true if all four corners of |rect| are contained inside |path|.
+bool IsRectInsidePath(NSRect rect, NSBezierPath* path) {
+  return [path containsPoint:rect.origin] &&
+         [path containsPoint:NSMakePoint(rect.origin.x + rect.size.width,
+                                         rect.origin.y)] &&
+         [path containsPoint:NSMakePoint(rect.origin.x,
+                                         rect.origin.y + rect.size.height)] &&
+         [path containsPoint:NSMakePoint(rect.origin.x + rect.size.width,
+                                         rect.origin.y + rect.size.height)];
+}
+
 // Convert a |point| in |source_window|'s AppKit coordinate system (origin at
 // the bottom left of the window) to |target_window|'s content rect, with the
 // origin at the top left of the content area.
@@ -117,6 +132,20 @@ bool DispatchEventToMenu(views::Widget* widget, ui::KeyboardCode key_code) {
                owner:self
             userInfo:nil]);
     [self addTrackingArea:cursorTrackingArea_.get()];
+
+    // Get Notified whenever the view bounds or frame change.

[tapted, 2016/02/05 04:51:07]

We should just be able to hook in via BridgedNativeWidget::OnSizeChanged(..) --
the view should be resized by then, and not yet drawn.

You can use [window_ inLiveResize] there decide whether or not to do `stuff`

[karandeepb, 2016/02/08 07:47:09]

Done.

+    [self setPostsBoundsChangedNotifications:YES];
+    [self setPostsFrameChangedNotifications:YES];
+    [[NSNotificationCenter defaultCenter]
+        addObserver:self
+           selector:@selector(boundsDidChangeNotification:)
+               name:NSViewBoundsDidChangeNotification
+             object:self];
+    [[NSNotificationCenter defaultCenter]
+        addObserver:self
+           selector:@selector(boundsDidChangeNotification:)
+               name:NSViewFrameDidChangeNotification
+             object:self];
   }
   return self;
 }
@@ -306,6 +335,15 @@ bool DispatchEventToMenu(views::Widget* widget, ui::KeyboardCode key_code) {
   hostedView_->SetSize(gfx::Size(newSize.width, newSize.height));
 }
 
+- (void)viewDidEndLiveResize {
+  // We prevent updating the window mask and clipping the border around the
+  // view, during a live resize. Hence update the window mask and redraw the
+  // view after resize has completed.
+  [super viewDidEndLiveResize];
+  [self setWindowMask];
+  [self setNeedsDisplay:YES];

[tapted, 2016/02/05 04:51:07]

should this go at the end of setWindowMask?

[karandeepb, 2016/02/08 07:47:09]

Don't think so. Whenever we set the window mask i.e whenever the bounds change,
Cocoa should have itself called setNeedsDisplay on the view. We only set it here
explicitly since we had suppressed drawing during live resize.

[tapted, 2016/02/09 06:47:12]

Acknowledged.

+}
+
 - (void)drawRect:(NSRect)dirtyRect {
   // Note that BridgedNativeWidget uses -[NSWindow setAutodisplay:NO] to
   // suppress calls to this when the window is known to be hidden.
@@ -320,6 +358,31 @@ bool DispatchEventToMenu(views::Widget* widget, ui::KeyboardCode key_code) {
                                      yRadius:radius] fill];
   }
 
+  // On OS versions earlier than Yosemite, to generate a drop shadow, we set an
+  // opaque background. This distorts windows with non rectangular shapes. To

[tapted, 2016/02/05 04:51:07]

I'm not sure if `distorts` is the right word. Is it just that the corners are
square? (can we say, "we set..." -> "the window is given an opaque background,
but this will have square corners. To get around.."

[karandeepb, 2016/02/08 07:47:10]

Done.

+  // get around this, fill the path outside the window boundary with clearColor
+  // and tell Cococa to regenerate drop shadow. See crbug.com/543671.
+  if (windowMask_ && ![self inLiveResize] &&
+      !IsRectInsidePath(dirtyRect, windowMask_)) {
+    gfx::ScopedNSGraphicsContextSaveGState state;
+    DLOG(WARNING) << "Drawing\n";

[tapted, 2016/02/05 04:51:07]

remove

[karandeepb, 2016/02/08 07:47:10]

Done.

+    // The outer rectangular path corresponding to the window.
+    NSBezierPath* outerPath = [NSBezierPath bezierPathWithRect:[self bounds]];
+
+    [outerPath appendBezierPath:windowMask_];
+    [outerPath setWindingRule:NSEvenOddWindingRule];
+    [[NSGraphicsContext currentContext]
+        setCompositingOperation:NSCompositeCopy];
+    [[NSColor clearColor] set];
+
+    // Fill the region between windowMask_ and its outer rectangular path
+    // with clear color. This causes the window to have the shape described
+    // by windowMask_.
+    [outerPath fill];
+    // Regerate drop shadow around the window boundary.
+    [[self window] invalidateShadow];
+  }
+
   // If there's a layer, painting occurs in BridgedNativeWidget::OnPaintLayer().
   if (hostedView_->GetWidget()->GetLayer())
     return;
@@ -741,4 +804,42 @@ bool DispatchEventToMenu(views::Widget* widget, ui::KeyboardCode key_code) {
   return [hostedView_->GetNativeViewAccessible() accessibilityHitTest:point];
 }
 
+// Update windowMask_ depending on the current view bounds.
+- (void)setWindowMask {

[tapted, 2016/02/05 04:51:07]

setWindowMask -> updateWindowMask

[tapted, 2016/02/05 04:51:08]

I don't think this is overriding anything, so it should be declared in an
@interface -- probably in the header since it's likely BridgedNativeWidget will
be calling it. (Then move this impl to match declaration order)

[karandeepb, 2016/02/08 07:47:09]

Done.

[karandeepb, 2016/02/08 07:47:10]

Done.

+  // Ensure a live resize is not in progress.
+  DCHECK(![self inLiveResize]);

[tapted, 2016/02/05 04:51:08]

I'd make base::mac::IsOSMavericksOrEarlier() as part of the DCHECK and move the
that check into BridgedNativeWidget -- it already has the version checking in
CreateLayer, so this keeps those checks together.  E.g. (in OnSizeChanged)
something like

  // 10.9 is unable to generate a window shadow from the CALayer, so use Quartz.
  if (base::mac::IsOSMavericksOrEarlier())
    [bridge_ updateWindowMask];

[karandeepb, 2016/02/08 07:47:09]

Done. But we'll still need an additional check in viewDidEndLiveResize. 
If we want to keep the logic in bridged_content_view, we can utilise the
windowDidEndLiveResize: method in NSWindowDelegate and have it call a method in
bridged_native_widget.

+
+  views::Widget* widget = hostedView_->GetWidget();
+  if (widget->non_client_view() && base::mac::IsOSMavericksOrEarlier()) {

[tapted, 2016/02/05 04:51:07]

nit: early return

[karandeepb, 2016/02/08 07:47:10]

Done.

+    const NSRect frameRect = [self bounds];
+    gfx::Path mask;
+    widget->non_client_view()->GetWindowMask(gfx::Size(frameRect.size), &mask);
+    if (!mask.isEmpty()) {

[tapted, 2016/02/05 04:51:07]

nit: early return

[karandeepb, 2016/02/08 07:47:09]

Done.

+      windowMask_.reset([gfx::CreateNSBezierPathFromSkPath(mask) retain]);
+
+      // Convert to AppKit coordinate system.
+      NSAffineTransform* flipTransform = [NSAffineTransform transform];
+      [flipTransform translateXBy:0.0 yBy:frameRect.size.height];
+      [flipTransform scaleXBy:1.0 yBy:-1.0];
+      [windowMask_ transformUsingAffineTransform:flipTransform];
+    }
+  }
+}
+

[tapted, 2016/02/05 04:51:08]

stuff below here shouldn't be needed

[karandeepb, 2016/02/08 07:47:09]

Done.

+// Called whenever the view's bounds or frame change. Used to update
+// windowMask_.
+- (void)boundsDidChangeNotification:(NSNotification*)notification {
+  // Ensure that the notification was posted by this object.
+  DCHECK_EQ(notification.object, self);
+  // We don't update the window mask during a live resize, instead it is done
+  // after the resize is completed in viewDidEndLiveResize:.
+  if (![self inLiveResize])
+    [self setWindowMask];
+}
+
+- (void)dealloc {
+  [[NSNotificationCenter defaultCenter] removeObserver:self];
+  [super dealloc];
+}
+
 @end