Menu for the OSX app launcher.

ui/app_list/cocoa/apps_search_box_controller.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/app_list/cocoa/apps_search_box_controller.h"
 
 #include "base/strings/sys_string_conversions.h"
+#include "grit/ui_resources.h"
+#include "ui/app_list/app_list_menu.h"
+#import "ui/app_list/cocoa/current_user_menu_item_view.h"
 #include "ui/app_list/search_box_model.h"
 #include "ui/app_list/search_box_model_observer.h"
+#import "ui/base/cocoa/controls/hover_image_menu_button.h"
 #include "ui/base/resource/resource_bundle.h"
 #include "ui/gfx/image/image_skia_util_mac.h"
 
 namespace {
 
-// Padding either side of the search icon.
+// Padding either side of the search icon and menu button.
 const CGFloat kPadding = 14;
 
 // Size of the search icon.
 const CGFloat kSearchIconDimension = 32;
 
+// Size of the menu button on the right.
+const CGFloat kMenuButtonDimension = 29;
+
+// Vertical offset that the menu should appear below the menu button.
+const CGFloat kMenuOffsetFromButton = 2;
+
 }
 
 @interface AppsSearchBoxController ()
 
 - (NSImageView*)searchImage;
 - (void)addSubviews;
+- (void)menuItemSelected:(NSMenuItem*)sender;
+
+- (void)addItemToMenu:(NSMenu*)menu
+             forIndex:(int)index;
 
 @end
 
 namespace app_list {
 
 class SearchBoxModelObserverBridge : public SearchBoxModelObserver {
  public:
   SearchBoxModelObserverBridge(AppsSearchBoxController* parent,
                                SearchBoxModel* model);
   virtual ~SearchBoxModelObserverBridge();
@@ skipping 65 matching lines @@
   return self;
 }
 
 - (void)clearSearch {
   [searchInput_ setStringValue:[NSString string]];
   [self controlTextDidChange:nil];
 }
 
 - (void)setDelegate:(id<AppsSearchBoxDelegate>)delegate {
   delegate_ = delegate;
+  app_list::AppListViewDelegate* appListDelegate = [delegate appListDelegate];
   app_list::SearchBoxModel* searchBoxModel = [delegate searchBoxModel];
+  appListMenu_.reset(appListDelegate ?
+      new app_list::AppListMenu(appListDelegate) : NULL);
   bridge_.reset(searchBoxModel ?
       new app_list::SearchBoxModelObserverBridge(self, searchBoxModel) : NULL);
 }
 
 - (NSTextField*)textField {
   return searchInput_;
 }
 
+- (NSPopUpButton*)menuControl {
+  return menuButton_;
+}
+
+- (app_list::AppListMenu*)appListMenu {
+  return appListMenu_.get();
+}
+
 - (NSImageView*)searchImage {
   return searchImage_;
 }
 
 - (void)addSubviews {
   NSSize viewSize = [[self view] bounds].size;
   searchImage_.reset([[NSImageView alloc] initWithFrame:NSMakeRect(
       kPadding, 0, kSearchIconDimension, viewSize.height)]);
 
+  ui::ResourceBundle& resourceBundle = ui::ResourceBundle::GetSharedInstance();
   searchInput_.reset([[NSTextField alloc] initWithFrame:NSZeroRect]);
   [searchInput_ setFocusRingType:NSFocusRingTypeNone];
   [searchInput_ setDrawsBackground:NO];
   [searchInput_ setBordered:NO];
   [searchInput_ setDelegate:self];
-  [searchInput_ setFont:ui::ResourceBundle::GetSharedInstance().GetFont(
+  [searchInput_ setFont:resourceBundle.GetFont(
       ui::ResourceBundle::MediumFont).GetNativeFont()];
 
   // Find the preferred height for those text properties, and center.
   [searchInput_ sizeToFit];
   CGFloat inputXOffset = kSearchIconDimension + 2 * kPadding;
   CGFloat inputHeight = NSHeight([searchInput_ bounds]);
   [searchInput_ setFrame:NSMakeRect(
       inputXOffset,
       floor(viewSize.height / 2 - inputHeight / 2),
-      viewSize.width - inputXOffset - kPadding,
+      viewSize.width - inputXOffset - kMenuButtonDimension - 2 * kPadding,
       inputHeight)];
 
+  // Add the drop-down menu, with a custom button.
+  NSRect buttonFrame = NSMakeRect(
+      NSMaxX([searchInput_ frame]) + kPadding,
+      floor(viewSize.height / 2 - kMenuButtonDimension / 2),
+      kMenuButtonDimension,
+      kMenuButtonDimension);
+  menuButton_.reset([[HoverImageMenuButton alloc] initWithFrame:buttonFrame
+                                                      pullsDown:YES]);
+  [[menuButton_ menu] setDelegate:self];
+  [[menuButton_ cell] setImage:resourceBundle.GetNativeImageNamed(

[sail, 2013/05/31 19:07:03]

use hoverImageMenuButtonCell accessor instead?

[tapted, 2013/06/03 12:49:18]

Done.

+      IDR_APP_LIST_TOOLS_NORMAL).AsNSImage()];
+  [[menuButton_ cell] setAlternateImage:resourceBundle.GetNativeImageNamed(
+      IDR_APP_LIST_TOOLS_PRESSED).AsNSImage()];
+  [[menuButton_ cell] setHoverImage:resourceBundle.GetNativeImageNamed(
+      IDR_APP_LIST_TOOLS_HOVER).AsNSImage()];
+
   [[self view] addSubview:searchImage_];
   [[self view] addSubview:searchInput_];
+  [[self view] addSubview:menuButton_];
+}
+
+- (void)menuItemSelected:(NSMenuItem*)sender {
+  if (!appListMenu_)

[sail, 2013/05/31 19:07:03]

is this possible?

[tapted, 2013/06/03 12:49:18]

Initially I wasn't sure, but I realised the menu is not cleared in setDelegate
-- it should be! So, I do that now, and I've changed this to a DCHECK (done.)

+    return;
+
+  appListMenu_->menu_model()->ActivatedAt([sender tag]);
+}
+
+- (void)menuNeedsUpdate:(NSMenu*)menu {
+  if (!appListMenu_ || [menu numberOfItems] != 1)
+    return;
+
+  int itemCount = appListMenu_->menu_model()->GetItemCount();

[sail, 2013/05/31 19:07:03]

do this in addSubviews instead?

[tapted, 2013/06/03 12:49:18]

I initially did it here because it means the creation of the menu and custom
view can be delayed until the menu is actually requested. But, I guess that's a
small component, and there's a bit more complexity since I really need to update
the menu in setDelegate, not addSubviews.

Done (moved to setDelegate)

+  for (int i = 0; i < itemCount; ++i) {
+    [self addItemToMenu:menu
+               forIndex:i];
+  }
+}
+
+- (void)addItemToMenu:(NSMenu*)menu

[Robert Sesek, 2013/05/31 19:16:09]

Have you considered using MenuController?
https://code.google.com/p/chromium/codesearch#chromium/src/chrome/browser/ui/...

It'd need to be moved to ui/base though

[tapted, 2013/06/03 12:54:24]

I have! But, it would need further refactoring to support the menu item with
custom view. I think I'll still be moving it to base soon, to do context menus
on grid items. Then and I'll follow that up to see whether there is merit making
menu_controller more generic to support the use case here.

+             forIndex:(int)index {
+  DCHECK(appListMenu_);
+  ui::MenuModel* menuModel = appListMenu_->menu_model();
+  if (menuModel->GetTypeAt(index) == ui::MenuModel::TYPE_SEPARATOR) {
+    [menu addItem:[NSMenuItem separatorItem]];
+    return;
+  }
+
+  string16 labelText = menuModel->GetLabelAt(index);
+  scoped_nsobject<NSMenuItem> item(
+      [[NSMenuItem alloc] initWithTitle:base::SysUTF16ToNSString(labelText)
+                                 action:@selector(menuItemSelected:)
+                          keyEquivalent:[NSString string]]);
+  [item setTag:index];
+  [item setTarget:self];
+
+  if (menuModel->GetCommandIdAt(index) == app_list::AppListMenu::CURRENT_USER) {
+    scoped_nsobject<NSView> customItemView([[CurrentUserMenuItemView alloc]
+        initWithDelegate:[delegate_ appListDelegate]
+               usingFont:[menu font]]);
+
+    [item setView:customItemView];
+  }
+
+  [menu addItem:item];
+}
+
+- (NSRect)confinementRectForMenu:(NSMenu*)menu
+                        onScreen:(NSScreen*)screen {
+  // Ensure the menu comes up below the menu button by trimming the window frame
+  // to a point anchored below the bottom right of the button.
+  NSPoint anchor = NSMakePoint(kMenuButtonDimension,
+                               kMenuButtonDimension + kMenuOffsetFromButton);
+  anchor = [menuButton_ convertPoint:anchor
+                              toView:nil];
+  anchor = [[menuButton_ window] convertBaseToScreen:anchor];
+  NSRect rect = [[menuButton_ window] frame];
+  rect.size = NSMakeSize(anchor.x - NSMinX(rect), anchor.y - NSMinY(rect));

[sail, 2013/05/31 19:07:03]

how about just converting [menuButton_ bounds] to screen coordinates?

[tapted, 2013/06/03 12:49:18]

Sadly, NSWindow convertRectToScreen: is OSX 10.7+ (unless there's an alternative
I've missed). I've updated to use NSView's convertRect: toView: to remove
kMenuButtonDimension from the equation though.

+  return rect;
 }
 
 - (BOOL)control:(NSControl*)control
                textView:(NSTextView*)textView
     doCommandBySelector:(SEL)command {
   // Forward the message first, to handle grid or search results navigation.
   BOOL handled = [delegate_ control:control
                            textView:textView
                 doCommandBySelector:command];
   if (handled)
     return YES;
 
   // Escape when there is text clears the search input.
   if (command == @selector(complete:)) {
     [self clearSearch];
     return YES;
   }
 
   return NO;
 }
 
 - (void)controlTextDidChange:(NSNotification*)notification {
   if (bridge_)
     bridge_->updateModel(base::SysNSStringToUTF16([searchInput_ stringValue]));
 
   [delegate_ modelTextDidChange];
 }
 
 @end