MacViews: Add native drop shadow to dialogs on OSX < 10.10.

ui/views/cocoa/bridged_content_view.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_content_view.h"
 
 #include "base/logging.h"
+#import "base/mac/mac_util.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "ui/base/ime/input_method.h"
 #include "ui/base/ime/text_input_client.h"
 #include "ui/compositor/canvas_painter.h"
 #import "ui/events/cocoa/cocoa_event_utils.h"
 #include "ui/events/keycodes/dom/dom_code.h"
 #import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #include "ui/gfx/canvas_paint_mac.h"
 #include "ui/gfx/geometry/rect.h"
+#include "ui/gfx/path.h"
+#import "ui/gfx/path_mac.h"
+#include "ui/gfx/scoped_ns_graphics_context_save_gstate_mac.h"
 #include "ui/strings/grit/ui_strings.h"
 #include "ui/views/controls/menu/menu_config.h"
 #include "ui/views/controls/menu/menu_controller.h"
 #include "ui/views/view.h"
 #include "ui/views/widget/widget.h"
 
 using views::MenuController;
 
 namespace {
 
@@ skipping 284 matching lines @@
     return;
 
   if (drawMenuBackgroundForBlur_) {
     const CGFloat radius = views::MenuConfig::instance().corner_radius;
     [skia::SkColorToSRGBNSColor(0x01000000) set];
     [[NSBezierPath bezierPathWithRoundedRect:[self bounds]
                                      xRadius:radius
                                      yRadius:radius] fill];
   }
 
+  views::Widget* widget = hostedView_->GetWidget();
+
+  // On OS versions earlier than Yosemite, to generate a drop shadow, we set an
+  // opaque background. This distorts windows with non rectangular shapes. To
+  // get around this, fill the path outside the window boundary with clearColor
+  // and tell Cococa to regenerate drop shadow. See crbug.com/543671.
+  // TODO(karandeepb) check how this can be optimised.

[tapted, 2016/01/28 05:59:22]

It might be possible to paint this directly into [compositor_superview_ layer]
inside BridgedNativeWidget::AcceleratedWidgetSwapCompleted.

And instead of painting, it might be enough to adjust the type of
|background_layer| in BridgedNativeWidget::AddCompositorSuperview() to a
CAShapeLayer, and give it a background color (on Mavericks). Then, in
AcceleratedWidgetSwapCompleted() just update the clip path before calling
invalidateShadow

[karandeepb, 2016/02/04 03:39:28]

Giving background_layer a background color with the NSWindow background clear,
and calling [window invalidateShadow] did not render a drop shadow.  Hence it
can be safe to assume that the window server is not taking the alpha channel of
background_layer into consideration.

+  if (widget->non_client_view() && base::mac::IsOSMavericksOrEarlier()) {
+    const NSRect frameRect = [self bounds];
+    gfx::Path windowMask;
+    widget->non_client_view()->GetWindowMask(gfx::Size(frameRect.size),
+                                             &windowMask);
+    if (!windowMask.isEmpty()) {
+      gfx::ScopedNSGraphicsContextSaveGState state;
+
+      // The outer rectangular path corresponding to the window.
+      NSBezierPath* outerPath = [NSBezierPath bezierPathWithRect:frameRect];
+
+      // Path corresponding to windowMask. This is in normal coordinate system
+      // (origin at top left of screen).
+      NSBezierPath* clippedPath = gfx::CreateNSBezierPathFromSkPath(windowMask);
+
+      // Convert to AppKit coordinate system.
+      NSAffineTransform* flipTransform = [NSAffineTransform transform];
+      [flipTransform translateXBy:0.0 yBy:frameRect.size.height];
+      [flipTransform scaleXBy:1.0 yBy:-1.0];
+      [clippedPath transformUsingAffineTransform:flipTransform];
+
+      [outerPath appendBezierPath:clippedPath];
+      [outerPath setWindingRule:NSEvenOddWindingRule];
+      [[NSGraphicsContext currentContext]
+          setCompositingOperation:NSCompositeCopy];
+      [[NSColor clearColor] set];
+
+      // Fill the region between clippedPath and its outer rectangular path with
+      // clear color. This causes the window to have the shape described by
+      // clippedPath.
+      [outerPath fill];
+      // Regerate drop shadow around the window boundary.
+      [[self window] invalidateShadow];
+    }
+  }
+
   // If there's a layer, painting occurs in BridgedNativeWidget::OnPaintLayer().
-  if (hostedView_->GetWidget()->GetLayer())
+  if (widget->GetLayer())
     return;
 
   gfx::CanvasSkiaPaint canvas(dirtyRect, false /* opaque */);
-  hostedView_->GetWidget()->OnNativeWidgetPaint(
-      ui::CanvasPainter(&canvas, 1.f).context());
+  widget->OnNativeWidgetPaint(ui::CanvasPainter(&canvas, 1.f).context());
 }
 
 - (NSTextInputContext*)inputContext {
   // If the textInputClient_ does not exist, return nil since this view does not
   // conform to NSTextInputClient protocol.
   if (!textInputClient_)
     return nil;
 
   // If a menu is active, and -[NSView interpretKeyEvents:] asks for the
   // input context, return nil. This ensures the action message is sent to
@@ skipping 395 matching lines @@
   }
 
   return [super accessibilityAttributeValue:attribute];
 }
 
 - (id)accessibilityHitTest:(NSPoint)point {
   return [hostedView_->GetNativeViewAccessible() accessibilityHitTest:point];
 }
 
 @end